Published May 5, 2020 © GPL3+

Wireless alert bell using Adafruit IO

Uses a single button to trigger 2 types of alert via the internet.

IntermediateShowcase (no instructions)1,727

Things used in this project

Hardware components

Espressif ESP8266 ESP-01

NodeMCU ESP8266 Breakout Board

Arduino UNO

Resistor 221 ohm

Resistor 47.5k ohm

DIYables LED

Buzzer

Tactile Switch, Top Actuated

DIYables Jumper Wires

Battery Holder, AA x 2

AA Batteries

Software apps and online services

Arduino IDE

Adafruit IO

Story

In this project I have used an ESP8266-01 to trigger alerts to the desired destination(buzzer connected to NodeMCU) using the internet via MQTT Protocol. The alert button can be operated from any remote locations provided both the ESP8266's have internet access via WiFi. A single button does the following functions.

1. When the button is pressed for a short duration(between 500 to 1500 milliseconds)- Triggers alert by ringing the buzzer for every short duration (alert-1).

2. When the button is pressed for long duration(more than 1500 milliseconds)-Triggers alert by keeping buzzer high(alert-2).

3. When the button is just clicked(less than 500ms)- Disable alerts.

MQTT Protocol

MQTT is a lightweight messaging protocol that uses publish/subscribe operations to exchange data between clients and the server. I have used this protocol since it is ideal for developing "Internet of things" project as it is faster, uses less data packets and is designed for constrained devices.

The MQTT broker acts as a medium of information exchange between the clients(NodeMCU and ESP8266-01) based on the interested topic.The topic I have used in this project is "alert". Since the ESP8266-01 has to send the status of the pushbutton, it "publishes"data on the topic "alert" to the MQTT broker. On the receiver end, the NodeMCU is "subscribed" to the same topic so it receives the button status. Based on the status of the button received, the buzzer attached to NodeMCU operates. I have used Adafruit io's MQTT broker as it is free and easy to implement. For this, we need to setup the dashboard on the Adafruit io.

Setting up the Adafruit Dashboard

To create a new dashboard, I have followed the steps as provided by the adafruit io.

1. After the dashboard is created, you will see a blank screen. To add a block, you need to click on the "+" icon.

Initial dashboard setup

2. Select the Gauge block.

Select the Gauge block

3. Create a new feed as "alert" and select the feed. The ESP8266's sketch is programmed to send data to the same feed.

1 / 2 • create a new feed as 'alert'

4. Enter the min and max value of the gauge as '1' and '3'. Value '1' is to disable alerts, ' 2 ' is to trigger alert-1 and '3' is to trigger alert-2.

Enter the min and max value of the gauge

5. The gauge is finally set up and you will be able to see it in your dashboard screen.

Final Dashboard setup

To "publish " and "subscribe" the data to/from the gauge, we need to upload the sketch to the NodeMCU and ESP8266-01.

Uploading the sketch

The sketch for both the ESP8266's have been modified from the example sketch(examples-> Adafruit MOTT Library-> mqtt_esp8266 )

If you are new to the ESP8266, make sure to inastall the ESP8266 board on the Arduino IDE. I have followed the steps given here before uploading my first sketch on it.

The sketch requires the following libraries which you can install from the Arduino IDE(tools->Library Manager) itself.

1. Adafruit IO Arduino (by Adafruit)

2. Adafruit MQTT Library (by Adafruit)

3. ArduinoHttpClient (by arduino)

Before uploading the sketch to both the ESP8266 modules, make sure to enter the SSID, Password, Username, Aio key to the sketch.

A separate SSID and Password can also be assigned to both the ESP8266's as they operate via the internet.

The username and aio key can be obtained from the top right corner of the adafruit dashboard. Copy the same in the IDE sketch.

1 / 2

Uploading the sketch to the ESP8266-01 could be a little tricky. I have used the Arduino UNO to program the ESP8266-01. Make the connections as given below.

Select the board in the IDE as "Generic ESP8266 module" and upload the sketch.

If the sketch fails to upload, then re-plug either the 3.3V or ground and try to upload the sketch again. I would suggest the following tutorial given here if the problem persists.

