Published February 6, 2021 © GPL3+

NodeMCU ESP8266 Alexa App Voice Control Smart Home System

In this IoT project, I have shown how to make IoT based Smart Home Automation using Amazon Alexa & NodeMCU to control 4 home appliances.

IntermediateFull instructions provided10 hours6,894

NodeMCU ESP8266 Alexa App Voice Control Smart Home System

Things used in this project

Hardware components

NodeMCU ESP8266 Breakout Board

Seeed Studio Grove - 2-Channel SPDT Relay

Software apps and online services

Arduino IDE

Amazon Alexa Alexa Skills Kit

Hand tools and fabrication machines

Soldering iron (generic)

Story

IoT based Smart Home Automation Using Amazon Alexa & NodeMCU to control 4 home appliances from the manual switch & Amazon Alexa App.

1 / 2

If the internet is not available, then you can control the home appliances from manual switches. During the article, I have shown all the steps to make this smart home system.

This NodeMCU Alexa control smart relay has the following features:

1. Control home appliances with voice commands using Alexa

2. Control home appliances with manual switches.

3. Monitor real-time feedback in the Alexa App.

4. Control home appliances manually without internet.

Required Components:

1 / 2

1. NodeMCU board

2. 4-channel SPDT 5V Relay Module

3. Alexa Echo Dot (Optional)

4. Manual Switches

Required Components for the PCB

1. Relays 5v (SPDT) (4 no)

2. BC547 Transistors (4 no)

3. PC817 Optocuplors (4 no)

4. 510-ohm 0.25-watt Resistor (4 no) (R1 - R4)

5. 1k 0.25-watt Resistors (5 no) (R5 - R9)

6. LED 5-mm (5 no)

7. 1N4007 Diodes (4 no) (D1 - D4)

8. Push Buttons (4 no)

9. Terminal Connectors

10. 5V DC supply

Required Software:

1. Arduino IDE

2. Amazon Alexa App

Circuit Diagram of the ESP32 Project:

This is the complete circuit diagram for this home automation project. I have explained the circuit in the tutorial video.

The circuit is very simple, I have used the GPIO pins D1, D2, D5 & D6 to control the 4 relays.

And the GPIO pins SD3, D3, D7 & RX connected with switches to control the 4 relays manually.

I have used the INPUT_PULLUP function in Arduino IDE instead of using the pull-up resistors.

I have used a 5V mobile charger to supply the smart relay module.

Control Relays With Voice Commands Using Alexa

1 / 2

If the NodeMCU is connected with the WiFi, then you can control the home appliances from Amazon Alexa App and also from the manual switches.

You can control, monitor the real-time status of the relays in the Alexa App from anywhere in the world.

You don't need an Alexa device for this home automation project.

Control Relays Using Switches:

1 / 3

If the WiFi is not available, you can control the relays from the manual switches.

The NodeMCU will check for the WiFi after every 5 seconds. When the WiFi is available, the NodeMCU will automatically connect with the WiFi.

Please refer to the circuit diagram to connect the manual switches.

Create an Account in Sinric

First, visit https://sinric.com/login

Click on Register.

You have to create an account in Snric.

Then log in to Sinric Account.

You will get an API key which will be required in the code.

Now click on Add.

Add Devices in Sinric

Then enter a name for the device. Alexa will identify the device with that name.

Select the type as Switch.

Click on Save.

In this way add 4 devices in Sinric. Each device will get a unique device ID.

Program NodeMCU Using Arduino IDE

First, you have to install the required libraries. I have shared all the links in the code.

Then enter the API key & WiFi credentials

#define MyApiKey "----------------"
#define MySSID "--------"
#define MyWifiPassword "------"

Then enter the device IDs for each device.

String device_ID_1 = "------------------------";
String device_ID_2 = "------------------------";
String device_ID_3 = "------------------------";
String device_ID_4 = "------------------------";

After that select the NodeMCU 1.0 (ESP-12E module) board and the PORT. Then click on the upload button.

Download and Install the Amazon Alexa App.

Download and install the Amazon Alexa App from the Google play store or App Store.

Configure the Alexa App for This Smart Home System

Go to "More", then select "Skills & Games"

Search for Sinric and tap on "Sinric".

Tap on "ENABLE TO USE"

Connecting Devices With Alexa

