Arduino DC Motor Speed Motor Control

/*CONTROL PROGRAM CONTROLLER MST_K12 WAY THROUGH SERIAL INTERFACE
Code for piloting of MST_K12 speed regulator. By connecting pin 13 at the entrance VCNT MST_K12 the positive and the negative input to GND GND of Arduino boards (MEGA), the controller may be controlled by sending commands via the serial monitor IDE dell'arduino with speed set to 9600.
The commands accepted are:

a - turn on the MOTOR
s - switch off the MOTOR
q - requests the status of the MOTOR.

    Possible answers:
    ENGINE on with speed regulation at xxx%
    ENGINE off with speed regulation at xxx%

rxxx - set the speed regulation value at the xxx%. possible values for "xxx" are from 0 to 100. Spaces are ignored.
The accepted characters are only numbers (0 through 9).
*/

//pin
const byte vcnt = 13; //output pwm

//variabili globali
byte regolazione = 0;  // contains the % value of the pwm on pin 13
int start =0;          // enable ignition of the regulator
void setup() {
  pinMode(vcnt,OUTPUT);
  analogWrite(vcnt, regolazione);
  Serial.begin(9600); // set the serial interface
  delay(1000); // wait a 1s
  Serial.println(F("Serial Interface ready ")); //are ready
  Serial.println(F(" a= turn on; s= turn off; rxxx = set regulation at  xxx%; q= motor status")); 
  
}

//main program
void loop() {
  int lettura; // PWM value read from serial
  unsigned long tempMillis; // set rx  timeout 
  byte caratteri; // rx char number
  byte tempChar; // read char

  // check if a byte is received
  if (Serial.available()) {
    byte command = Serial.read(); //read the first bye
    switch (command) { // check if it is valid
      case 'a': // turn on the MOTOR
        //;regolazione = 100;
        start =1;
        analogWrite(vcnt, start*regolazione*255/100);
        Serial.print(F("MOTOR"));
        Serial.print(F(" is on with regulation at "));
        Serial.print(regolazione, DEC);
        Serial.println("%");
        break;
      case 's': // turn off the MOTOR
        start=0;
        analogWrite(vcnt, 0);
        Serial.println(F("MOTOR off"));
        break;
      case 'q': // user wants to know the MOTORE status
        Serial.print(F("MOTOR "));
        if (start == 0) {
          Serial.print(F("off"));
        } else if (start == 1) {
          Serial.print(F("on"));
        } 
          Serial.print(F(" regulation at "));
          Serial.print(regolazione, DEC);
          Serial.println("%");
        
        break;
      case 'r': // set pwm
        lettura = 0;
        tempMillis = millis();
        caratteri = 0;
        // I need other chars
        do {
          if (Serial.available()) {
            tempChar = Serial.read();
            caratteri++;
            if ((tempChar >= 48) && (tempChar <= 57)) { //is it a number? ok
              lettura = (lettura * 10) + (tempChar - 48);
            } else if ((tempChar == 10) || (tempChar == 13)) {
              //
              break;
            }
          }
          //abort for timeout, for pwm value > 255
          //or for more un-significant chars
        } while ((millis() - tempMillis < 500) && (lettura <= 100) && (caratteri < 10));
        // if pwm value is valid, the set the pin pwm
        if (lettura <= 100) {
          regolazione = lettura;
          analogWrite(vcnt, start*regolazione*255/100);
          Serial.print(F("regulation set at "));
          Serial.print(regolazione, DEC);
          Serial.println("%");
         }
        break;
    }
    // clear the buffer
    while (Serial.available()) {
      byte a = Serial.read();
    }
  }
}