Published December 28, 2021 © CC BY-NC-ND

My pocket watch tells CO2

A story of a spare SCD30 inspiring a highly portable weather station to fight Sick Building Syndrome and (maybe) COVID-19 spread.

IntermediateFull instructions provided7 hours425

Things used in this project

Hardware components

SparkFun CO₂ Humidity and Temperature Sensor - SCD30

Elegoo Real Time Clock (DS1307)

Wemos D1 clone (ESP-12F)

ElectroPeak 0.96" OLED 64x128 Display Module

Photo resistor

SparkFun Pushbutton switch 12mm

Resistor 220 ohm

Software apps and online services

Arduino IDE

Hand tools and fabrication machines

Soldering iron (generic)

Solder Wire, Lead Free

Story

The origin story

Have you ever heard of the Sick Building Syndrome (SBS)? This umbrella term unites numerous non-specific illness symptoms from spending time indoors. This phenomenon has been recognised since early 1980s, and now there is a rich collection of papers linking SBS to ventilation rates and indoor carbon dioxide (CO2) concentration. We know that chronic exposure to more than 800 parts-per-million (ppm) of CO2 can reduce our wellbeing and even provoke chronic disease. [1]

In 2019, another health hazard joined the list. SARS-CoV-2 is an airborne virus, and its viral particles can survive and remain infectious for up to ten times longer in poorly ventilated spaces [2]. With omicron on the rise [3], it is the time to follow the Slovenian kindergartens, who obviously prioritized air quality over the thermal comfort of their visitors [4]. Although, perhaps, we can be a little less radical with keeping the windows open when it snows...

With this noble thought in mind, I was enrolled in a "Build Your Own CO2 Sensor" workshop. With a Grove shield, an SCD30, an eight-segment display, and a push button, we embarked on a journey to create the ultimate Arduino project. Following instructions inspired by a niche French website, we assembled a device capable of motivating the upkeep of high air quality inside any lecture hall.

Figure 1. Proto-prototype of the portable CO2 sensor in its natural habitat.

As you may have noticed, the resulting prototype had many tangling wires and took a lot of space, which drastically reduced its EDC potential. So, equipped with a soldering iron and everlasting procrastinating issues, I decided to ameliorate the situation and make a pocket-sized version of this device.

Glue gun >> 3D printer

One does not simply revitalize an old project without adding a few features. For instance, I dislike 8-segment displays. Despite their "Retro" appearance, they always feel severely limiting for my creative genius. Gladly, I had an OLED display collecting dust in a corner, as well as a Real-Time Clock module. After swapping Arduino Uno with a ESP8266-based development board to exploit its WiFi functionality, I began soldering all the pieces together.

Spoiler: I could've stayed with Arduino.

Figure 2. Portable CO2 sensor at the breadboard stage (WIP). The indoor CO2 is at a tolerable level.

After a few hours of trying to fit everything on a generic 4x6 PCB, the screen finally powered up. Some of the connections felt a little flimsy and easy to break, so (in absence of a better option), a milestone decision was made: soak it all in the hot glue. And, voila - the pocket CO2 monitor and weather station is now ready to go.

Dim the lights

Somehow there is no simple tutorial showing how to control the brightness of a '0.96 OLED screen. But then, this never stopped anyone!

Tweaking contrast and precharge allows sufficient brightness adjustments. Solder A0 to a photoresistor in sequence with 2 parallel 220 Ohm resistors, and now you can adapt the screen brightness in response to the ambient light. Magic!

Maximum values: contrast = 255 precharge = 34

1 / 2 • Figure 3. Portable CO2 sensor en face. So cute!

The tale of 2 calibrations

1. Every temperature sensor has an intrinsic source of error: it heats up. SCD30 is no exception, and it easily gains 2-3°C after within first minutes of powering-up. Normally, it is not an issue, because the sensor is designed for for continuous work: a single-time temperature offset completely resolves the problem. However, with the pocket format, the offset depends on how long the sensor has been running for. Hence the custom temperature offset function, which allows you to add an offset value based on temperature registered at start-up.

This solution is far from perfect - please suggest better options in the comments!

2. SCD30 relies on a reference value to calculate the ambient CO2 concentration. And since the automatic calibration is a mess, it is easiest to utilise the reference value of 417 ppm and perform forced re-calibration outdoors. The device has to be running for at least 2 minutes in stable CO2 conditions, which is why the script does not offer this option straightaway. Once calibrated, the device stores the new reference value in non-volatile memory of the SCD30, which means it stays there even once you have cut the power. Neat!