Goto Alexa and tap on "DISCOVER DEVICES".

It will take a minute to add devices. During this time the NodeMCU should be connected with the WiFi.

Tap on "Devices", and tap on "Switch" to see all the devices.

Design the PCB for This Smart Home System

1 / 2

To make the circuit compact and give a professional look, I have designed the PCB after testing all the features of the smart relay module.

You can download the PCB Gerber file of this home automation project from the following link:

https://drive.google.com/uc?export=download&id=1Jx4D_DSV_ei1y0a82AbtxbsNhy8sjCmY

Order the PCB

After downloading the Garber file you can easily order the PCB

1. Visit https://jlcpcb.com and Sign in / Sign up

2. Click on the QUOTE NOW button.

3. Click on the "Add your Gerber file" button. Then browse and select the Gerber file you have downloaded.

Uploading the Gerber File and Set the Parameters

4. Set the required parameter like Quantity, PCB masking color, etc.

5. After selecting all the Parameters for PCB click on SAVE TO CART button.

Select Shipping Address and Payment Mode

6. Type the Shipping Address.

7. Select the Shipping Method suitable for you.

8. Submit the order and proceed with the payment.

You can also track your order from the JLCPCB.com.

My PCBs took 2 days to get manufactured and arrived within a week using the DHL delivery option.

PCBs were well packed and the quality was really good at this affordable price.

Solder All the Components on PCB

After that, I have soldered all the components as per the circuit diagram.

Then connect the NodeMCU board with the PCB.

Testing the NodeMCU Home Automation Circuit

After uploading the code, if the NodeMCU connects with the WiFi, the blue LED will turn on.

Then you can control the relay module from Amazon Alexa App.

Connect the Home Appliances with Relay Module

Connect the 4 home appliances as per the circuit diagram. Please take proper safety precautions while working with high voltage.

Connect 5-volt DC supply with the PCB. (I have used my old mobile charger)

Turn ON the Supply

Turn on the 110V/230V supply and 5V DC supply.

Finally!! the Alexa Home Automation System Is Ready

1 / 2

Now you can control your home appliances in a smart way.

I hope you have liked this Alexa home automation project. I have shared all the required information for this project. I will really appreciate it if you share your valuable feedback.

Also if you have any query please write in the comment section. Thank you & Happy Learning.

Code

Code for NodeMCU & Alexa Controlled Relay with Manual Switch

/**********************************************************************************
 *  TITLE: NodeMCU Alexa Home Automation with Sinric | Manual & WiFi control 4-Relays with feedback
 *  Click on the following links to learn more. 
 *  YouTube Video: https://youtu.be/Sx9akwBwK4g
 *  Related Blog : https://iotcircuithub.com/esp8266-projects/
 *  by Subhajit (Tech StudyCell)
 *  Preferences--> Aditional boards Manager URLs : 
 *  https://dl.espressif.com/dl/package_esp32_index.json, http://arduino.esp8266.com/stable/package_esp8266com_index.json
 *  
 *  Download Board ESP8266: https://github.com/esp8266/Arduino
 *  Download the libraries
 *  ArduinoJson Library: https://github.com/bblanchon/ArduinoJson/tags
 *  arduinoWebSockets Library: https://github.com/Links2004/arduinoWebSockets/releases
 *  AceButton Library: https://github.com/bxparks/AceButton
 *  Install the libraries at Arduino IDE -> Sketch - Include Library -> Add Zip Library
 **********************************************************************************/
 
#include <Arduino.h>
#include <ESP8266WiFi.h>
#include <ESP8266WiFiMulti.h>
#include <WebSocketsClient.h>
#include <ArduinoJson.h>
#include <StreamString.h>

#include <AceButton.h>
using namespace ace_button;
ESP8266WiFiMulti WiFiMulti;
WebSocketsClient webSocket;
WiFiClient client;

#define MyApiKey "---------------------" // TODO: Change to your sinric API Key. Your API Key is displayed on sinric.com dashboard
#define MySSID "------" // TODO: Change to your Wifi network SSID
#define MyWifiPassword "-------" // TODO: Change to your Wifi network password

#define HEARTBEAT_INTERVAL 300000 // 5 Minutes 

uint64_t heartbeatTimestamp = 0;
bool isConnected = false;

