Step 1: Tactile Switch Button Circuit
Step 2: Breadboard Circuit Diagram
Step 3: Printed Circuit Board
Step 4: PCB Circuit
Step 5: Source Code (Adafruit IO
Step 6: If This Then That (IFTTT
Step 7: Source Code (Functions and Definitions
Step 8: Testing Circuit and Source Code
Step 9: Assembling the Circuit to 3D Design

Published December 20, 2023 © GPL3+

Mood Tracker! Get Feedback on Feelings

This is where I thought of a way to get feedback, and decided to make a mood tracker.

IntermediateFull instructions provided87

Things used in this project

Hardware components

Espressif Wemos D1 Mini

Capacitor 100 µF

5MM 2Pin Terminal Block

5MM 3Pin Terminal Block

Female Header 8 Position 1 Row (0.1")

Male Header 40 Position 1 Row (0.1")

Through Hole Resistor, 330 kohm

Resistor 10k ohm

Software apps and online services

Arduino IDE

IFTTT Maker service

Adafruit IO

Hand tools and fabrication machines

Soldering iron (generic)

Solder Wire, Lead Free

Story

My daughter started primary school this year, and primary school is challenging for students and that's normal! But children sometimes avoid sharing how they are feeling with their parents. This is where I thought of a way to get feedback, and decided to make a mood tracker. The system includes two "thumbs", and has some LED strips to make it look fun. A simple distance sensor detects when the device is approached and the device is activated. An "up thumb" indicates a "good" mood and a "down thumb" indicates a "bad" mood, and a different colored light appears for each mood expression. The "mood tracker" provides feedback by e-mail through a Wi-Fi board and a few other tools. You can develop this project to find out how your students, family, or office colleagues are feeling, let's get started!

Step 1: Tactile Switch Button Circuit

1 / 5

First of all, two tactile switch buttons are needed to read the thumb actions. I also used drilled PCB to build and fix the switch buttons circuit. Finally, a resistor is needed for the switch circuit to work properly. With the help of a soldering iron, I solder and fix the circuit components and complete the connections. After the two switch circuits are prepared, I fix the switches with the help of glue on the inside of the back cover of the 3D box where the whole circuit will be placed. Then, I commonly connect the switch circuit power line with the help of a clip.

Step 2: Breadboard Circuit Diagram

1 / 2

Once the switch circuit is complete, we need to make the circuit connections that contain the whole system. A breadboard and some jumpers are needed for the base of the circuit. You can easily build your circuit by following the shared circuit diagram.

Step 3: Printed Circuit Board

However, to avoid a complex circuit, I will use the printed circuit board that I have designed before. This printed circuit board is suitable for this project and many other projects. If you would like to have this PCB, you can easily order it from PCBWay by following the shared link.

https://www.pcbway.com/project/shareproject/Mood_Tracker_Get_feedback_of_feelings.html

1 / 4

You can easily assemble the components using a soldering iron and soldering wire. The heart of the PCB is a Wi-Fi-based WeMos controller, you can use all I/O pins on the WeMos with both terminal blocks and headers. There is also a MOSFET on the board, which has an external power supply and allows you to switch digitally.

Step 4: PCB Circuit

1 / 3

We start the circuit connections by first wiring the 3.3 volts and ground line common to the switches. Then, make the digital pin connections to read the switch values. Next, connect the LED strip connections to the digital, ground, and 5-volt inputs respectively. Next, complete the ultrasonic distance sensor connections. Finally, make the ground and power connections to supply 5 Volt power to the circuit. Let's move on to the next part, programming the board.

Step 5: Source Code (Adafruit IO)

1 / 10

Open the shared source code, then install the required libraries. As an example, I will show the Adafruit library installation. We will use Adafruit IO to save the switch data and trigger some actions based on the read values. The library is compatible with many boards. After completing the library installation, go to Adafruit IO and create two New Feeds from the Feeds section to save the read values. I defined two feeds as "vote good" and "vote bad". To ensure correct communication with Adafruit IO, you must add your unique username and key number to the code.

Step 6: If This Then That (IFTTT)

1 / 17

We will use IFTTT to get feedback on the data saved in Adafruit. We need to create two Applets. Find Adafruit and select "if new data is received", in this section you will be asked to connect with your Adafruit IO account. If "vote good" data is received, we will trigger the "send me an email" option. Set the subject and message content for the email, you can use HTML codes when editing. Create the "vote bad" applet in the same way and let's go back to the code.

Step 7: Source Code (Functions and Definitions)

1 / 8

In the code, your WiFi information and the feed names created in Adafruit must be updated. In the "Setup" section, firstly pin modes are specified, and then Adafruit IO and strip LED initial settings are defined. In the "Loop" section, the functions to be executed when the distance sensor detects an object is defined. Outside the "Loop", there are functions for object detection and LED color to be activated when an object is detected. In the LED color section, you can update your preferred color values. Then, the operations to be executed when the buttons are pressed and the LED colors to be displayed are defined. Again, you can update the colors that will light up when the buttons are pressed according to your preference. Finally, at the beginning of the source code, you can update the pins to which the components are connected, the distance threshold value, the LED brightness value, and the LED delay values.

Step 8: Testing Circuit and Source Code

1 / 3

After uploading the source code to the board, let's test our circuit! Supply the circuit with 5 volt 1 amp power and then test if the distance sensor, buttons, and LED lighting are working correctly.

Step 9: Assembling the Circuit to 3D Design

1 / 12

If your circuit is working correctly, let's place the whole circuit in our 3D enclosure in the next section. You can find the 3D models from the shared link.

Finally, we have come to the end of one more project, you can improve the project and expand its usage areas depending on your personal preferences. Write your thoughts in the comments about what you would add to the project. Thank you for reading.

Schematics

Code

Source Code

#include <ESP8266WiFi.h>
#include <FastLED.h>
#include <AdafruitIO.h>
#include <AdafruitIO_WiFi.h>
#include <Adafruit_MQTT.h>
#include <ArduinoHttpClient.h>

// Pin numbers are defined as GPIO
#define LED_PIN       15
#define NUM_LEDS      21
#define BUTTON_A      5
#define BUTTON_B      4
#define TRIG_PIN      13
#define ECHO_PIN      16
#define THRESHOLD     30    // Distance threshold value (cm)
#define BRIGHTNESS    125   // LED brightness (range 0-255)
#define LED_OFF_DELAY 3000  // LED turn-off delay (ms)

CRGB leds[NUM_LEDS];

bool objectDetected = false;  // Check object detection
bool firstRun = true;         // Check the first run
bool buttonPressed = false;   // Flag to check if one of the buttons has been pressed

// Adafruit IO Configuration
// visit io.adafruit.com if you need to create an account
// or if you need your Adafruit IO key
#define IO_USERNAME  "maker101io"
#define IO_KEY       "aio_cMrQ77o666kuutGgf0keXQW0AuMw"

// WIFI Configuration
#define WIFI_SSID    "MERT-KILIC"
#define WIFI_PASS    "fckgw1212mertkilic"

AdafruitIO_WiFi io(IO_USERNAME, IO_KEY, WIFI_SSID, WIFI_PASS);

// Set up the 'command' feed
AdafruitIO_Feed *commandGood = io.feed("vote good");
AdafruitIO_Feed *commandBad = io.feed("vote bad");

void setup() {
  Serial.begin(115200);
  pinMode(BUTTON_A, INPUT_PULLUP);
  pinMode(BUTTON_B, INPUT_PULLUP);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);

  // Connect to io.adafruit.com
  Serial.print("Connecting to Adafruit IO");
  io.connect();

  // Wait for a connection
  while(io.status() < AIO_CONNECTED) {
    Serial.print(".");
    delay(500);
  }
  Serial.println();
  Serial.println(io.statusText());

  FastLED.addLeds<WS2812, LED_PIN, GRB>(leds, NUM_LEDS);
  FastLED.setBrightness(BRIGHTNESS);
  FastLED.show();
  FastLED.clear();
}

void loop() {
  if (detectObject()) {
    objectDetected = true;
    activateLEDs();
    waitForButtons();
    objectDetected = false;   // Reset object detection
    firstRun = false;         // Reset first run
    buttonPressed = false;    // Reset button pressed state
  }
}

bool detectObject() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);

  long duration = pulseIn(ECHO_PIN, HIGH);
  int distance = duration * 0.034 / 2;

  Serial.print("Distance: ");
  Serial.print(distance);
  Serial.println(" cm");

  return distance <= THRESHOLD;
}

void activateLEDs() {
  if (!firstRun) { // Disable the LED from lighting up at first run
    fill_solid(leds, NUM_LEDS, CRGB::Purple);
    FastLED.show();
  }
}

void waitForButtons() {
  unsigned long buttonPressTime = millis();

  while (true) {
    if (digitalRead(BUTTON_A) == LOW) {
      commandGood->save(1);
      buttonAEffect();
      break;
    }
    if (digitalRead(BUTTON_B) == LOW) {
      commandBad->save(1);
      buttonBEffect();
      break;
    }

    unsigned long currentTime = millis();
    if (currentTime - buttonPressTime >= LED_OFF_DELAY) {
      break; // Exit loop if the LED_OFF_DELAY milliseconds have passed without any button press
    }

    delay(100);
  }
}

void buttonAEffect() {
  buttonPressed = true; // Set the Button A pressed flag
  fill_solid(leds, NUM_LEDS, CRGB::Green);
  FastLED.show();
  delay(LED_OFF_DELAY);
  fill_solid(leds, NUM_LEDS, CRGB::Black);
  FastLED.show();
}

void buttonBEffect() {
  buttonPressed = true; // Set the Button B pressed flag
  fill_solid(leds, NUM_LEDS, CRGB::Red);
  FastLED.show();
  delay(LED_OFF_DELAY);
  fill_solid(leds, NUM_LEDS, CRGB::Black);
  FastLED.show();
}

Credits

Maker 101

56 projects • 187 followers

Maker 101; Beginner and intermediate level Maker projects!

Contact

Comments

Please log in or sign up to comment.

Mood Tracker! Get Feedback on Feelings

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Step 1: Tactile Switch Button Circuit

Step 2: Breadboard Circuit Diagram

Step 3: Printed Circuit Board

Step 4: PCB Circuit

Step 5: Source Code (Adafruit IO)

Step 6: If This Then That (IFTTT)

Step 7: Source Code (Functions and Definitions)

Step 8: Testing Circuit and Source Code

Step 9: Assembling the Circuit to 3D Design

Custom parts and enclosures

mood-tracker-3d-001_ax6WZGGxSE.stl

mood-tracker-cover-02_4valkiBByK.stl

mood-tracker-thumbs_t697CE8CCw.stl

mood-tracker-3d-halka_ynLKGWvdOy.stl

Schematics

Mood Tracker Circuit Diagram

Code

Source Code

Credits

Maker 101

Comments

Embed the widget on your own site

Mood Tracker! Get Feedback on Feelings

Mood Tracker! Get Feedback on Feelings

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Step 1: Tactile Switch Button Circuit

Step 2: Breadboard Circuit Diagram

Step 3: Printed Circuit Board

Step 4: PCB Circuit

Step 5: Source Code (Adafruit IO)

Step 6: If This Then That (IFTTT)

Step 7: Source Code (Functions and Definitions)

Step 8: Testing Circuit and Source Code

Step 9: Assembling the Circuit to 3D Design

Custom parts and enclosures

mood-tracker-3d-001_ax6WZGGxSE.stl

mood-tracker-cover-02_4valkiBByK.stl

mood-tracker-thumbs_t697CE8CCw.stl

mood-tracker-3d-halka_ynLKGWvdOy.stl

Schematics

Mood Tracker Circuit Diagram

Code

Source Code

Credits

Maker 101

Comments

Related channels and tags