Making our Dorm's Thermostat Smart

//=====================
//  Code for 1st Argon Device
//  Written By Andrew Thompson and Kealoha Hankins
//  For UNCC MEGR3171 IoT Project
//=====================



//The two libraries below are needed for the dallas temperature sensor
#include <OneWire.h>
#include <spark-dallas-temperature.h>

//=====================
//SERVO:    (library already built into IDE)
//Servo pin: D8
Servo servo1;
int pos = 90;   //initial position of the servo
const int defaultPos = 90;    //default position of the servo arm.
    //our servo is a 180 degree servo, so 90 degrees is right in the middle.
int setPos(String angle);   //setPos is the variable for the function to set the angle
int angleIncreaseTemp = 35;    //this is the anlge the servo needs to be to press the increase button on the thermostat
int angleDecreaseTemp = 150;     //this is the angle the servo needs to be to press the decrease button on the thermostat
double timeConstant = 2.85*1000; //this is the number of seconds * 1000 that button must be held down in order to change the temp by 1 degree on the thermostat


//=====================
//TEMPERATURE SENSOR:
//Pin 1: GND
//Pin 2: POWER
//Pin 3: D6
#define ONE_WIRE_BUS D6
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);
int dsRawTemp = 0;  //this is the temp directly from the temp sensor
int dsTemp = 0; //this is the temp that will be reported

//=====================
//These variables are for getting the time from the internet and time-related actions in the code
int hours = -1; //sets the hour to be -1. If the time value is ever neagtive, this indicates a problem
int mins = -1;  //sets the minute to be -1. If the time value is ever negative, this indicates a problem
String sHour;
String sMin;
String currentTime; //create a string for getting the current time.

//=====================
//These variables control how often the program publishes data
int cycle = 3600000;    //cycle time in milliseconds that the program loops before. Changing cycle will change how often actions are performed.
int interval = 0;   //(check) this is the time in milliseconds for setting when actions are performed.
double cycleMin = cycle/60000;  //this is the cycle time in minutes
double cycleHr = cycleMin/60;   //this is the cycle time in hours
int timeSince = 0;  //this variable will be used to keep track of the time that has passed since the last check

double curTemp = 70;    //this double is for the current temperature the thermostat is set at. This is a double because our thermostat is capable of adjusting temp to the tenths place

//=====================
//these variables are for changing the cycle time. Associated with Particle functions below
int setCycleHr(String newCycle);
int setCycleMin(String newCycle);
int setTemp(String newTemp);

int calibrateTemp(String caliTemp);


int tempDiffCN = 0; //difference between the Current temp and New temp
int morningTemp = 0;
int nightTemp = 0;

//====================================================================================

void setup() 
{
servo1.attach(D8);  //tells the argon the servo is connected to pin D8
sensors.begin();    //tells the temp sensor to be ready

Time.zone(-5);  //the line sets the time zone to EST, which is 5 hours behind GMT

Particle.variable("Temperature",dsTemp);    //particle variable for the temperature
Particle.variable("Angle", pos);    //particle variable for the servo angle
Particle.variable("Time_Interval_millis", cycle);
Particle.variable("Time_Interval_mins",cycleMin);
Particle.variable("Time_Interval_hour",cycleHr);
Particle.variable("Thermostat_Temperature", curTemp);
Particle.variable("Current_Time", currentTime);

Particle.function("Set_Servo_Angle", setPos); //particle function for adjusting the servo angle over the web
Particle.function("Change_Time_Interval (hours)", setCycleHr);
Particle.function("Change_Time_Interval (minutes)", setCycleMin);
Particle.function("Change_Temperature", setTemp);
Particle.function("Calibrate_Temperature", calibrateTemp);
Particle.function("Change_Temperature", setTemp);

Particle.subscribe("Day_Temp", morningRoutine, MY_DEVICES);
Particle.subscribe("Night_Temp", nightRoutine, MY_DEVICES);
}

//====================================================================================

void loop() 
{
sensors.requestTemperatures();  //requests that the temp sensor to take the temperature
dsRawTemp = sensors.getTempFByIndex(0); //sets dsrawTemp equal to the temperature (in F)

hours = Time.hour();
sHour = String(hours);
if (hours >= 1 && hours <= 9)
{
    sHour = "0"+String(hours);
}

mins = Time.minute();
sMin = String(mins);
if (mins <=1 <= 9 )
{
    sMin = "0"+String(mins);
}
currentTime = sHour + sMin;

//the following if statmenet is used to suppress random spikes in data.
//The environement where the sensor is located will never realistically be above 100F or below 20F
if (dsRawTemp < 100 && dsRawTemp > 20)  //if dsRawTemp is less than 100 AND dsRawTemp is greater than 20...
{
    dsTemp = dsRawTemp; //sets dstemp to the value of dsRawTemp
}

if (millis() - interval > cycle)    //if the number of miliseconds since the program began minus the interval period is GEATER than the cycle period
{
    Particle.publish("Temperature_internal", String(dsTemp));
    interval = millis();    //sets interval to the number of milliseconds that have passed since the program began
}
timeSince = millis();   //sets timeSince to the number of milliseconds that have passed since the program began

cycleMin = cycle/60000; //converts the cycle time to minutes
cycleHr = cycleMin/60;  //converts the cycle time to hours

delay (500);    //waits .5 seconds
}


//====================================================================================

int setPos(String angle)    //function code for changing the servo's angle
{
    if(angle.toInt() >= 0 && angle.toInt() <= 180)
    {
        pos = angle.toInt();
        servo1.write(pos);
        return pos; //returns the angle given and end the function
    }
    return -1;  //returns -1. This implies there was a problem (such as an angle above 180 or a string that wasn't a number)
}

