IoT Smart Garden

// Author: Gustavo Ortenzi
// Date: 11/October/2017


// Including Libraries for project
#include <ESP8266WiFi.h>
#include <Adafruit_Sensor.h>

//CAYENNE_DEBUG
#define CAYENNE_PRINT Serial
#include <CayenneMQTTESP8266.h>

// Cayenne authentication info. This should be obtained from the Cayenne Dashboard.
char username[] = "Add your Cayenne Username here";
char password[] = "Add your Cayenne PAssword here";
char clientID[] = "Add your Cayenne ID here";

// WiFi network info.
char ssid[] = "Add your SSID here";
char wifiPassword[] = "Add your SSID password here";

// Deep Sleep Parameters (~16minutos)
uint32_t sleep_time_s = 960 * 1000000;

WiFiClient client;

// Function Prototypes

int average(void);

// Pins Declaration
  const int LM35SW = 13;
  const int VbatSW = 2;
  const int HumSW = 12;

// Average Function
// Math the average value of the analog converter
// Return: AD Value (0 - 1023)
int average(void)
{
  int analogico = 0;
  for ( int i = 0; i < 10; i++) {
    analogico += analogRead(A0);
    delay (500);
  }
  analogico = analogico / 10;
  return analogico;
}

void setup() {

  // Initializing pins
  pinMode(LM35SW, OUTPUT);
  pinMode(VbatSW, OUTPUT);
  pinMode(HumSW, OUTPUT);
  digitalWrite(LM35SW, HIGH);
  digitalWrite(VbatSW, HIGH);
  digitalWrite(HumSW, HIGH);
  delay(10);
  
  //Configurao da UART
  Serial.begin(115200);

    // Connecting to WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, wifiPassword);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
   
   // Printing the ESP IP address
  Serial.println(WiFi.localIP());
  
  // Initializing Cayenne
  Cayenne.begin(username, password, clientID);
 
}
 
  void loop() {
   
  Cayenne.loop();

  Serial.println("");
  Serial.println("-------Inicio--------");

// Temperatura LM35
  digitalWrite(LM35SW, LOW);
  digitalWrite(VbatSW, HIGH);
  digitalWrite(HumSW, HIGH);
  delay(400);
  float temp_celsius;
  temp_celsius = 330 * ( (float)average() / 1023);
  Serial.println("");
  Serial.print("Temperatura:");
  Serial.print(temp_celsius);
  Serial.print("C");
// ************************************************************
// Umidade Solo
  digitalWrite(LM35SW, HIGH);
  digitalWrite(VbatSW, HIGH);
  digitalWrite(HumSW, LOW);
  delay(400);
  int umidade = 0;
  float umidade_percent = 0;
  umidade_percent = 100 * ( (1023 - (float)average()) / 1023);
  umidade = (int)umidade_percent;
  Serial.println("");
  Serial.print("Umidade Percentual Solo:");
  Serial.print(umidade);
  Serial.print("%");
//***************************************************************
// Tenso Bateria
  digitalWrite(LM35SW, HIGH);
  digitalWrite(VbatSW, LOW);
  digitalWrite(HumSW, HIGH);
  delay(400);
  float bateria;
  bateria = 33 * ( (float)average() / 10230 );
  Serial.println("");
  Serial.print("Bateria:");
  Serial.print(bateria);
  Serial.print("Volts");
   
   // Desliga Sensores
   digitalWrite(LM35SW, HIGH);
   digitalWrite(VbatSW, HIGH);
   digitalWrite(HumSW, HIGH);
   delay(300);
  
  Cayenne.celsiusWrite(0, temp_celsius);
  Cayenne.virtualWrite(1, umidade);
  Cayenne.virtualWrite(2, bateria);
  
  ESP.deepSleep(sleep_time_s);

}