Published September 25, 2024 © GPL3+

Spongebob that can detect drowsiness!

Usually, high CO2 in a room can cause drowsiness. This Spongebob gets sleepy as CO2 level in the room rises so you can open the windows!

AdvancedFull instructions provided10 hours1,002

Things used in this project

Hardware components

Seeed Studio XIAO ESP32S3 Sense

mq135

Jumper wires (generic)

DC motor (generic)

m4 bolt

Software apps and online services

Arduino IDE

JLCPCB easyeda

Hand tools and fabrication machines

Plier, Long Nose

Soldering iron (generic)

Story

Lately, I've noticed that I feel quite drowsy in class. Now I won't blame the lessons for being boring, and since I've been sleeping well at night, that's not the cause either. After doing some research online (mostly through Google and ChatGPT XD), I discovered that the drowsiness is probably due to excess carbon dioxide accumulating in the classroom. This makes sense, as the weather has been quite cold recently, and we keep the classroom windows and door closed most of the time.

The same issue occurs in my dorm. I feel drowsy while studying because I keep the windows closed, which causes the room to fill with too much carbon dioxide. Here's an article I came across if you’d like to know more: Read

So, I came up with the idea of building a cool-looking CO2 monitor that is very intuitive to understand! It is basically an artwork of SpongeBob SquarePants (from the good old days!) whose eyelids move up and down to indicate how drowsy he gets based on the CO2 levels. When the CO2 levels are low, his eyes are wide open with his eyelids up. As the level rises, his eyelids gradually lower according to the ppm level. If his eyes are completely shut, it means there's too much CO2 in the room, and you better let some fresh air in!

Working

The main components of this project are the MQ135 air quality sensor and a Xiao esp32 microcontroller. The setup also contains five hall effect sensors, each one mapped to a certain CO2 ppm level. A motor is connected to the microcontroller through an L293D motor driver IC. This motor is a DIY linear motor that moves the eyelids up or down depending on the direction of rotation. The eyelids contain a magnet at the long end that can be detected by the hall sensors.

The microcontroller reads the MQ135 sensor’s analog output and converts them to the CO2 ppm levels with some math. This is done for a specific duration (5 minutes in my code) and the ppm values are averaged for that duration. Then, the microcontroller turns the linear motor on until the magnet is in front of the hall sensor that corresponds to the same ppm (within a tolerance range). This way the eyelids move to match the ppm level.

1 / 2

Design the circuit

For this project, I decided to design a PCB and have it assembled. I’ve never done it before and wanted to explore this. I’ve seen a lot of other creators at Instructables and Youtube make their own PCB so I thought this will be a good project to give it a go.

I used Easyeda for designing the circuit and PCB. There might be better alternatives out there, but I’ve seen a lot of youtubers use this and it seemed quite easy to learn.

Design the PCB

I never designed and got a PCB manufactured before. After seeing a lot of YouTubers do it, I decided to give it a try. I got my PCB manufactured by Seeed Fusion. So, before designing my PCB, I made sure to read all their guidelines.

First, I clicked on the "Design" menu and selected "Convert Schematic to PCB." EasyEDA then generated a new PCB file with all the components from my schematic. From there I designed the PCB and generated the Gerber files.

Making SpongeBob SquarePants!

Well, my design currently features SpongeBob without his SquarePants. However, you’re more than welcome to add the pants yourself, there's no rule against it! For this project, I decided to use Sunboard, a type of low-density PVC board. It's incredibly easy to work with while still being remarkably durable, making it perfect for this kind of craft.

1 / 6

Putting it all together

After getting my PCB assembled, I put it all together.

I placed the CO2 sensor behind to hide it from view. If you do this too, make sure the frame is not placed in the corner of the room where there is no air circulation. Otherwise your SpongeBob might always be drowsy!

The eyelids do wobble a bit while moving, but that is not an issue at all. Since they only move when there is a significant difference in the CO2 levels, you will barely see them move. However it does make some noise while moving. Mainly because of my old geared motor grinding. I think a tiny N20 motor would be a better option.

Code

CO2_sensor

#include "MQ135.h"

// Define the pins for hall sensors, motor driver, and MQ135 sensor
const int hallSensors[] = {D1, D2, D3, D4, D5};
const int motorEnable = D8;
const int motorInput1 = D6;
const int motorInput2 = D7;
const int mq135Pin = A0;

MQ135 gasSensor = MQ135(mq135Pin);

// Define the CO2 ppm ranges for each hall sensor
const int ppmRanges[][2] = {
  {800, 1000},
  {1001, 1200},
  {1201, 1400},
  {1401, 1600},
  {1601, 1800}
};

// Store the CO2 ppm readings
const int maxReadings = 30; // 5 minutes / 10 seconds
float ppmReadings[maxReadings];
int readingIndex = 0;

void setup() {
  Serial.begin(115200);

  // Initialize the hall sensors as inputs
  for (int i = 0; i < 5; i++) {
    pinMode(hallSensors[i], INPUT);
  }

  // Initialize the motor driver pins as outputs
  pinMode(motorEnable, OUTPUT);
  pinMode(motorInput1, OUTPUT);
  pinMode(motorInput2, OUTPUT);

  // Initialize the motor to stop
  digitalWrite(motorEnable, LOW);
}

void loop() {
  // Read the CO2 ppm level from the MQ135 sensor
  float ppm = gasSensor.getPPM();

  // Store the CO2 ppm reading
  ppmReadings[readingIndex] = ppm;
  readingIndex = readingIndex + 1;
  
  if(readingIndex >= 30)
  {
    // Calculate the average CO2 ppm level
    int avgPPM = calculateAveragePPM();

    // Determine the target hall sensor based on the average CO2 ppm level
    int targetSensor = determineTargetSensor(avgPPM);

    // Move the motor to the target hall sensor
    moveMotorToTargetSensor(targetSensor);

    readingIndex = 0;
  }

  delay(10000); // wait 10 seconds
}

// Calculate the average CO2 ppm level from the stored readings
int calculateAveragePPM() {
  int sum = 0;
  for (int i = 0; i < maxReadings; i++) {
    sum += ppmReadings[i];
  }
  return sum / maxReadings;
}

// Determine the target hall sensor based on the average CO2 ppm level
int determineTargetSensor(int avgPPM) {
  for (int i = 0; i < 5; i++) {
    if (avgPPM >= ppmRanges[i][0] && avgPPM <= ppmRanges[i][1]) {
      return i;
    }
  }
  return 0; // default to the first sensor if the avgPPM is out of range
}

// Move the motor to the target hall sensor
void moveMotorToTargetSensor(int targetSensor) {
  int currentSensor = getCurrentSensor();
  if (currentSensor != targetSensor) {
    int direction = (targetSensor > currentSensor) ? 1 : -1;
    while (currentSensor != targetSensor) {
      moveMotor(direction);
      currentSensor = getCurrentSensor();
    }
    stopMotor();
  }
}

// Get the current hall sensor
int getCurrentSensor() {
  for (int i = 0; i < 5; i++) {
    if (digitalRead(hallSensors[i]) == LOW) {
      return i;
    }
  }
  return 0; // default to the first sensor if no sensor is active
}

// Move the motor in the specified direction
void moveMotor(int direction) {
  digitalWrite(motorEnable, HIGH);
  if (direction == 1) {
    digitalWrite(motorInput1, HIGH);
    digitalWrite(motorInput2, LOW);
  } else {
    digitalWrite(motorInput1, LOW);
    digitalWrite(motorInput2, HIGH);
  }
}

// Stop the motor
void stopMotor() {
  digitalWrite(motorEnable, LOW);
}