For the NodeMCU, the sketch is comparatively easy to upload. Just select the board as "NodeMCU 1.0(ESP-12E Module)" with the correct COM port and upload the NodeMCU sketch.

Final Execution

After the Following sketch has been uploaded on both the ESP8266 Modules, make the circuit connections as given in the schematics.

You can use the 3.3V of the arduino to power up the ESP8266-01.I have used a separate 3V supply from 2 AA battery for the ESP8266-01 as it makes the circuit portable, but the battery drained out fast so in the video I have used a partially charged 3.7V li-ion battery(not recommended). I would suggest you to use voltage regulator while using the Li-po/Li-ion batteries (check here for more info).

The led connected to the Pin-2 of ESP8266-01 provides status regarding button press and connection to the MQTT. Initially the LED will blink for one second to denote the connection to the MQTT is successful. If the button is pressed to trigger alert-1(less than 500 and 1500 milliseconds), then the LED blinks at once and if the button is pressed for alert-2(greater than 1.5 sec), then the LED glows until it is turned off(when button is just clicked).

ESP8266-01(transmitter)

You will notice that the gauge value on the dashboard changes upon pressing the button on the ESP8266-01, it means that the communication on the transmitter side is successful.

If the gauge value changes, then the NodeMCU receives it and rings the buzzer corresponding to the button pressed.The built-in LED of the NodeMCU also provides an indication regarding the connection to the MQTT broker. Initially when the NodeMCU is turned on, the led becomes HIGH indicating it is connecting and when the LED turns LOW, it indicates the connection to the broker is successful.

NodeMCU (Receiver)

Code

/***************************************************
  Adafruit MQTT Library ESP8266 Example

  Must use ESP8266 Arduino from:
    https://github.com/esp8266/Arduino

  Works great with Adafruit's Huzzah ESP board & Feather
  ----> https://www.adafruit.com/product/2471
  ----> https://www.adafruit.com/products/2821

  Adafruit invests time and resources providing this open source code,
  please support Adafruit and open-source hardware by purchasing
  products from Adafruit!

  Written by Tony DiCola for Adafruit Industries.
  MIT license, all text above must be included in any redistribution
 ****************************************************/
#include <ESP8266WiFi.h>
#include "Adafruit_MQTT.h"
#include "Adafruit_MQTT_Client.h"

/************************* WiFi Access Point *********************************/

#define WLAN_SSID       "your SSID"
#define WLAN_PASS       "enter Password "

/************************* Adafruit.io Setup *********************************/

#define AIO_SERVER      "io.adafruit.com"
#define AIO_SERVERPORT  1883                   // use 8883 for SSL
#define AIO_USERNAME    "Enter Username"
#define AIO_KEY         "Enter Aio key"

/************ Global State (you don't need to change this!) ******************/

// Create an ESP8266 WiFiClient class to connect to the MQTT server.
WiFiClient client;
// or... use WiFiFlientSecure for SSL
//WiFiClientSecure client;

// Setup the MQTT client class by passing in the WiFi client and MQTT server and login details.
Adafruit_MQTT_Client mqtt(&client, AIO_SERVER, AIO_SERVERPORT, AIO_USERNAME, AIO_KEY);

/****************************** Feeds ***************************************/


// modified by Shubham Santosh
// publish to the feed 'alert' 
Adafruit_MQTT_Publish alertbutton = Adafruit_MQTT_Publish(&mqtt, AIO_USERNAME "/feeds/alert");

/*************************** Sketch Code ************************************/