//====================================================================================

int setCycleHr(String newCycle)   //function for changing the cycle time (in hours) from the web
{
    if (newCycle.toInt() > 0)   //checks to see if the passed string is an INT greater than 0
    {
        cycle = newCycle.toInt()*60000*60; //since the expected time is in hours, newCycle is multiplied by 60000, and then 60, to convert back to milliseconds.
        return newCycle.toInt();    //returns the time given and ends the function.
    }
    return -1;  //if an error occured, -1 will be returned
}

//====================================================================================

int setCycleMin(String newCycle)    //function for changing the cycle time (in minutes) from the web
{
    if (newCycle.toInt() > 0)
    {
        cycle = newCycle.toInt()*60000;
        return newCycle.toInt();
    }
    return -1;  //if an error occured, -1 will be returned
}

//====================================================================================

int setTemp(String newTemp) //this function is in charge of changing the temperature in the program AND physically. Later code will be added to adjust the servo to push the buttons.
{
    if (newTemp.toFloat() >= 60 && newTemp.toFloat() <= 80)
    {
        if(newTemp.toFloat() > curTemp)
        {
            tempDiffCN = curTemp-newTemp.toFloat();
            tempDiffCN = abs(tempDiffCN);
            //finds the absolute value of the difference between the new temperature and the old temperature
            
            servo1.write(angleIncreaseTemp);
            delay(timeConstant*tempDiffCN);
            servo1.write(defaultPos);
            //sets the servo to hold down the INCREASE button long enough to raise the temperature by tempDiffCN degrees
            
            curTemp = newTemp.toFloat();    //updates the current temperature within the program
            return newTemp.toFloat();       //returns the value it was given
        }
        else if (newTemp.toFloat() < curTemp)
        {
            tempDiffCN = curTemp-newTemp.toFloat();
            tempDiffCN = abs(tempDiffCN);
            //finds the absolute value of the difference between the new temperature and the old temperature
            
            servo1.write(angleDecreaseTemp);
            delay(timeConstant*tempDiffCN);
            servo1.write(defaultPos);
            //sets the servo to hold down the DECREASE button long enough to raise the temperature by tempDiffCN degrees
            
            curTemp = newTemp.toFloat();    //updates the current temperature within the program
            return newTemp.toFloat();   //returns the value it was given
        }
        
    }
    return -1;  //if an error occured, -1 will be returned
}

//====================================================================================

int calibrateTemp(String caliTemp)  //this function is responsible for changing ONLY the temp in the program. This is useful in case the thermostat  temperature and curTemp differ.
{
    if(caliTemp.toFloat() >= 60 && caliTemp.toFloat() <= 80)
    {
        curTemp = caliTemp.toFloat();
        return caliTemp.toFloat();  //if the program runs correctly, the number entered will be returned
    }
    return -1;  //if an error occured, -1 will be returned
}

//====================================================================================

void morningRoutine(const char *topic, const char *data)    //this function is for chaing the temperature based on the daily morning routine. Does not return any value
{
    morningTemp = String(data).toInt(); //sets morning temp to the value from the Day_Temp event
    
    if(morningTemp > curTemp)   //if the morning temp is warmer than the current temp, the temp needs to be INCREASED
    {
        tempDiffCN = curTemp-morningTemp;
        tempDiffCN = abs(tempDiffCN);
            //finds the absolute value of the difference between the new temperature and the old temperature
        
        servo1.write(angleIncreaseTemp);
        delay(timeConstant*tempDiffCN);
        servo1.write(defaultPos);
            //sets the servo to hold down the INCREASE button long enough to raise the temperature by tempDiffCN degrees
        
        curTemp = morningTemp;   //updates the curret temperature within the program
    }
    
    if(morningTemp < curTemp)   //if the morning temp is cooler than the current temp, the temp needs to be DECREASED
    {
        tempDiffCN = curTemp-morningTemp;
        tempDiffCN = abs(tempDiffCN);
        //finds the absolute value of the difference between the new temperature and the old temperature
        
        servo1.write(angleDecreaseTemp);
        delay(timeConstant*tempDiffCN);
        servo1.write(defaultPos);
            //sets the servo to hold down the DECREASE button long enough to lower the temp by tempDiffCN degrees
        
        curTemp = morningTemp;   //updates the current temperature within the program
    }
}

//====================================================================================

void nightRoutine(const char *topic, const char *data)    //this function is for chaing the temperature based on the daily night routine. Does not return any value
{
    nightTemp = String(data).toInt(); //sets night temp to the value from the Night_temp event
    
    if(nightTemp > curTemp)   //if the night temp is warmer than the current temp, the temp needs to be INCREASED
    {
        tempDiffCN = curTemp-nightTemp;
        tempDiffCN = abs(tempDiffCN);
            //finds the absolute value of the difference between the new temperature and the old temperature
        
        servo1.write(angleIncreaseTemp);
        delay(timeConstant*tempDiffCN);
        servo1.write(defaultPos);
            //sets the servo to hold down the INCREASE button long enough to raise the temperature by tempDiffCN degrees
        
        curTemp = nightTemp;   //updates the curret temperature within the program
    }
    
    if(nightTemp < curTemp)   //if the night temp is cooler than the current temp, the temp needs to be DECREASED
    {
        tempDiffCN = curTemp-nightTemp;
        tempDiffCN = abs(tempDiffCN);
        //finds the absolute value of the difference between the new temperature and the old temperature
        
        servo1.write(angleDecreaseTemp);
        delay(timeConstant*tempDiffCN);
        servo1.write(defaultPos);
            //sets the servo to hold down the DECREASE button long enough to lower the temp by tempDiffCN degrees
        
        curTemp = nightTemp;   //updates the current temperature within the program
    }
}