String device_ID_1 = "------------------------";
String device_ID_2 = "------------------------";
String device_ID_3 = "------------------------";
String device_ID_4 = "------------------------";

// define the GPIO connected with Relays and switches

// Relays
#define RelayPin1 D1  //D1
#define RelayPin2 D2  //D2
#define RelayPin3 D5  //D5
#define RelayPin4 D6  //D6

// Switches
#define SwitchPin1 10  //SD3
#define SwitchPin2 D3   //D3 
#define SwitchPin3 D7  //D7
#define SwitchPin4 3   //RX

//WiFi Status LED
#define wifiLed    D0   //D0


ButtonConfig config1;
AceButton button1(&config1);
ButtonConfig config2;
AceButton button2(&config2);
ButtonConfig config3;
AceButton button3(&config3);
ButtonConfig config4;
AceButton button4(&config4);


void handleEvent1(AceButton*, uint8_t, uint8_t);
void handleEvent2(AceButton*, uint8_t, uint8_t);
void handleEvent3(AceButton*, uint8_t, uint8_t);
void handleEvent4(AceButton*, uint8_t, uint8_t);

void setPowerStateOnServer(String deviceId, String value);

// deviceId is the ID assgined to your smart-home-device in sinric.com dashboard. Copy it from dashboard and paste it here

void turnOn(String deviceId) {
  if (deviceId == device_ID_1) // Device ID of 1st device
  {
    Serial.print("Turn on device id: ");
    Serial.println(deviceId);
    digitalWrite(RelayPin1, LOW);
  }
  if (deviceId == device_ID_2) // Device ID of 2nd device
  {
    Serial.print("Turn on device id: ");
    Serial.println(deviceId);
    digitalWrite(RelayPin2, LOW);
  }
  if (deviceId == device_ID_3) // Device ID of 3rd device
  {
    Serial.print("Turn on device id: ");
    Serial.println(deviceId);
    digitalWrite(RelayPin3, LOW);
  }
  if (deviceId == device_ID_4) // Device ID of 4th device
  {
    Serial.print("Turn on device id: ");
    Serial.println(deviceId);
    digitalWrite(RelayPin4, LOW);
  }
}

void turnOff(String deviceId) {
  if (deviceId == device_ID_1) // Device ID of 1st device
  {
    Serial.print("Turn off Device ID: ");
    Serial.println(deviceId);
    digitalWrite(RelayPin1, HIGH);
  }
  if (deviceId == device_ID_2) // Device ID of 2nd device
  {
    Serial.print("Turn off Device ID: ");
    Serial.println(deviceId);
    digitalWrite(RelayPin2, HIGH);
  }
  if (deviceId == device_ID_3) // Device ID of 3rd device
  {
    Serial.print("Turn off Device ID: ");
    Serial.println(deviceId);
    digitalWrite(RelayPin3, HIGH);
  }
  if (deviceId == device_ID_4) // Device ID of 4th device
  {
    Serial.print("Turn off Device ID: ");
    Serial.println(deviceId);
    digitalWrite(RelayPin4, HIGH);
  }
}

void webSocketEvent(WStype_t type, uint8_t * payload, size_t length) {
  switch (type) {
    case WStype_DISCONNECTED:
      isConnected = false;
      WiFiMulti.addAP(MySSID, MyWifiPassword);
      Serial.printf("[WSc] Webservice disconnected from sinric.com!\n");
      break;
    case WStype_CONNECTED: {
        isConnected = true;
        Serial.printf("[WSc] Service connected to sinric.com at url: %s\n", payload);
        Serial.printf("Waiting for commands from sinric.com ...\n");
      }
      break;
      case WStype_TEXT: {
        Serial.printf("[WSc] get text: %s\n", payload);

        #if ARDUINOJSON_VERSION_MAJOR == 5
                DynamicJsonBuffer jsonBuffer;
                JsonObject& json = jsonBuffer.parseObject((char*)payload);
        #endif
        #if ARDUINOJSON_VERSION_MAJOR == 6
                DynamicJsonDocument json(1024);
                deserializeJson(json, (char*) payload);
        #endif
        String deviceId = json ["deviceId"];
        String action = json ["action"];

        if (action == "setPowerState") { // Switch or Light
          String value = json ["value"];
          if (value == "ON") {
            turnOn(deviceId);
          } else {
            turnOff(deviceId);
          }
        }
        else if (action == "test") {
          Serial.println("[WSc] received test command from sinric.com");
        }
      }
      break;
    case WStype_BIN:
      Serial.printf("[WSc] get binary length: %u\n", length);
      break;
  }
}