// Bug workaround for Arduino 1.6.6, it seems to need a function declaration
// for some reason (only affects ESP8266, likely an arduino-builder bug).
void MQTT_connect();
void setup() {

  pinMode(0,INPUT);            // reads button press
  pinMode(2,OUTPUT);         //connected to LED providing status
  Serial.begin(115200);
  delay(10);
  Serial.println(F("Adafruit MQTT demo"));

  // Connect to WiFi access point.
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WLAN_SSID);

  WiFi.begin(WLAN_SSID, WLAN_PASS);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();
  Serial.println("WiFi connected");
  Serial.println("IP address: "); Serial.println(WiFi.localIP());

}
int newstatus=0,buttonstats=1;
void loop() {
  // Ensure the connection to the MQTT server is alive (this will make the first
  // connection and automatically reconnect when disconnected).  See the MQTT_connect
  // function definition further below.
  MQTT_connect();
  // this is our 'wait for incoming subscription packets' busy subloop

 
  if(digitalRead(0)==HIGH)
  {
   buttonstats= readbutton();
  if(buttonstats==2)
  {
  Serial.println("Alert-1 triggered");
  digitalWrite(2,HIGH);
  delay(500);
  digitalWrite(2,LOW);
  }
  else if(buttonstats==3)
  {
  Serial.println("Alert-2 triggered");
  digitalWrite(2,HIGH);
  }
  else
  {
  Serial.println("ALerts Disabled");
  digitalWrite(2,LOW);
  }
  }
  if(newstatus!=buttonstats)      //if a change of button state is detected
  {
  Serial.print(F("\nSending button status "));
   // Now we can publish stuff!
  if (! alertbutton.publish(buttonstats)) {
    Serial.println(F("Failed"));
  } else {
    Serial.println(F("OK!"));
  }
  newstatus=buttonstats;
  delay(1000);
  }
delay(50);
  // ping the server to keep the mqtt connection alive
  // NOT required if you are publishing once every KEEPALIVE seconds
  /*
  if(! mqtt.ping()) {
    mqtt.disconnect();
  }
  */
}

// Function to connect and reconnect as necessary to the MQTT server.
// Should be called in the loop function and it will take care if connecting.
void MQTT_connect() {
  int8_t ret;

  // Stop if already connected.
  if (mqtt.connected()) {
    return;
  }

  Serial.print("Connecting to MQTT... ");

  uint8_t retries = 3;
  while ((ret = mqtt.connect()) != 0) { // connect will return 0 for connected
       Serial.println(mqtt.connectErrorString(ret));
       Serial.println("Retrying MQTT connection in 5 seconds...");
       mqtt.disconnect();
       delay(5000);  // wait 5 seconds
       retries--;
       if (retries == 0) {
         // basically die and wait for WDT to reset me
         while (1);
       }
  }
  Serial.println("MQTT Connected!");
  digitalWrite(2,HIGH);
  delay(1000);
  digitalWrite(2,LOW);
}
int readbutton()          // reads the button status
{
int alert1time=1500;
float times=0;
  while(digitalRead(0)==HIGH)
  {
    times=times+50;
        delay(50);
    }
    digitalWrite(2,LOW);
   if (times>500  and times<alert1time)
   return(2);
   else if(times>alert1time)
   return(3);
   else if(times<500) 
   return(1);
}

/***************************************************
  Adafruit MQTT Library ESP8266 Example

  Must use ESP8266 Arduino from:
    https://github.com/esp8266/Arduino

  Works great with Adafruit's Huzzah ESP board & Feather
  ----> https://www.adafruit.com/product/2471
  ----> https://www.adafruit.com/products/2821

  Adafruit invests time and resources providing this open source code,
  please support Adafruit and open-source hardware by purchasing
  products from Adafruit!

  Written by Tony DiCola for Adafruit Industries.
  MIT license, all text above must be included in any redistribution
 ****************************************************/
#include <ESP8266WiFi.h>
#include "Adafruit_MQTT.h"
#include "Adafruit_MQTT_Client.h"

/************************* WiFi Access Point *********************************/

#define WLAN_SSID       "enter SSID"
#define WLAN_PASS       "enter Password"

/************************* Adafruit.io Setup *********************************/

#define AIO_SERVER      "io.adafruit.com"
#define AIO_SERVERPORT  1883                   // use 8883 for SSL
#define AIO_USERNAME    "enter username"
#define AIO_KEY         "enter aio key"

/************ Global State (you don't need to change this!) ******************/

#define buzzerpin D1
// Create an ESP8266 WiFiClient class to connect to the MQTT server.
WiFiClient client;
// or... use WiFiFlientSecure for SSL
//WiFiClientSecure client;

// Setup the MQTT client class by passing in the WiFi client and MQTT server and login details.
Adafruit_MQTT_Client mqtt(&client, AIO_SERVER, AIO_SERVERPORT, AIO_USERNAME, AIO_KEY);