1 / 2 • Figure 5. Portable CO2 sensor telling me its time to open the window. The bottom button calls the temperature offset menu.

The library that killed the vibe

Shortly after programing the breadboard prototype, I noticed my gadget freezing. Sometimes after a few minutes, oftentimes after a few seconds. This behaviour seemed random, and it took a while to find and eliminate the culprit.

The first problem came in the form of a single "stock" library provided by my Elegoo starter kit. Their "DS1307.h" required an instance of a class containing multiple String objects to read and store the Real Time Clock module output. In simple words - it used way too much memory for a fairly simple task. Gladly, swapping the library solved the freezing issue for good.

Furthermore, every now and then the RTC randomly outputs 165 for time and/or date values. I couldn't find the source of this peculiarity, so instead my script skips a frame if any of the values is suddenly 165. Engineering at its finest, I know.

IoT not!

When I picked an ESP8266-based board, I wanted to add two Internet-of-Things functions:

Log/share data using WiFi (e.g. via a Telegram bot);
Display outdoor weather (like Martin Smaha).

An attempt to add OpenWeather API wasn't as successful as envisioned. Well, it actually fried up my development board! The poor D1 eventually stopped showing any signs of life and had to be replaced. After a closer look, I realized that a single WiFi.begin(); line was enough to screw with the ESP's brains, resulting in a drastically slower screen refresh rate (sometimes even skipping a few seconds).

Since I have a different WiFi-based project with the identical "brain" running just fine, I suspect there must be a problem with overloading the volatile memory (again!). Quite a shame, I could've used my Logan Nano and spared an OLED.

Remarks

Here are some bonus observations to help fellow hobbyists:

The built-in LED of Wemos D1 mini is connected to one of the digital pins. My clone had it at D4, so it flickers every time the screen is updated. Fun!
The D0 pin of my board had no input-pullup capacity, so the final PCB layout differs from the breadboard one. Always check documentation!
DuPont female connectors + PCB = magically simple component replacement. Especially if you covered it all in hot glue. Really.

And that's about it!

Let me know what you think in the comments, feedback always makes me happy!

Code

Final Script

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||                WiFi Setup               ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

/*  Unfortunately, just initiating the WiFi connection overloads my D1 clone, leading
 *  to inconsistent OLED output (temporary freezes) and other bugs -> idea shelved 
*/
 
#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <WiFiUdp.h>

char ssid[] = "SSID";         //  your network SSID (name)
char pass[] = "PasSWoRd";     // your network password 

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||            0.96 OLED Setup              ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

#include <SPI.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

// Declaration for SSD1306 display connected using software SPI (default case):
#define OLED_MOSI  D4 // SDA
#define OLED_CLK   D3 // SCK
#define OLED_DC    D7 // DC
#define OLED_CS    D8 // CS
#define OLED_RESET D6 // RES
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT,
  OLED_MOSI, OLED_CLK, OLED_DC, OLED_RESET, OLED_CS);

void display_YesNO(){
    display.fillTriangle (120, 3, 127, 1, 124, 7, 1);
    display.fillTriangle (120, 61, 127, 63, 124, 57, 1);
    display.setCursor(103, 8);
    display.println (F("Yes"));
    display.setCursor(105, 51);
    display.println (F("No"));
}
void display_startup(){
  display.begin();
  display.clearDisplay();               // Clear the OLED buffer
  display.setTextSize(2);               // Enlarged text for the startup screen
  display.setTextColor(SSD1306_WHITE);  // Draw white text
  display.drawLine(17, 17, 25, 25,1);
  display.drawLine(18, 17, 26, 25,1);
  display.drawLine(25, 17, 17, 25,1);
  display.drawLine(26, 17, 18, 25,1);
  display.drawLine(37, 17, 45, 25,1);
  display.drawLine(38, 17, 46, 25,1);
  display.drawLine(45, 17, 37, 25,1);
  display.drawLine(46, 17, 38, 25,1);
  display.drawCircle(31,31,30,1);
  display.drawCircle(31,31,28,1);
  display.drawCircle(31,45,3,1);
  display.drawCircle(33,40,3,1);
  display.drawCircle(29,43,3,1);
  display.drawCircle(34,47,3,1);
  display.drawCircle(28,47,3,1);
  display.drawCircle(37,43,3,1);
  display.drawCircle(23,43,3,1);
  display.setCursor(75, 5);
  display.println (F("Time"));
  display.setCursor(75, 25);
  display.println (F("to"));
  display.setCursor(75, 45);
  display.println (F("air"));
  display.display();
  display.setTextSize(1);                 // Normal 1:1 pixel scale
  delay(2000);
}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||      Buttons & Photoresistor setup      ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

