Published October 13, 2017 © GPL3+

AllThingsTalk Maker Platform & NodeMCU

Getting started project for "AllThingsTalk MAKER". Client app works on NodeMCU.

IntermediateProtip1 hour2,156

Things used in this project

Hardware components

NodeMCU ESP8266 Breakout Board

Software apps and online services

AllThingsTalk Maker

Story

AllThingsTalk Maker (ATT Maker) is free and easy to use platform. It provides almost everything to create real Internet of Things solution:

Full GUI administration

Device management

Charts and other visual controls for visual presentation

Server-side rules engine for notification and actuation

MQTT and HTTP Rest protocols

Step by Step

Prerequisites:

Account on MAKER

NodeMCU (or similar ESP8266 device)

Arduino IDE with PubSubClient and ArduinoJSON libraries installed

Sign in into your ATT Maker and create (Connect a device button) your first device. Name of the device in this tutorial is NodeMCU, but you can define any other you want. Devices are identified with their DeviceID, not with name.

For the created device, add two assets: one sensor and one actuator.

To provide data for Arduino sketch, we need to get some details: DeviceID, Device Token and Asset name. First two values you will find under the device Settings=>Authentication. Asset name is what you input during asset creation into Display name field.

Updating code

Find following lines in attached Arduino code and update with your data.

const char* ssid = "WiFi SSID ....."; 
const char* password = "WiFi password ....."; 
const char* mqtt_server = "api.allthingstalk.io"; 
char deviceId[] = "YourDeviceId..."; 
char token[] = "YourDeviceToken..."; 
char outTopicCounter[] = "device/[YourDeviceId]/asset/[AssetName]/state"; 
char inTopic[] = "device/[YourDeviceId]/asset/+/command";

Testing counter (sensor value)

After uploading code to NodeMCU, on the dashboard, counter start with displaying the last received value.

Testing LED (actuator command)

Click on the panel for the LED actuator, and you will get dialog box with option for sending command. At the bottom of the dialog box you will see "Command" panel. Change value to 0 or 1 (without quotes, type of actuator is integer) and send command to NodeMCU with click on green check mark. If everything works fine, you will see in serial console messages arrived from cloud, and built-in LED changes state (ON-OFF).

Message arrived [device/sxBP79eJDwOelE3TFIufXTLY/asset/led/command] 0 
Message arrived [device/sxBP79eJDwOelE3TFIufXTLY/asset/led/command] 1

att_mqtt.ino

/*
  Basic ESP8266 MQTT example
*/

#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <ArduinoJson.h>

// Update these with values suitable for your network.

const char* ssid = "WiFi SSID .....";
const char* password = "WiFi password .....";
const char* mqtt_server = "api.allthingstalk.io";

char deviceId[] = "YourDeviceId...";
char token[] = "YourDeviceToken...";

char outTopicCounter[] = "device/[YourDeviceId]/asset/[AssetName]/state";
char inTopic[] = "device/[YourDeviceId]/asset/+/command";

WiFiClient espClient;
PubSubClient client(espClient);
long lastMsg = 0;
char msg[50];

long int counter = 0;

void setup() {
  pinMode(BUILTIN_LED, OUTPUT);     // Initialize the BUILTIN_LED pin as an output
  Serial.begin(9600);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void setup_wifi() {

  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {

  StaticJsonBuffer<500> jsonBuffer;
  char json[500];

  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    json[i] = (char)payload[i];
  }
  json[length] = '\0';
  
  JsonObject& root = jsonBuffer.parseObject(json);

  if (root.success()) {
    const char* vrednost = root["value"];
    Serial.println(vrednost);
    if (strcmp(vrednost,"1") == 0) {
      digitalWrite(BUILTIN_LED, LOW);   // Turn the LED on (Note that LOW is the voltage level
    } else {
      digitalWrite(BUILTIN_LED, HIGH);  // Turn the LED off by making the voltage HIGH
    }
  } else {
    Serial.println("Parsing JSON failed");
  }

}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Attempt to connect
    if (client.connect("ESP8266Client", token, "")) {
      Serial.println("connected");
      client.subscribe(inTopic);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

void loop() {

  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  long now = millis();
  if (now - lastMsg > 1000) {
    lastMsg = now;
    ++counter;
    String value;
    value = String(counter);
    snprintf (msg, 75, "0|%s", value.c_str());
    client.publish(outTopicCounter, msg);
  }
}