void setup() {
  Serial.begin(9600);

  WiFiMulti.addAP(MySSID, MyWifiPassword);
  Serial.println();
  Serial.print("Connecting to Wifi: ");
  Serial.println(MySSID);

  // Waiting for Wifi connect
  if (WiFiMulti.run() != WL_CONNECTED) {
    delay(500);
    Serial.print("Connecting...");
  }
  if (WiFiMulti.run() == WL_CONNECTED) {
    Serial.println("");
    Serial.print("WiFi connected. ");
    Serial.print("IP address: ");
    Serial.println(WiFi.localIP());
  }

  pinMode(SwitchPin1, INPUT_PULLUP);
  pinMode(SwitchPin2, INPUT_PULLUP);
  pinMode(SwitchPin3, INPUT_PULLUP);
  pinMode(SwitchPin4, INPUT_PULLUP);

  pinMode(RelayPin1, OUTPUT);
  pinMode(RelayPin2, OUTPUT);
  pinMode(RelayPin3, OUTPUT);
  pinMode(RelayPin4, OUTPUT);

  pinMode(wifiLed, OUTPUT);

  //During Starting all Relays should TURN OFF
  digitalWrite(RelayPin1, HIGH);
  digitalWrite(RelayPin2, HIGH);
  digitalWrite(RelayPin3, HIGH);
  digitalWrite(RelayPin4, HIGH);
  
  //During Starting WiFi LED should TURN OFF
  digitalWrite(wifiLed, HIGH);

  config1.setEventHandler(button1Handler);
  config2.setEventHandler(button2Handler);
  config3.setEventHandler(button3Handler);
  config4.setEventHandler(button4Handler);
  
  button1.init(SwitchPin1);
  button2.init(SwitchPin2);
  button3.init(SwitchPin3);
  button4.init(SwitchPin4);

  // server address, port and URL
  webSocket.begin("iot.sinric.com", 80, "/");

  // event handler
  webSocket.onEvent(webSocketEvent);
  webSocket.setAuthorization("apikey", MyApiKey);

  // try again every 5000ms if connection has failed
  webSocket.setReconnectInterval(5000);   // If you see 'class WebSocketsClient' has no member named 'setReconnectInterval' error update arduinoWebSockets
}

void loop() {

  if (WiFiMulti.run() != WL_CONNECTED)
  {  
    //  Serial.println("Not Connected");
    digitalWrite(wifiLed, HIGH);
  }
  else
  {
    //Serial.println(" Connected");
    digitalWrite(wifiLed, LOW);
    webSocket.loop();
  }

  button1.check();
  button2.check();
  button3.check();
  button4.check();

  if (isConnected) {
    uint64_t now = millis();

    // Send heartbeat in order to avoid disconnections during ISP resetting IPs over night. Thanks @MacSass
    if ((now - heartbeatTimestamp) > HEARTBEAT_INTERVAL) {
      heartbeatTimestamp = now;
      webSocket.sendTXT("H");
    }
  }
}

void setPowerStateOnServer(String deviceId, String value) {
  #if ARDUINOJSON_VERSION_MAJOR == 5
    DynamicJsonBuffer jsonBuffer;
    JsonObject& root = jsonBuffer.createObject();
  #endif
  #if ARDUINOJSON_VERSION_MAJOR == 6
    DynamicJsonDocument root(1024);
  #endif
  
    root["deviceId"] = deviceId;
    root["action"] = "setPowerState";
    root["value"] = value;
    StreamString databuf;
  #if ARDUINOJSON_VERSION_MAJOR == 5
    root.printTo(databuf);
  #endif
  #if ARDUINOJSON_VERSION_MAJOR == 6
    serializeJson(root, databuf);
  #endif
  webSocket.sendTXT(databuf);
}

void button1Handler(AceButton* button, uint8_t eventType, uint8_t buttonState) {
  Serial.println("EVENT1");
  switch (eventType) {
    case AceButton::kEventPressed:
      Serial.println("kEventPressed");
      setPowerStateOnServer(device_ID_1, "ON");
      digitalWrite(RelayPin1, LOW);
      break;
    case AceButton::kEventReleased:
      Serial.println("kEventReleased");
      setPowerStateOnServer(device_ID_1, "OFF");
      digitalWrite(RelayPin1, HIGH);
      break;
  }
}