/****************************** Feeds ***************************************/

// Notice MQTT paths for AIO follow the form: <username>/feeds/<feedname>
//modified by Shubham Santosh
// Setup a feed called 'alert' for subscribing to changes.
Adafruit_MQTT_Subscribe buzzer = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/alert");

/*************************** Sketch Code ************************************/

// Bug workaround for Arduino 1.6.6, it seems to need a function declaration
// for some reason (only affects ESP8266, likely an arduino-builder bug).
void MQTT_connect();

void setup() {
  Serial.begin(115200);
  pinMode(buzzerpin,OUTPUT);
  pinMode(LED_BUILTIN,OUTPUT);
  delay(10);

  Serial.println(F("MQTT SOS Receiver"));

  // Connect to WiFi access point.
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WLAN_SSID);

  WiFi.begin(WLAN_SSID, WLAN_PASS);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();

  Serial.println("WiFi connected");
  Serial.println("IP address: "); Serial.println(WiFi.localIP());

  // Setup MQTT subscription for alert feed.
  mqtt.subscribe(&buzzer);
}
int value;

void loop() {
  // Ensure the connection to the MQTT server is alive (this will make the first
  // connection and automatically reconnect when disconnected).  See the MQTT_connect
  // function definition further below.
  MQTT_connect();

  // this is our 'wait for incoming subscription packets' busy subloop
  // try to spend your time here

  Adafruit_MQTT_Subscribe *subscription;
  while ((subscription = mqtt.readSubscription(200))) {
    if (subscription == &buzzer) {
      Serial.print(F("Got: "));
      value=atoi((char *)buzzer.lastread);
      Serial.println(value);
    }
  }
    if(value==2)    // triggers alert-1
      {
      digitalWrite(buzzerpin,HIGH);
      digitalWrite(LED_BUILTIN,LOW);
      delay(500);
      digitalWrite(buzzerpin,LOW);
      digitalWrite(LED_BUILTIN,HIGH);
      }
    else if(value==3)     // triggers alert-2
    {
    digitalWrite(buzzerpin,HIGH);
    digitalWrite(LED_BUILTIN,LOW);
    }
    else            // disable alerts
    {
    digitalWrite(buzzerpin,LOW);
    digitalWrite(LED_BUILTIN,HIGH);
}
}
// Function to connect and reconnect as necessary to the MQTT server.
// Should be called in the loop function and it will take care if connecting.
void MQTT_connect() {
  int8_t ret;

  // Stop if already connected.
  if (mqtt.connected()) {
    return;
  }

  Serial.print("Connecting to MQTT... ");

  uint8_t retries = 3;
  while ((ret = mqtt.connect()) != 0) { // connect will return 0 for connected
       Serial.println(mqtt.connectErrorString(ret));
       Serial.println("Retrying MQTT connection in 5 seconds...");
       mqtt.disconnect();
       delay(5000);  // wait 5 seconds
       retries--;
       if (retries == 0) {
         // basically die and wait for WDT to reset me
         while (1);
       }
  }
  Serial.println("MQTT Connected!");
  digitalWrite(LED_BUILTIN,LOW);
  delay(1000);
 digitalWrite(LED_BUILTIN,HIGH);   // to show MQTT is connected
}

Credits

Shubham Santosh

13 projects • 101 followers

I am a 25 yo electronic enthusiast.

Wireless alert bell using Adafruit IO

Things used in this project

Hardware components

Software apps and online services

Story

MQTT Protocol

Setting up the Adafruit Dashboard

Uploading the sketch

Final Execution

Schematics

ESP8266-01 Schematic

NodeMCU Schematic

Code

ESP8266-01 Code

NodeMCU Code

Credits

Shubham Santosh

Comments

Embed the widget on your own site

Wireless alert bell using Adafruit IO

Wireless alert bell using Adafruit IO

Things used in this project

Hardware components

Software apps and online services

Story

MQTT Protocol

Setting up the Adafruit Dashboard

Uploading the sketch

Final Execution

Schematics

ESP8266-01 Schematic

NodeMCU Schematic

Code

ESP8266-01 Code

NodeMCU Code

Credits

Shubham Santosh

Comments

Related channels and tags