const int button [2] = {D4, D3};
bool button_state [2] = {HIGH};

void buttonCheck (int b){if (digitalRead(button[b])==LOW){button_state[b]=LOW;}}
void buttonReset (int b){button_state [b] = HIGH;}

#define photoresistor A0
int photoValue = 0;

void photoCheck () {            // Moving average filter
  photoValue = (photoValue+analogRead (photoresistor))/2;
}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||          Display brightness             ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

void setContrast_subfunciton (int brightn = 255, int precharge = 34) {
  display.ssd1306_command(SSD1306_SETCONTRAST);         
  display.ssd1306_command(brightn);
  display.ssd1306_command(SSD1306_SETPRECHARGE);      
  display.ssd1306_command(precharge);
}

void setContrast(){
  photoCheck();
  if (photoValue >= 1000){setContrast_subfunciton();}
  // Gaps in the range below to reduce display flickering at border values
  if ((photoValue <= 900)&&(photoValue >= 600)){setContrast_subfunciton(255, 16);}
  if (photoValue < 500){setContrast_subfunciton(1, 16);}
}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||         SCD30 air sensor setup          ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

//Click here to get the library: http://librarymanager/All#SparkFun_SCD30
#include <Wire.h>
#include "SparkFun_SCD30_Arduino_Library.h"
SCD30 airSensor;

int CO2=0;
float T=0;
float T_offset=0;
float T_start=0;
int H=0;
int basal_level=417; // Basal CO2 level (ppm) corresponding to fresh air (in 2021)
bool skipOnStartUp = true;

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||          Air quality to text            ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

void displayText_AirQuality (){
  // Displaying air quality data from SCD30
  if (airSensor.dataAvailable()){
    CO2=airSensor.getCO2();
    T=airSensor.getTemperature();
    H=airSensor.getHumidity();}
  display.print(F("CO2:  ")); 
  display.print(CO2);   display.println(F(" ppm"));
  display.print(F("Temp: "));
  display.print(T+T_offset);     display.println(F(" C"));
  display.drawCircle(69, display.getCursorY() - 6, 1, WHITE);      // https://stackoverflow.com/questions/47955775/display-degree-symbol-in-arduino-oled
  Serial.println (display.getCursorY());
  display.print(F("Hum.: "));
  display.print(H);     display.println(F(" %"));}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||         Calibration functions           ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

/* Routing function choosing between calibrate_T () and calibrate_CO2 () */

unsigned long run_timer = millis();

void calibrate () {
  if (millis()-run_timer<120000){
    display.fillTriangle (120, 61, 127, 63, 124, 57, 1);
    display.setCursor(105, 51);
    display.println (F(" T"));
    display.drawCircle(118, display.getCursorY()-7, 1, WHITE);      // https://stackoverflow.com/questions/47955775/display-degree-symbol-in-arduino-oled
    calibrate_T ();
  }
  else {
    display.fillTriangle (120, 61, 127, 63, 124, 57, 1);
    calibrate_CO2 ();
    display.setCursor(102, 51);
    display.println (F("CO2"));
  }
}

/*  The function below offers the user to record temperature offset due to device heating 
 *  by subtractibg the current temperature from the startup value. Only makes sense if the 
 *  device was idle before startup. This version does not use the SCD30 non-volatile memory,
 *  so the value is lost when the device is turned off.
*/
 
void calibrate_T () {
  if (millis()-run_timer<5000) {
    T_start = T;
  }
  buttonCheck (1);
  if (button_state [1] == LOW){
    buttonReset (1);
    if (skipOnStartUp == true){skipOnStartUp=false; return;}
    display.clearDisplay();
    display.setCursor(0, 24);
    display.println (F("Do you want to offset"));
    display.println (F("temperature?"));
    display_YesNO();
    display.display();
    delay(250);
    while ((button_state [0] == HIGH)&&(button_state [1] == HIGH)){
      buttonCheck(0);
      buttonCheck(1);
      delay (100);}
    if (button_state [1] == LOW){
      buttonReset(0);
      buttonReset(1);
      return;}
    // Record temperature offset
    T_offset = T_start - T; 
    display.clearDisplay();
    display.setCursor(0, 24);
    display.println (F("Temperatire offset"));
    display.print (F("is: "));
    display.print (T_offset); display.print (F(" ppm"));
    display.display();
    buttonReset(0);
    buttonReset(1);
    delay(1000);}}