void button2Handler(AceButton* button, uint8_t eventType, uint8_t buttonState) {
  Serial.println("EVENT2");
  switch (eventType) {
    case AceButton::kEventPressed:
      Serial.println("kEventPressed");
      setPowerStateOnServer(device_ID_2, "ON");
      digitalWrite(RelayPin2, LOW);
      break;
    case AceButton::kEventReleased:
      Serial.println("kEventReleased");
      setPowerStateOnServer(device_ID_2, "OFF");
      digitalWrite(RelayPin2, HIGH);
      break;
  }
}

void button3Handler(AceButton* button, uint8_t eventType, uint8_t buttonState) {
  Serial.println("EVENT3");
  switch (eventType) {
    case AceButton::kEventPressed:
      Serial.println("kEventPressed");
      setPowerStateOnServer(device_ID_3, "ON");
      digitalWrite(RelayPin3, LOW);
      break;
    case AceButton::kEventReleased:
      Serial.println("kEventReleased");
      setPowerStateOnServer(device_ID_3, "OFF");
      digitalWrite(RelayPin3, HIGH);
      break;
  }
}

void button4Handler(AceButton* button, uint8_t eventType, uint8_t buttonState) {
  Serial.println("EVENT4");
  switch (eventType) {
    case AceButton::kEventPressed:
      Serial.println("kEventPressed");
      setPowerStateOnServer(device_ID_4, "ON");
      digitalWrite(RelayPin4, LOW);
      break;
    case AceButton::kEventReleased:
      Serial.println("kEventReleased");
      setPowerStateOnServer(device_ID_4, "OFF");
      digitalWrite(RelayPin4, HIGH);
      break;
  }
}

Credits

Subhajit

47 projects • 126 followers

I have studied Electrical Engineering. I do love to make different DIY electronics projects & share it on my YouTube channel Tech StudyCell.

NodeMCU ESP8266 Alexa App Voice Control Smart Home System

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Required Components:

Required Components for the PCB

Required Software:

Circuit Diagram of the ESP32 Project:

Control Relays With Voice Commands Using Alexa

Control Relays Using Switches:

Create an Account in Sinric

Add Devices in Sinric

Program NodeMCU Using Arduino IDE

Download and Install the Amazon Alexa App.

Configure the Alexa App for This Smart Home System

Connecting Devices With Alexa

Design the PCB for This Smart Home System

Order the PCB

Uploading the Gerber File and Set the Parameters

Select Shipping Address and Payment Mode

Solder All the Components on PCB

Testing the NodeMCU Home Automation Circuit

Connect the Home Appliances with Relay Module

Turn ON the Supply

Finally!! the Alexa Home Automation System Is Ready

Schematics

Circuit for NodeMCU & Alexa Controlled Relay with Manual Switch

Code

Code for NodeMCU & Alexa Controlled Relay with Manual Switch

Credits

Subhajit

Comments

Embed the widget on your own site

NodeMCU ESP8266 Alexa App Voice Control Smart Home System

NodeMCU ESP8266 Alexa App Voice Control Smart Home System

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Required Components:

Required Components for the PCB

Required Software:

Circuit Diagram of the ESP32 Project:

Control Relays With Voice Commands Using Alexa

Control Relays Using Switches:

Create an Account in Sinric

Add Devices in Sinric

Program NodeMCU Using Arduino IDE

Download and Install the Amazon Alexa App.

Configure the Alexa App for This Smart Home System

Connecting Devices With Alexa

Design the PCB for This Smart Home System

Order the PCB

Uploading the Gerber File and Set the Parameters

Select Shipping Address and Payment Mode

Solder All the Components on PCB

Testing the NodeMCU Home Automation Circuit

Connect the Home Appliances with Relay Module

Turn ON the Supply

Finally!! the Alexa Home Automation System Is Ready

Schematics

Circuit for NodeMCU & Alexa Controlled Relay with Manual Switch

Code

Code for NodeMCU & Alexa Controlled Relay with Manual Switch

Credits

Subhajit

Comments

Related channels and tags