Published March 15, 2018 © GPL3+

Air Quality Analyzer

Analyses home air quality and records the values in a SD card.

IntermediateShowcase (no instructions)5,402

Things used in this project

Hardware components

ADAFRUIT FEATHER M0 ADALOGGER

Adafruit MONOCHROME 0.96" 128X64 OLED GRAPHIC DISPLAY

ADAFRUIT CCS811 AIR QUALITY SENSOR BREAKOUT - VOC AND ECO2

DHT11 Temperature & Humidity Sensor (4 pins)

Jumper wires (generic)

around 20 male to male 15cm jumpers.

Software apps and online services

Arduino IDE

Hand tools and fabrication machines

Soldering iron (generic)

Story

The quality of the air that we breathe, is very important to our health. This device analyses the air quality inside our homes, and records the values in a SD card. By analyzing the stored values, we know how the evolution of the parameters thru time was.

I will use temperature, humidity and air quality sensors that are cheap enough to use in this kind of project, without sacrificing too much the precision. The main idea behind this project is to know if the air is breathable or not.

The elected sensors are:

DTH11 Temperature and humidity sensor, approx. $5.00 (not very accurate but good enough);

CCS811 Air Quality Sensor module, approx $19.95.

Platform:

I used Arduino Uno before, and I felt some memory limitations, so I decided to use a different board this time. As I need an SD card to record the values, the Adafruit Feather M0 Adalogger, was a perfect choice at a good price ($19.95):

ATSAMD21G18 ARM Cortex M0 processor, clocked at 48 MHz / 3.3V logic

256KB of FLASH + 32KB of RAM

Built in 100mA lipoly charger with charging status indicator LED

MicroSD card holder

light (5.3 grams)

small (51mm x 23mm x 8mm)

Building:

I started by downloading the latest version of the Arduino IDE from https://www.arduino.cc/en/Main/Software choosing the windows installer. After the installation is complete, be sure to read carefully the Adafruit Feather M0 Adalogger user manual.

To be able to use Arduino IDE with this board, we have to configure the IDE as described in the Adafruit Feather M0 Adalogger user manual. Will be necessary to add a URL to the new Additional Boards Manager URLs option. Other simple actions are required, all of them described in the manual that can be found at:

https://cdn-learn.adafruit.com/downloads/pdf/adafruit-feather-m0-adalogger.pdf

https://learn.adafruit.com/adafruit-feather-m0-adalogger

https://learn.adafruit.com/adafruit-feather-m0-adalogger/setup