/*   The function below offers the user to calibrate CO2 sensor. According to the module
 *   documentation, SCD30 has to run for at least 2 minutes before  calibration -> function 
 *   can only be called after two minutes runtime. This function uses the SCD30 non-volatile 
 *   memory, allowing to preserve the value when the device is not powered.
*/

void calibrate_CO2 () {
  buttonCheck (1);
  if (button_state [1] == LOW){
    buttonReset (1);
    if (skipOnStartUp == true){skipOnStartUp=false; return;}
    display.clearDisplay();
    display.setCursor(0, 24);
    display.println (F("Do you want to"));
    display.println (F("calibrate CO2?"));
    display_YesNO();
    display.display();
    delay(250);
    while ((button_state [0] == HIGH)&&(button_state [1] == HIGH)){
      buttonCheck(0);
      buttonCheck(1);
      delay (100);}
    if (button_state [1] == LOW){
      buttonReset(0);
      buttonReset(1);
      return;}
    // Start forced recalibration
    airSensor.setForcedRecalibrationFactor(basal_level);
    display.clearDisplay();
    display.setCursor(0, 24);
    display.println (F("Forced recalibration"));
    display.print (F("factor is: "));
    display.print (basal_level); display.print (F(" ppm"));
    display.display();
    buttonReset(0);
    buttonReset(1);
    delay(1000);}}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||          Time / Date to text            ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

#include <DS3231.h>

RTClib myRTC;
DateTime dt = myRTC.now();

void displayText_Time(){
  dt = myRTC.now();
  display.print (F("Time: "));
  if (dt.hour()<10){display.print(0);}
  display.print(dt.hour());   display.print(F(":"));
  if (dt.minute()<10){display.print(0);}
  display.print(dt.minute()); display.print(F(":"));
  if (dt.second()<10){display.print(0);}
  display.println (dt.second());
  display.print (F("Date: "));
  switch (dt.month()){
    case 1:
      display.print (F("January "));
      break;
    case 2:
      display.print (F("February "));
      break;
    case 3:
      display.print (F("March "));
      break;
    case 4:
      display.print (F("April "));
      break;
    case 5:
      display.print (F("May "));
      break;
    case 6:
      display.print (F("June "));
      break;
    case 7:
      display.print (F("July "));
      break;
    case 8:
      display.print (F("August "));
      break;
    case 9:
      display.print (F("September "));
      break;
    case 10:
      display.print (F("October "));
      break;
    case 11:
      display.print (F("November "));
      break;
    case 12:
      display.print (F("December "));
      break;}
  display.print(dt.day());
  display.println(F("th"));
}

/*  |||||||||||||||||||||||||||||||`||||||||||||||||||||||
 *  ||||||           Main program body             ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

void setup() {
  //Serial.begin(9600);
  //WiFi.persistent(false);
  //WiFi.begin(ssid, pass);
  pinMode(button [0], INPUT_PULLUP);
  pinMode(button [1], INPUT_PULLUP);
  Wire.begin();
  // SCD30 air sensor setup
  airSensor.begin();
  airSensor.setAutoSelfCalibration(false); 
  //airSensor.setMeasurementInterval (5);  // https://www.mouser.com/pdfdocs/CD_AN_SCD30_Low_Power_Mode_D2.pdf
  // OLED setup
  display_startup();
}

/* Don't forget to set cursor position, clear the buffer and call display.display(); */
unsigned long screen_timer = millis();    // display refresh rate

void loop() {
  buttonCheck (1);
  if (millis() - screen_timer <= 100){return;} // Screen refresh rate 10 FPS
  else {screen_timer = millis();}
  setContrast();
  display.clearDisplay();
  display.setCursor(0, 0);        // Start at top-left corner
  displayText_Time();         display.println();
  displayText_AirQuality();   display.println();
  calibrate ();
  if ((dt.hour()==165)||(dt.day()==165)){            // Getting rid of a bug: sometimes all readouts equal 165 for some obscure reason....
    display.clearDisplay(); 
    return;
  }
  display.display();
  }