With everything configured, (don't forget to select the right board and port on the IDE) lets do some simple test to check if everything is working. I used this code:

void setup() {
 pinMode(13, OUTPUT);// initialize digital pin 13 as an output.
}
void loop() {
 digitalWrite(13, !digitalRead(13)); // flash the LED with inverse value
 delay(500); // wait for a half a second
}

After sending this code to the FEATHER M0 ADALOGGER, I had no errors and the red LED on the board (connected to port 13 ) started flashing. Everything was OK.

Connecting the display:

The first thing I connected to the board, was the OLED display. I strongly recommend that you read the display documentation available at https://cdn-learn.adafruit.com/downloads/pdf/monochrome-oled-breakouts.pdf

I connected the display pins to the processor board in this way:

Display - > Board

GND goes to ground

Vin goes to 3V

DATA to digital 6

CLK to digital 10

D/C to digital 11

RST to digital 5

CS to digital 12

Using the OLED Display documentation, Install Adafruit SSD1306 and Adafruit GFX Libraries. Restart the Arduino IDE.

Finally you can run the File→Sketchbook →Libraries→ Adafruit_SSD1306→ SSD1306_128x64_spi example

I had a compilation error complaining about an incorrect display height. This is because the library file SSD1306.h was generic and I had to edit it, to select the correct height of my display (64). Find the relevant lines and select the correct value by commenting the incorrect lines.

//   #define SSD1306_128_64
  #define SSD1306_128_32
//   #define SSD1306_96_16

I changed the default pins, because of some conflicts. So, I had to change the default code definitions in the example code, to match the pins I used:

#define OLED_MOSI   6
#define OLED_CLK   10
#define OLED_DC    11
#define OLED_CS    12
#define OLED_RESET 5
Adafruit_SSD1306 display(OLED_MOSI, OLED_CLK, OLED_DC, OLED_RESET, OLED_CS);

NOTE: Don't use pin digital 9 if you plan to use the battery voltage monitoring in A7. Digital 9 and A7 share the same pin. I found that in the hard way, after hours of bad Vbat readings and bad display behavior.

D9 uses same pin as A7

When the display works correctly you can proceed to the next section:

Connecting the Sensors:

Connect DHT 11 according to the diagram. (Don't use the pin D13 on the board to read DHT11 data. Pin D13 has a LED connected permanently, it presents a low impedance and is not suitable for this kind of use).

PIN D13 has a LED connected permanently

We have to use one of the free digital pins. We excluded D9 because it conflicts with A7 used to read Vbat, and D13 because of the LED circuit. I will use D19 to connect to DHT11 pin 2, and read temperature and humidity via its one wire protocol. D19 is marked as A5 on the board, but can also be used as Digital 19. Don't forget to define DHTpin on software:

#define DHTPIN 19

Adalogger Analog pins can also be used as digital

CCS811 Connection:

Vin goes to 3.3V line,

GND goes to GND line,

SDA goes to Adalogger SDA

SCL goes to Adalogger SCL

/WAKE goes to GND

I used Adafruit_CCS811 library version=1.0.0 and everything works fine.

SD Card

To be able to record the values thru time, I used an old 512MB uSD card. This Adalogger board is fantastic because it already has a uSD Card slot. I use here the Arduino library version 1.2.2. and the pin D4 as the CS pin for SD. In the next figure i show the format os the data in SD Card. It is comma separated, in order to be opened by spreadsheet software for analysis.

SD File created by software v 2.0

In this example, data is being recorded every 5 minutes (300 seconds). This value of time is easily changed in software, by changing line:

#define SD_write_interval 300 //seconds between SD writes

Replace 300 by the number of seconds you want between SD writes. That simple.

SD Data after being imported by spreadsheet

The file is in csv format (comma separated values) meaning that all values are separated by commas. It can be easily imported by a spreadsheet to further analysis.

RTC

A time stamp is essencial for the data-logger. For now, I'm using and evaluating the internal RTC with RTCZero library.

#include <RTCZero.h> //author=Arduino version=1.5.2
#include <RTClib.h> //author=Adafruit version=1.2.1

However i use RTClib as a complement. For the RTC initialization I use the folowing code:

 //RTC initialization
 DateTime now;
 now = (DateTime(F(__DATE__), F(__TIME__))); //compile time
 now=now+20; //20s compensation for Compile + Reset time
 rtc.begin(); // initialize RTCZero
 rtc.setTime(now.hour(), now.minute(), now.second());
 rtc.setDate(now.day(), now.month(), now.year()-2000);

The next thing to do is to find a way to adjust the time. Stay tuned!

The LEDs

If the user don’t know what are the limits of all those air quality parameters, and don't care about the numbers, probably is better to tell him just if they are safe or not. Using 3 LEDs is a simpler interface and more useful if the user just wants to know if he/she can breathe that air. That was the reason why I decided to implement these 3 LEDs with different levels of alarm: Green,Yellow, or Red. The levels that trigger each alarm are programmable according local regulations. To change the levels just edit the following lines of code:

//Levels
//temp levels
#define low_temp_level_1 18
#define low_temp_level_2 12
#define low_temp_level_3 8
#define high_temp_level_1 29
#define high_temp_level_2 35
#define high_temp_level_3 40
//rh levels
#define low_rh_level_1 40
#define low_rh_level_2 30
#define low_rh_level_3 20
#define high_rh_level_1 70
#define high_rh_level_2 80
#define high_rh_level_3 90
//co2 levels
#define co2_level_1 1000
#define co2_level_2 1500
#define co2_level_3 3000
//TVOC levels
#define tvoc_level_1 100
#define tvoc_level_2 500
#define tvoc_level_3 1000

The values shown are just indicative and i´m using them just to test purposes

GO!

Well, i'm still in the evaluation phase, and hoping someone wants to build a similar circuit to help me improve this useful data logger.

Lets download the code and have some fun, reading those CO2 values. I had to open some windows to improve air quality :)

Don't forget to wait 20 minutes after power on, for good CCS811 readings. (The CCS811 also needs 48 hours of burnin time before first use. )

Have fun

Code

Software version 2.0.3

/* Air Quality Sensor V2.0.3 2018/03/27 Luis Sousa */

#include <SPI.h> //Standard lib
#include <SD.h> //author=Arduino, SparkFun version=1.2.2
#include <DHT.h>//author=Adafruit version=1.3.0
//#include <Wire.h>
#include <RTCZero.h> //author=Arduino version=1.5.2
#include <RTClib.h> //author=Adafruit version=1.2.1 
#include <Adafruit_GFX.h> //author=Adafruit version=1.2.3
#include <Adafruit_SSD1306.h> //author=Adafruit version=1.1.2
#include <Adafruit_CCS811.h>//author=Adafruit version=1.0.0

//Levels
//temp levels
#define low_temp_level_1 18
#define low_temp_level_2 12
#define low_temp_level_3 8
#define high_temp_level_1 29
#define high_temp_level_2 35
#define high_temp_level_3 40
//rh levels
#define low_rh_level_1 40
#define low_rh_level_2 30
#define low_rh_level_3 20
#define high_rh_level_1 70
#define high_rh_level_2 80
#define high_rh_level_3 90
//co2 levels
#define co2_level_1 1000
#define co2_level_2 1500
#define co2_level_3 3000
//TVOC levels
#define tvoc_level_1 100
#define tvoc_level_2 500
#define tvoc_level_3 1000

//Status LEDS
#define green_led  14
#define yellow_led 15
#define red_led 16

//OLED Display If using software SPI (the default case):
#define OLED_MOSI   6
#define OLED_CLK   10
#define OLED_DC    11
#define OLED_CS    12
#define OLED_RESET 5
#define display_refresh_interval 1 //2 seconds refresh
Adafruit_SSD1306 display(OLED_MOSI, OLED_CLK, OLED_DC, OLED_RESET, OLED_CS);

//DHT Sensor
#define DHTPIN 19     // what pin DHT is connected to (19=A5 on this Board)
#define DHTTYPE DHT11   // DHT 11
#define DHT_read_interval 3 //Read temp every X seconds
DHT dht(DHTPIN, DHTTYPE); //object dht creation

//SD Card
#define cardSelect 4  //SD chip select pin
#define ficheiro "dados.csv" // nome do ficheiro de dados
//#define Serial_Header "Date,Hour,Vbat,Temp,%RH,eCO2,TVOC,STATUS"
#define SD_Header "Date,Hour,Vbat,min_Temp,Max_Temp,min_RH,Max_RH,min_eCO2,Max_eCO2,min_TVOC,Max_TVOC,STATUS"
#define SD_write_interval 300 //seconds between SD writes
#define SD_led 8 //Green LED

//RTC
RTCZero rtc;  // Create an rtc object /

//Vbat read
#define vbatpin A7    //pin to read Bat Voltage
#define vbat_read_interval 30 //seconds between vbat readings
float measuredvbat;

//Set up variables using the SD utility library functions:
Sd2Card card;
SdVolume volume;
SdFile root;

//Set up CCS811 object ccs
Adafruit_CCS811 ccs;
#define CCS811_read_interval 3 //Read data every X seconds

//variable declaration
unsigned long nseconds; //seconds since start of day.
unsigned long SD_last_write = 0;
unsigned long vbat_last_read = 0;
unsigned long DHT_last_read = 0;
unsigned long CCS811_last_read = 0;
unsigned long display_last_refresh = 0;
boolean error = false; //clear errors
boolean alarm = false; //clear alarms
boolean alarm_level_0 = false;
boolean alarm_level_1 = false;
boolean alarm_level_2 = false;
boolean alarm_level_3 = false;
float eco2 = 0.0;
float max_eco2 = 0.0;
float min_eco2 = 10000;
float tvoc = 0.0;
float max_tvoc = 0.0;
float min_tvoc = 10000;
float temp = 0.0;
float max_temp = 0.0;
float min_temp = 100;
float rh = 0.0;
float max_rh = 0.0;
float min_rh = 100;
String errorString = "";
String alarmString = "";
//byte day = 27;
//byte month = 03;
//byte year = 18;
//byte seconds = 00;
//byte minutes = 00;
//byte hours = 12;

void setup() {
  pinMode(SD_led, OUTPUT);// initialize digital pin 8 as an output.
  pinMode(green_led, OUTPUT);// initialize digital pin as an output.
  pinMode(yellow_led, OUTPUT);// initialize digital pin as an output.
  pinMode(red_led, OUTPUT);// initialize digital pin as an output.

  //Serial Port Initialization
  Serial.begin(57600);
  delay (300);//wait for the serial to be ready
  /*
    while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
    }
  */

  //RTC initialization
  DateTime now;
  now = (DateTime(F(__DATE__), F(__TIME__))); //Compilation time
  now=now+20; //compensation for Compile + Reset time
  rtc.begin(); // initialize RTCZero
  rtc.setTime(now.hour(), now.minute(), now.second());
  rtc.setDate(now.day(), now.month(), now.year()-2000);

  //DHT Initialisation
  dht.begin();

  // CCS811 test
  if (!ccs.begin()) {
    Serial.println("Failed to start CCS811 sensor! Please check your wiring.");
    errorString = "CCS811 Error";
    //while (1);
  }
  //calibrate CCS811 temperature sensor
  while (!ccs.available());
  temp = ccs.calculateTemperature();
  ccs.setTempOffset(temp - 25.0);

  //Display initialization
  display.begin(SSD1306_SWITCHCAPVCC);// by default, we'll generate the high voltage from the 3.3v line internally!
  display.clearDisplay();  // Clear the buffer.

  //SD Initialization and Test
  Serial.print("\nInitializing SD card...");
  // we'll use the initialization code from the utility libraries
  // since we're just testing if the card is working!
  if (!card.init(SPI_HALF_SPEED, cardSelect)) {
    Serial.println("initialization failed. Things to check: ");
    Serial.println("* is a card inserted ? ");
    Serial.println("* is your wiring correct ? ");
    Serial.println("* did you change the chipSelect pin to match your shield or module ? ");
    //while (1);
    errorString = "SD Card Error";
  } else {
    Serial.println("Wiring is correct and a card is present.");
  }
  // print the type of card
  Serial.println();
  Serial.print("Card type :         ");
  switch (card.type()) {
    case SD_CARD_TYPE_SD1:
      Serial.println("SD1");
      break;
    case SD_CARD_TYPE_SD2:
      Serial.println("SD2");
      break;
    case SD_CARD_TYPE_SDHC:
      Serial.println("SDHC");
      break;
    default:
      Serial.println("Unknown");
  }
  // Now we will try to open the 'volume'/'partition' - it should be FAT16 or FAT32
  if (!volume.init(card)) {
    Serial.println("Could not find FAT16 / FAT32 partition.\nMake sure you've formatted the card");
    //while (1);
    errorString = "SD Format Error";
  }
  Serial.print("Clusters:          ");
  Serial.println(volume.clusterCount());
  Serial.print("Blocks x Cluster:  ");
  Serial.println(volume.blocksPerCluster());
  Serial.print("Total Blocks:      ");
  Serial.println(volume.blocksPerCluster() * volume.clusterCount());
  Serial.println();
  // print the type and size of the first FAT-type volume
  uint32_t volumesize;
  Serial.print("Volume type is:    FAT");
  Serial.println(volume.fatType(), DEC);
  volumesize = volume.blocksPerCluster();    // clusters are collections of blocks
  volumesize *= volume.clusterCount();       // we'll have a lot of clusters
  volumesize /= 2;                           // SD card blocks are always 512 bytes (2 blocks are 1KB)
  Serial.print("Volume size (Kb):  ");
  Serial.println(volumesize);
  Serial.print("Volume size (Mb):  ");
  volumesize /= 1024;
  Serial.println(volumesize);
  Serial.print("Volume size (Gb):  ");
  Serial.println((float)volumesize / 1024.0);
  Serial.println("\nFiles found on the card (name, date and size in bytes): ");
  root.openRoot(volume);
  // list all files in the card with date and size
  root.ls(LS_R | LS_DATE | LS_SIZE);
  if (!SD.begin(cardSelect)) {
    errorString = ("No SD Card");
  }
  else {
    File logfile = SD.open(ficheiro, FILE_WRITE);
    if (!logfile)
      errorString = ("File Error");
    else {
      Serial.print("Gravando em: ");
      Serial.println(ficheiro);
      logfile.println(SD_Header);
      logfile.close();
    }
  }
}

void loop() {
  //How many seconds since 0H (start of day)
  nseconds = 3600 * rtc.getHours() + 60 * rtc.getMinutes() + rtc.getSeconds();

  //measure Vbat
  if (abs(nseconds - vbat_last_read >= vbat_read_interval)) //time to read vbat
  {
    measuredvbat = analogRead(vbatpin);
    measuredvbat *= 2; // we divided by 2, so multiply back
    measuredvbat *= 3.3; // Multiply by 3.3V, our reference voltage
    measuredvbat /= 1024; // convert to voltage
    vbat_last_read = nseconds;
  }
  // Reading temperature and humidity
  //if (nseconds % DHT_read_interval == 0) //Time to read temp
  if (abs(nseconds - DHT_last_read >= DHT_read_interval)) //time to read DHT
  {
    rh = dht.readHumidity();
    temp = dht.readTemperature();  // Read temperature as Celsius (the default)
    float f = dht.readTemperature(true);   // Read temperature as Fahrenheit (isFahrenheit = true)

    if (isnan(rh) || isnan(temp) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");// Check if any reads failed and exit early (to try again).
      error = true;
      errorString = ("DHT Error");
      //return;
    }
    DHT_last_read = nseconds;
  }
  // Reading eCO2 & TVOC
  //if (nseconds % CCS811_read_interval == 0) //Time to read data
  if (abs(nseconds - CCS811_last_read >= CCS811_read_interval)) //time to read CCS811
  {
    if (ccs.available()) {
      //temp = ccs.calculateTemperature();
      if (!ccs.readData()) {
        eco2 = ccs.geteCO2();
        tvoc = ccs.getTVOC();
      }
      else {
        error = true;
        Serial.println("CCS811 sensor error!");
        errorString = "CCS811 error";
        //while(1);
      }
      CCS811_last_read = nseconds;
    }
  }

  //Alarm levels
  alarm_level_3 = temp > high_temp_level_3 || temp < low_temp_level_3 || rh > high_rh_level_3 || rh < low_rh_level_3 || eco2 > co2_level_3 || tvoc > tvoc_level_3;
  alarm_level_2 = temp > high_temp_level_2 || temp < low_temp_level_2 || rh > high_rh_level_2 || rh < low_rh_level_2 || eco2 > co2_level_2 || tvoc > tvoc_level_2;
  alarm_level_1 = temp > high_temp_level_1 || temp < low_temp_level_1 || rh > high_rh_level_1 || rh < low_rh_level_1 || eco2 > co2_level_1 || tvoc > tvoc_level_1;
  alarm_level_0 = !alarm_level_3 & !alarm_level_2 & !alarm_level_2;

  //Alarm LEDS &  Alarm Strings
  if (alarm_level_3) {
    alarm = true;
    digitalWrite(green_led, LOW);
    digitalWrite(yellow_led, LOW);
    digitalWrite(red_led, HIGH);
    if (eco2 > co2_level_3) alarmString = "CO2 High ++";
    else if (tvoc > tvoc_level_3) alarmString = "TVOC High ++";
    else if (rh > high_rh_level_3) alarmString = "RH High ++";
    else if (rh < low_rh_level_3) alarmString = "RH Low --";
    else if (temp > high_temp_level_3) alarmString = "Temp High ++";
    else if (temp < low_temp_level_3) alarmString = "Temp Low --";
  }
  else if (alarm_level_2) {
    alarm = true;
    digitalWrite(green_led, LOW);
    digitalWrite(yellow_led, HIGH);
    digitalWrite(red_led, LOW);
    if (eco2 > co2_level_2) alarmString = "CO2 High +";
    else if (tvoc > tvoc_level_2) alarmString = "TVOC High +";
    else if (rh > high_rh_level_2) alarmString = "RH High +";
    else if (rh < low_rh_level_2) alarmString = "RH Low -";
    else if (temp > high_temp_level_2) alarmString = "Temp High +";
    else if (temp < low_temp_level_2) alarmString = "Temp Low -";
  }
  else if (alarm_level_1) {
    alarm = true;
    digitalWrite(green_led, LOW);
    digitalWrite(yellow_led, HIGH);
    digitalWrite(red_led, LOW);
    if (eco2 > co2_level_1)alarmString = ("CO2 High");
    else if (tvoc > tvoc_level_1) alarmString = "TVOC High";
    else if (rh > high_rh_level_1) alarmString = "RH High";
    else if (rh < low_rh_level_1) alarmString = "RH Low";
    else if (temp > high_temp_level_1) alarmString = "Temp High";
    else if (temp < low_temp_level_1) alarmString = "Temp Low";
  }
  else if (alarm_level_0) {
    alarm = false;
    digitalWrite(green_led, HIGH);
    digitalWrite(yellow_led, LOW);
    digitalWrite(red_led, LOW);
    alarmString = "OK";
  }
  //Max and min determination
  if (temp > max_temp) max_temp = temp;
  if (temp < min_temp) min_temp = temp;
  if (rh > max_rh) max_rh = rh;
  if (rh < min_rh) min_rh = rh;
  if (eco2 > max_eco2) max_eco2 = eco2;
  if (eco2 < min_eco2) min_eco2 = eco2;
  if (tvoc > max_tvoc) max_tvoc = tvoc;
  if (tvoc < min_tvoc) min_tvoc = tvoc;

  //Relatorio serial
  Serial.print("Data:" );
  serial2digits(rtc.getDay());
  Serial.print("/");
  serial2digits(rtc.getMonth());
  Serial.print("/");
  Serial.print(2000 + rtc.getYear(), DEC);
  Serial.print(" Hora:" );
  serial2digits(rtc.getHours());
  Serial.print(":");
  serial2digits(rtc.getMinutes());
  Serial.print(":");
  serial2digits(rtc.getSeconds());
  Serial.print("  ");
  Serial.print("VBat:" ); Serial.print(measuredvbat);
  Serial.print(" Temp:");   Serial.print(temp);
  Serial.print(" Humid:");   Serial.print(rh);
  Serial.print(" CO2:");   Serial.print(eco2);
  Serial.print(" ppm, TVOC:");  Serial.print(tvoc); Serial.print(" ppb:");
  Serial.print(" Status:");
  if (error)
    Serial.println(errorString);
  else if (alarm)
    Serial.println(alarmString);
  else Serial.println("OK");

  //Data display
  if (abs(nseconds - display_last_refresh >= display_refresh_interval)) //time to display information
  {
    display.clearDisplay();// Clean Display
    display.setTextSize(1);
    display.setTextColor(WHITE);
    display.setCursor(0, 0);
    display.println("Air Quality Analyzer");
    display.setCursor(0, 8);
    display2digits(rtc.getDay());
    display.print("/");
    display2digits(rtc.getMonth());
    display.print("/");
    display.print(2000 + rtc.getYear(), DEC);
    display.print(" ");
    display2digits(rtc.getHours());
    display.print(":");
    display2digits(rtc.getMinutes());
    /*display.print(":");
      display.print(rtc.getSeconds(), DEC);*/
    display.setCursor(0, 16);
    display.print("Vbat:");
    display.setCursor(50, 16);
    display.print(measuredvbat); display.print(" V");
    display.setCursor(0, 24);
    display.print("Temp:");
    display.setCursor(50, 24);
    display.print(temp); display.print(" C");
    display.setCursor(0, 32);
    display.print("RH:");
    display.setCursor(50, 32);
    display.print(rh); display.print(" %");
    display.setCursor(0, 40);
    display.print("eCO2:");
    display.setCursor(50, 40);
    display.print(eco2); display.print(" ppm");
    display.setCursor(0, 48);
    display.print("TVOC:");
    display.setCursor(50, 48);
    display.print(tvoc); display.print(" ppb");
    display.setCursor(0, 56);
    display.print("Status:");
    display.setCursor(50, 56);
    if (error) {
      display.print(errorString);
    } else if (alarm) {
      display.print(alarmString);
    }
    else
    {
      display.print("OK");
    }
    display.display();
    display_last_refresh = nseconds;
  }
  //SD datalog
  //if (nseconds % SD_write_interval == 0) //Time to log data
  if (abs(nseconds - SD_last_write >= SD_write_interval)) //Time to log data
  {
    File logfile = SD.open(ficheiro, FILE_WRITE);
    if (logfile) {
      digitalWrite(SD_led, HIGH); //SD Write begins
      logfile2digits(rtc.getDay(), logfile);
      logfile.print("/");
      logfile2digits(rtc.getMonth(), logfile);
      logfile.print("/");
      logfile.print(2000 + rtc.getYear(), DEC);
      logfile.print(",");
      logfile2digits(rtc.getHours(), logfile);
      logfile.print(":");
      logfile2digits(rtc.getMinutes(), logfile);
      logfile.print(":");
      logfile2digits(rtc.getSeconds(), logfile);
      logfile.print(",");
      logfile.print(measuredvbat, 2);
      logfile.print(",");
      logfile.print(min_temp, 2);
      logfile.print(",");
      logfile.print(max_temp, 2);
      logfile.print(",");
      logfile.print(min_rh, 2);
      logfile.print(",");
      logfile.print(max_rh, 2);
      logfile.print(",");
      logfile.print(min_eco2, 2);
      logfile.print(",");
      logfile.print(max_eco2, 2);
      logfile.print(",");
      logfile.print(min_tvoc, 2);
      logfile.print(",");
      logfile.print(max_tvoc, 2);
      logfile.print(",");
      if (error)
        logfile.println(errorString);
      else if (alarm)
        logfile.println(alarmString);
      else logfile.println("OK");
      logfile.close();
      SD_last_write = nseconds;
      digitalWrite(SD_led, LOW); //SD Write ends
    }
    else
    {
      error = true;
      errorString = ("logfile error");
    }
    //Max and min RESET
    max_eco2 = 0.0;
    min_eco2 = 10000;
    max_tvoc = 0.0;
    min_tvoc = 10000;
    max_temp = 0.0;
    min_temp = 100;
    max_rh = 0.0;
    min_rh = 100;
  }
  delay(200); //don't use values higher than 1000 or nseconds won't be properly updated
}

void display2digits(int number)// create a leading zero for month/day/hour/minute when <10
{
  if (number >= 0 && number < 10) {
    display.write('0');
  }
  display.print(number);
}

void logfile2digits(int number, File logfile) // create a leading zero for month/day/hour/minute when <10
{
  if (number >= 0 && number < 10) {
    logfile.write('0');
  }
  logfile.print(number);
}

void serial2digits(int number)// create a leading zero for month/day/hour/minute when <10
{
  if (number >= 0 && number < 10) {
    Serial.write('0');
  }
  Serial.print(number);
}

Credits

lmsousa

5 projects • 21 followers