RAK1906 Air Quality Monitoring: A Focused Guide on Environme

This project is a refined version of broader air quality and IoT monitoring guides—focusing solely on the RAK1906 Environmental Sensor to explore what meaningful insights we can extract from its readings. The RAK1906 measures temperature, humidity, barometric pressure, and gas resistance, which can be used to estimate air quality indices such as Indoor Air Quality (IAQ), dew point, discomfort index, and heat index.

By isolating this sensor, we take an in-depth, educational approach to understanding how these parameters interact and how we can calculate indices that reflect human comfort, pollution levels, and environmental changes. Data is transmitted over LoRaWAN using the RAK4631 WisBlock Core, then visualized in real time on platforms like TTN and Ubidots.

This guide is ideal for students, developers, and researchers looking to dive deeper into environmental sensing, develop smart agriculture, indoor climate control, or air quality awareness tools, and truly understand what the RAK1906 is capable of on its own.

Things Used in the Project

Hardware Components

Microcontroller & Sensor:

• RAK4631 WisBlock Core – LoRa-enabled microcontroller for low-power, long-range IoT connectivity.
• RAK1906 Environmental Sensor – Measures temperature, humidity, barometric pressure, and gas resistance (used to estimate air quality indices like VOC levels, IAQ, and more).
• RAK19007 WisBlock Base Board – Hosts and powers WisBlock modules.

Connectivity:

• RAK7268 WisGate Edge Lite 2 – LoRaWAN gateway that relays sensor data to The Things Network (TTN).
• LoRa Antenna – Boosts wireless communication range between the sensor node and the gateway.

Power Supply:

• USB-C Cable – For programming and powering the device during setup.
• Rechargeable Li-ion Battery – Enables standalone, portable operation.

Other Components:

• Jumper wires and connectors
• (Optional) 3D-printed or custom enclosure for protection and deployment

Software Apps and Online Services

Programming & Development:

• Arduino IDE – For writing, compiling, and uploading firmware.
• RAK WisBlock Libraries – To easily interface with the RAK1906 sensor.

IoT & Cloud Platforms:

• The Things Network (TTN) – Provides LoRaWAN connectivity to transmit data to the cloud.
• Ubidots – For real-time visualization, analysis, and dashboard creation.

Additional Tools:

• GitHub – For managing and sharing source code.

Hand Tools and Fabrication (Optional)

• Screwdrivers, pliers, and wire strippers – For basic assembly and wiring.
• 3D Printer – For creating enclosures tailored to your deployment environment.

Story (Step-by-Step Guide)

Step 0: Gateway: Setup and Configuration

To avoid damage to the gateway, make sure to connect the antenna before turning it on!

This step is thoroughly explained in the guide - IoT Education Kit - Setup the Gateway RAK7268V2 - that can be found on https://www.hackster.io/520073/iot-education-kit-setup-the-gateway-rak7268v2-6b222f

Step 1: Mounting WisBlock Parts

• Attach RAK4630 WisBlock Core onto the RAK19007 WisBlock Base.

• Connect RAK1906 (Air Quality Sensor) to an I²C slot.

• Connect the LoRa Antenna

Step 2&3: Setup Arduino IDE & Connection to the TTN

The full instructions for setting up the Arduino IDE and connecting your WisBlock RAK4631 to The Things Network (TTN) are covered in detail in the guide: Getting Started with WisBlock and The Things Network (TTN)

Follow that guide to

• Install board support for WisBlock in the Arduino
• Load and configure the LoRaWAN example sketch
• Register your device on TTN
• Insert TTN credentials into your code
• Upload the code and verify data transmission

Once complete, your device will be ready to send data over LoRaWAN through TTN!

Step 4: Verifying the RAK1906 sensor

Below is a step-by-step guide showing how to verify the RAK1906_Environment_BME690 sensor.

Part 1: Installing the library

In this example we tested a sensor which is RAK1906 and, for that, you will need to follow the same steps above to install the library, but the specific library for our example is SX126x-Arduino.

Part 2: Setting Up the Sensor and Serial Monitor

1. Open the Example for the Sensor:

- Open Arduino IDE and go to:

`File > Examples > RAK WisBlock Examples > RAK 4631 > Sensors > RAK1906_Environment_BME690 `.

2. View Data in Serial Monitor:

Step 6: Merging the code of the sensors

1. Configure LoRaWAN Credentials

Ensure your RAK4631 device can join The Things Network (TTN) by setting the correct credentials:

• Obtain Device Credentials:
• From the TTN console, retrieve your device's Device EUI, Application EUI, and App Key.
• Update the Example Code:
• Open the RAK4631_DeepSleep_LoRaWAN example.
• Locate the arrays for nodeDeviceEUI[8], nodeAppEUI[8], and nodeAppKey[16].

2. Initialize Sensors in setup()

Integrate the BME680 and LTR390 sensor initialization into the setup() function:

• Include Necessary Libraries:

At the beginning of your code, include the sensor libraries:#include <Adafruit_Sensor.h>

#include <Adafruit_BME680.h>

• Declare Sensor Objects:

Before the setup() function, declare the sensor objects:

Adafruit_BME680 bme;

And the following functions:

void bme680_init()

void bme680_get()

• Initialize Sensors:

Within the setup() function, initialize both sensors. After the Serial insert this:

// On nRF52840 the USB serial is not available immediately
while (!Serial)
{
if ((millis() - timeout) < 5000)
{
delay(100);
digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
}
else
{
break;
}
}
#endif
digitalWrite(LED_BUILTIN, LOW);
bme680_init();

3. Collect Sensor Data in loop()

Modify the loop() function to read data from both sensors and prepare it for transmission:

• Read Sensor Data:

Within the loop() function, read data from the BME680 and LTR390 sensors. After this line:

/// \todo read sensor or whatever you need to do frequently

Insert this code:

if (! bme.performReading())
{
Serial.println("Failed to perform reading :(");
}
bme680_get();
}

4. Update the SendLoraFrame Function

On the main file and on the lora_handler.cpp you should update the new SendLoraFrame function to include the following: float temperature, float pressure, float humidity, float gas_resistence

After you should convert sensor readings into a byte array suitable for LoRaWAN transmission:

uint8_t buffSize = 0;
uint16_t temp = (temperature*100)+5000;
uint16_t press = pressure/100;
uint16_t hum = (humidity*100)+5000;  
uint16_t gs = gas_resistence/1000;    


// Reset buffer size
buffSize = 0;

// Adding temperature
m_lora_app_data_buffer[buffSize++] = 0x01;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(temp / 256);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(temp % 256);

// Adding pressure
m_lora_app_data_buffer[buffSize++] = 0x02;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(press / 256);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(press % 256);

// Adding humidity data
m_lora_app_data_buffer[buffSize++] = 0x03;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(hum / 256);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(hum % 256);

// Adding gas data
m_lora_app_data_buffer[buffSize++] = 0x04;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(gs / 256);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(gs % 256);



  m_lora_app_data.buffsize = buffSize;

5. Calculating Environmental Indices

Environmental Indices Overview:

• Indoor Air Quality (IAQ) – A rough estimate (0–500) of air pollution based on gas resistance and humidity. Lower is better.
• Dew Point – The temperature at which condensation begins. Useful for moisture and comfort analysis.
• Discomfort Index (DI) – Indicates how hot and humid it feels. Higher values reflect greater discomfort.
• Heat Index – The perceived temperature felt by humans, especially useful in hot and humid climates.

Add Functions for Calculations: At the bottom of your main.ino file, after your sensor reading functions (e.g., bme680_get()), add the following:

float calculateIAQ(float gas_resistance, float humidity) {
float humidity_score = (humidity > 38 && humidity < 42) ? 0.25 : 0.25 - abs(humidity - 40.0) * 0.00625;
float gas_score = (gas_resistance > 50000) ? 0.75 : 0.75 * gas_resistance / 50000.0;
float iaq = (1.0 - (humidity_score + gas_score)) * 500;
return constrain(iaq, 0, 500);
}
float calculateDewPoint(float temp, float humidity) {
float a = 17.27;
float b = 237.7;
float alpha = ((a * temp) / (b + temp)) + log(humidity / 100.0);
return (b * alpha) / (a - alpha);
}
float calculateDiscomfortIndex(float temp, float humidity) {
return 0.81 * temp + 0.01 * humidity * (0.99 * temp - 14.3) + 46.3;
}
float calculateHeatIndex(float temp, float humidity) {
if (temp < 27) return temp;
return -8.784695 +
1.61139411 * temp +
2.338549 * humidity +
-0.14611605 * temp * humidity +
-0.012308094 * pow(temp, 2) +
-0.016424828 * pow(humidity, 2) +
0.002211732 * pow(temp, 2) * humidity +
0.00072546 * temp * pow(humidity, 2) +
-0.000003582 * pow(temp, 2) * pow(humidity, 2);
}

Calculate Indices After Reading Sensor Data

In your loop() function, after the call to bme680_get();, insert the following code to calculate and print the indices:

if (! bme.performReading())
{
Serial.println("Failed to perform reading :(");
}
bme680_get();
temp = bme.temperature;
humidity = bme.humidity;
pressure = bme.pressure / 100.0; // Convert Pa to hPa
gas = bme.gas_resistance;
iaq = calculateIAQ(gas, humidity);
dewPoint = calculateDewPoint(temp, humidity);
discomfortIndex = calculateDiscomfortIndex(temp, humidity);
heatIndex = calculateHeatIndex(temp, humidity);
Serial.println("---- Environmental Indices ----");
Serial.print("IAQ Estimate: "); Serial.println(iaq);
Serial.print("Dew Point: "); Serial.print(dewPoint); Serial.println(" °C");
Serial.print("Discomfort Index: "); Serial.println(discomfortIndex);
Serial.print("Heat Index: "); Serial.print(heatIndex); Serial.println(" °C");
// Send the data package
if (sendLoRaFrame(temp, pressure, humidity, gas, iaq, dewPoint, discomfortIndex, heatIndex))
{

In your.ino file, call SendLoRaFrame() with all required parameters from your loop, right after calculating the sensor values and indices:

SendLoRaFrame(temp, pressure, humidity, gas, iaq, dewPoint, discomfortIndex, heatIndex);

Updated Payload Packing Code

bool sendLoRaFrame(float temperature, float pressure, float humidity, float gas_resistance, float iaq, float dew_point, float discomfort_index, float heat_index)
{
if (lmh_join_status_get() != LMH_SET)
{
//Not joined, try again later
#ifndef MAX_SAVE
Serial.println("Did not join network, skip sending frame");
#endif
return false;
}
m_lora_app_data.port = LORAWAN_APP_PORT;
//******************************************************************
/// \todo here some more usefull data should be put into the package
//******************************************************************
uint8_t buffSize = 0;
uint16_t temp = (temperature * 100) + 5000;
uint16_t hum = (humidity  * 100) + 5000;
uint16_t press = pressure; // Already in hPa
uint16_t gas = gas_resistance / 100;
uint16_t iaqVal = iaq * 100;
uint16_t dp = dew_point * 100;
uint16_t di = discomfort_index * 100;
uint16_t hi = heat_index * 100;
// Reset buffer
buffSize = 0;
// Temperature
m_lora_app_data_buffer[buffSize++] = 0x01;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(temp >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(temp);
// Humidity
m_lora_app_data_buffer[buffSize++] = 0x02;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(hum >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(hum);
// Pressure
m_lora_app_data_buffer[buffSize++] = 0x03;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(press >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(press);
// Gas Resistance
m_lora_app_data_buffer[buffSize++] = 0x04;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(gas >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(gas);
// IAQ
m_lora_app_data_buffer[buffSize++] = 0x05;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(iaqVal >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(iaqVal);
// Dew Point
m_lora_app_data_buffer[buffSize++] = 0x06;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(dp >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(dp);
// Discomfort Index
m_lora_app_data_buffer[buffSize++] = 0x07;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(di >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(di);
// Heat Index
m_lora_app_data_buffer[buffSize++] = 0x08;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(hi >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(hi);
// Finalize
m_lora_app_data.buffsize = buffSize;
lmh_error_status error = lmh_send(&m_lora_app_data, LMH_UNCONFIRMED_MSG);
return (error == 0);
}

Update Declaration in lora_handler.h

Don't forget to match the function signature in the header file too.

The link with the code for this example can be found on Github:https://github.com/1ClickBait/DSIOT/tree/main/RAK4631_1906

You can also copy the.ino file from here:

/**
* @file RAK4631-DeepSleep-LoRaWan.ino
* @author Bernd Giesecke (bernd.giesecke@rakwireless.com)
* @brief LoRaWan deep sleep example
* Device goes into sleep after successful OTAA/ABP network join.
* Wake up every SLEEP_TIME seconds. Set time in main.h
* @version 0.1
* @date 2020-09-05
*
* @copyright Copyright (c) 2020
*
* @note RAK4631 GPIO mapping to nRF52840 GPIO ports
RAK4631    <->  nRF52840
WB_IO1     <->  P0.17 (GPIO 17)
WB_IO2     <->  P1.02 (GPIO 34)
WB_IO3     <->  P0.21 (GPIO 21)
WB_IO4     <->  P0.04 (GPIO 4)
WB_IO5     <->  P0.09 (GPIO 9)
WB_IO6     <->  P0.10 (GPIO 10)
WB_SW1     <->  P0.01 (GPIO 1)
WB_A0      <->  P0.04/AIN2 (AnalogIn A2)
WB_A1      <->  P0.31/AIN7 (AnalogIn A7)
*/
#include "main.h"
#include <Wire.h>
#include <Adafruit_Sensor.h>
#include <Adafruit_BME680.h> // Click to install library: http://librarymanager/All#Adafruit_BME680
Adafruit_BME680 bme;
// Might need adjustments
#define SEALEVELPRESSURE_HPA (1010.0)
// Environmental sensor values
float temp = 0.0;
float humidity = 0.0;
float pressure = 0.0;
float gas = 0.0;
// Environmental indices
float iaq = 0.0;
float dewPoint = 0.0;
float discomfortIndex = 0.0;
float heatIndex = 0.0;
float calculateIAQ(float gas_resistance, float humidity) {
float humidity_score = (humidity > 38 && humidity < 42) ? 0.25 : 0.25 - abs(humidity - 40.0) * 0.00625;
float gas_score = (gas_resistance > 50000) ? 0.75 : 0.75 * gas_resistance / 50000.0;
float iaq = (1.0 - (humidity_score + gas_score)) * 500;
return constrain(iaq, 0, 500);
}
float calculateDewPoint(float temp, float humidity) {
float a = 17.27;
float b = 237.7;
float alpha = ((a * temp) / (b + temp)) + log(humidity / 100.0);
return (b * alpha) / (a - alpha);
}
float calculateDiscomfortIndex(float temp, float humidity) {
return 0.81 * temp + 0.01 * humidity * (0.99 * temp - 14.3) + 46.3;
}
float calculateHeatIndex(float temp, float humidity) {
if (temp < 27) return temp;
return -8.784695 +
1.61139411 * temp +
2.338549 * humidity +
-0.14611605 * temp * humidity +
-0.012308094 * pow(temp, 2) +
-0.016424828 * pow(humidity, 2) +
0.002211732 * pow(temp, 2) * humidity +
0.00072546 * temp * pow(humidity, 2) +
-0.000003582 * pow(temp, 2) * pow(humidity, 2);
}
void bme680_init()
{
Wire.begin();
if (!bme.begin(0x76)) {
Serial.println("Could not find a valid BME680 sensor, check wiring!");
return;
}
// Set up oversampling and filter initialization
bme.setTemperatureOversampling(BME680_OS_8X);
bme.setHumidityOversampling(BME680_OS_2X);
bme.setPressureOversampling(BME680_OS_4X);
bme.setIIRFilterSize(BME680_FILTER_SIZE_3);
bme.setGasHeater(320, 150); // 320*C for 150 ms
}
void bme680_get()
{
Serial.print("Temperature = ");
Serial.print(bme.temperature);
Serial.println(" *C");
Serial.print("Pressure = ");
Serial.print(bme.pressure / 100.0);
Serial.println(" hPa");
Serial.print("Humidity = ");
Serial.print(bme.humidity);
Serial.println(" %");
Serial.print("Gas = ");
Serial.print(bme.gas_resistance / 1000.0);
Serial.println(" KOhms");
Serial.println();
}
/** Semaphore used by events to wake up loop task */
SemaphoreHandle_t taskEvent = NULL;
/** Timer to wakeup task frequently and send message */
SoftwareTimer taskWakeupTimer;
/** Buffer for received LoRaWan data */
uint8_t rcvdLoRaData[256];
/** Length of received data */
uint8_t rcvdDataLen = 0;
/**
* @brief Flag for the event type
* -1 => no event
* 0 => LoRaWan data received
* 1 => Timer wakeup
* 2 => tbd
* ...
*/
uint8_t eventType = -1;
/**
* @brief Timer event that wakes up the loop task frequently
*
* @param unused
*/
void periodicWakeup(TimerHandle_t unused)
{
// Switch on blue LED to show we are awake
digitalWrite(LED_BUILTIN, HIGH);
eventType = 1;
// Give the semaphore, so the loop task will wake up
xSemaphoreGiveFromISR(taskEvent, pdFALSE);
}
/**
* @brief Arduino setup function. Called once after power-up or reset
*
*/
void setup(void)
{
// Create the LoRaWan event semaphore
taskEvent = xSemaphoreCreateBinary();
// Initialize semaphore
xSemaphoreGive(taskEvent);
// Initialize the built in LED
pinMode(LED_BUILTIN, OUTPUT);
digitalWrite(LED_BUILTIN, LOW);
// Initialize the connection status LED
pinMode(LED_CONN, OUTPUT);
digitalWrite(LED_CONN, HIGH);
#ifndef MAX_SAVE
// Initialize Serial for debug output
Serial.begin(115200);
time_t timeout = millis();
// On nRF52840 the USB serial is not available immediately
while (!Serial)
{
if ((millis() - timeout) < 5000)
{
delay(100);
digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
}
else
{
break;
}
}
#endif
bme680_init();
digitalWrite(LED_BUILTIN, LOW);
#ifndef MAX_SAVE
Serial.println("=====================================");
Serial.println("RAK4631 LoRaWan Deep Sleep Test");
Serial.println("=====================================");
#endif
// Initialize LoRaWan and start join request
int8_t loraInitResult = initLoRaWan();
#ifndef MAX_SAVE
if (loraInitResult != 0)
{
switch (loraInitResult)
{
case -1:
Serial.println("SX126x init failed");
break;
case -2:
Serial.println("LoRaWan init failed");
break;
case -3:
Serial.println("Subband init error");
break;
case -4:
Serial.println("LoRa Task init error");
break;
default:
Serial.println("LoRa init unknown error");
break;
}
// Without working LoRa we just stop here
while (1)
{
Serial.println("Nothing I can do, just loving you");
delay(5000);
}
}
Serial.println("LoRaWan init success");
#endif
// Take the semaphore so the loop will go to sleep until an event happens
xSemaphoreTake(taskEvent, 10);
}
/**
* @brief Arduino loop task. Called in a loop from the FreeRTOS task handler
*
*/
void loop(void)
{
// Switch off blue LED to show we go to sleep
digitalWrite(LED_BUILTIN, LOW);
// Sleep until we are woken up by an event
if (xSemaphoreTake(taskEvent, portMAX_DELAY) == pdTRUE)
{
// Switch on blue LED to show we are awake
digitalWrite(LED_BUILTIN, HIGH);
delay(500); // Only so we can see the blue LED
// Check the wake up reason
switch (eventType)
{
case 0: // Wakeup reason is package downlink arrived
#ifndef MAX_SAVE
Serial.println("Received package over LoRaWan");
#endif
if (rcvdLoRaData[0] > 0x1F)
{
#ifndef MAX_SAVE
Serial.printf("%s\n", (char *)rcvdLoRaData);
#endif
}
else
{
#ifndef MAX_SAVE
for (int idx = 0; idx < rcvdDataLen; idx++)
{
Serial.printf("%X ", rcvdLoRaData[idx]);
}
Serial.println("");
#endif
}
break;
case 1: // Wakeup reason is timer
#ifndef MAX_SAVE
Serial.println("Timer wakeup");
#endif
/// \todo read sensor or whatever you need to do frequently
if (! bme.performReading())
{
Serial.println("Failed to perform reading :(");
}
bme680_get();
delay(5000);
temp = bme.temperature;
humidity = bme.humidity;
pressure = bme.pressure / 100.0; // Convert Pa to hPa
gas = bme.gas_resistance;
iaq = calculateIAQ(gas, humidity);
dewPoint = calculateDewPoint(temp, humidity);
discomfortIndex = calculateDiscomfortIndex(temp, humidity);
heatIndex = calculateHeatIndex(temp, humidity);
// Send the data package
if (sendLoRaFrame(temp, pressure, humidity, gas, iaq, dewPoint, discomfortIndex, heatIndex))
{
#ifndef MAX_SAVE
Serial.println("LoRaWan package sent successfully");
#endif
}
else
{
#ifndef MAX_SAVE
Serial.println("LoRaWan package send failed");
/// \todo maybe you need to retry here?
#endif
}
break;
default:
#ifndef MAX_SAVE
Serial.println("This should never happen ;-)");
#endif
break;
}
digitalWrite(LED_BUILTIN, LOW);
// Go back to sleep
xSemaphoreTake(taskEvent, 10);
}
}

You can find a copy of the.cpp file here:

/**
@file lora_handler.cpp
@author Bernd Giesecke (bernd.giesecke@rakwireless.com)
@brief Initialization, event handlers and task for LoRaWan
@version 0.1
@date 2020-08-15
@copyright Copyright (c) 2020
*/
#include "main.h"
/** DIO1 GPIO pin for RAK4631 */
#define PIN_LORA_DIO_1 47
/** Max size of the data to be transmitted. */
#define LORAWAN_APP_DATA_BUFF_SIZE 64
/** Number of trials for the join request. */
#define JOINREQ_NBTRIALS 8
/** Lora application data buffer. */
static uint8_t m_lora_app_data_buffer[LORAWAN_APP_DATA_BUFF_SIZE];
/** Lora application data structure. */
static lmh_app_data_t m_lora_app_data = {m_lora_app_data_buffer, 0, 0, 0, 0};
// LoRaWan event handlers
/** LoRaWan callback when join network finished */
static void lorawan_has_joined_handler(void);
/** LoRaWan callback when join failed */
static void lorawan_join_failed_handler(void);
/** LoRaWan callback when data arrived */
static void lorawan_rx_handler(lmh_app_data_t *app_data);
/** LoRaWan callback after class change request finished */
static void lorawan_confirm_class_handler(DeviceClass_t Class);
/** LoRaWan Function to send a package */
bool sendLoRaFrame(void);
/**@brief Structure containing LoRaWan parameters, needed for lmh_init()
Set structure members to
LORAWAN_ADR_ON or LORAWAN_ADR_OFF to enable or disable adaptive data rate
LORAWAN_DEFAULT_DATARATE OR DR_0 ... DR_5 for default data rate or specific data rate selection
LORAWAN_PUBLIC_NETWORK or LORAWAN_PRIVATE_NETWORK to select the use of a public or private network
JOINREQ_NBTRIALS or a specific number to set the number of trials to join the network
LORAWAN_DEFAULT_TX_POWER or a specific number to set the TX power used
LORAWAN_DUTYCYCLE_ON or LORAWAN_DUTYCYCLE_OFF to enable or disable duty cycles
Please note that ETSI mandates duty cycled transmissions.
*/
static lmh_param_t lora_param_init = {LORAWAN_ADR_OFF, DR_3, LORAWAN_PUBLIC_NETWORK, JOINREQ_NBTRIALS, LORAWAN_DEFAULT_TX_POWER, LORAWAN_DUTYCYCLE_OFF};
/** Structure containing LoRaWan callback functions, needed for lmh_init() */
static lmh_callback_t lora_callbacks = {BoardGetBatteryLevel, BoardGetUniqueId, BoardGetRandomSeed,
lorawan_rx_handler, lorawan_has_joined_handler, lorawan_confirm_class_handler, lorawan_join_failed_handler
};
//  !!!! KEYS ARE MSB !!!!
/** Device EUI required for OTAA network join */
uint8_t nodeDeviceEUI[8] = {0xAC, 0x1F, 0x09, 0xFF, 0xFE, 0x16, 0x20, 0x3C};
/** Application EUI required for network join */
uint8_t nodeAppEUI[8] = {0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
/** Application key required for network join */
uint8_t nodeAppKey[16] = {0x2C, 0xB6, 0x36, 0x02, 0xAF, 0x55, 0x8A, 0x86, 0x43, 0x33, 0x01, 0x29, 0xAA, 0x5D, 0xB5, 0x4B};/** Device address required for ABP network join */
/** Device address required for ABP network join */
uint32_t nodeDevAddr = 0x26021FB6;
/** Network session key required for ABP network join */
uint8_t nodeNwsKey[16] = {0x32, 0x3D, 0x15, 0x5A, 0x00, 0x0D, 0xF3, 0x35, 0x30, 0x7A, 0x16, 0xDA, 0x0C, 0x9D, 0xF5, 0x3F};
/** Application session key required for ABP network join */
uint8_t nodeAppsKey[16] = {0x3F, 0x6A, 0x66, 0x45, 0x9D, 0x5E, 0xDC, 0xA6, 0x3C, 0xBC, 0x46, 0x19, 0xCD, 0x61, 0xA1, 0x1E};
/** Flag whether to use OTAA or ABP network join method */
bool doOTAA = true;
DeviceClass_t gCurrentClass = CLASS_A;                  /* class definition*/
LoRaMacRegion_t gCurrentRegion = LORAMAC_REGION_EU868;  /* Region:EU868*/
/**
@brief Initialize LoRa HW and LoRaWan MAC layer
@return int8_t result
0 => OK
-1 => SX126x HW init failure
-2 => LoRaWan MAC initialization failure
-3 => Subband selection failure
*/
int8_t initLoRaWan(void)
{
// Initialize LoRa chip.
if (lora_rak4630_init() != 0)
{
return -1;
}
// Setup the EUIs and Keys
if (doOTAA)
{
lmh_setDevEui(nodeDeviceEUI);
lmh_setAppEui(nodeAppEUI);
lmh_setAppKey(nodeAppKey);
}
else
{
lmh_setNwkSKey(nodeNwsKey);
lmh_setAppSKey(nodeAppsKey);
lmh_setDevAddr(nodeDevAddr);
}
// Initialize LoRaWan
if (lmh_init(&lora_callbacks, lora_param_init, doOTAA, gCurrentClass, gCurrentRegion) != 0)
{
return -2;
}
// For some regions we might need to define the sub band the gateway is listening to
// This must be called AFTER lmh_init()
if (!lmh_setSubBandChannels(1))
{
return -3;
}
// Start Join procedure
#ifndef MAX_SAVE
Serial.println("Start network join request");
#endif
lmh_join();
return 0;
}
/**
@brief LoRa function for handling HasJoined event.
*/
static void lorawan_has_joined_handler(void)
{
if (doOTAA)
{
uint32_t otaaDevAddr = lmh_getDevAddr();
#ifndef MAX_SAVE
Serial.printf("OTAA joined and got dev address %08X\n", otaaDevAddr);
#endif
}
else
{
#ifndef MAX_SAVE
Serial.println("ABP joined");
#endif
}
// Default is Class A, where the SX1262 transceiver is in sleep mode unless a package is sent
// If switched to Class C the power consumption is higher because the SX1262 chip remains in RX mode
// lmh_class_request(CLASS_C);
digitalWrite(LED_CONN, LOW);
// Now we are connected, start the timer that will wakeup the loop frequently
taskWakeupTimer.begin(SLEEP_TIME, periodicWakeup);
taskWakeupTimer.start();
}
/**@brief LoRa function for handling OTAA join failed
*/
static void lorawan_join_failed_handler(void)
{
Serial.println("OVER_THE_AIR_ACTIVATION failed!");
Serial.println("Check your EUI's and Keys's!");
Serial.println("Check if a Gateway is in range!");
}
/**
@brief Function for handling LoRaWan received data from Gateway
@param app_data  Pointer to rx data
*/
static void lorawan_rx_handler(lmh_app_data_t *app_data)
{
#ifndef MAX_SAVE
Serial.printf("LoRa Packet received on port %d, size:%d, rssi:%d, snr:%d\n",
app_data->port, app_data->buffsize, app_data->rssi, app_data->snr);
#endif
switch (app_data->port)
{
case 3:
// Port 3 switches the class
if (app_data->buffsize == 1)
{
switch (app_data->buffer[0])
{
case 0:
lmh_class_request(CLASS_A);
#ifndef MAX_SAVE
Serial.println("Request to switch to class A");
#endif
break;
case 1:
lmh_class_request(CLASS_B);
#ifndef MAX_SAVE
Serial.println("Request to switch to class B");
#endif
break;
case 2:
lmh_class_request(CLASS_C);
#ifndef MAX_SAVE
Serial.println("Request to switch to class C");
#endif
break;
default:
break;
}
}
break;
case LORAWAN_APP_PORT:
// Copy the data into loop data buffer
memcpy(rcvdLoRaData, app_data->buffer, app_data->buffsize);
rcvdDataLen = app_data->buffsize;
eventType = 0;
// Notify task about the event
if (taskEvent != NULL)
{
#ifndef MAX_SAVE
Serial.println("Waking up loop task");
#endif
xSemaphoreGive(taskEvent);
}
}
}
/**
@brief Callback for class switch confirmation
@param Class The new class
*/
static void lorawan_confirm_class_handler(DeviceClass_t Class)
{
#ifndef MAX_SAVE
Serial.printf("switch to class %c done\n", "ABC"[Class]);
#endif
// Informs the server that switch has occurred ASAP
m_lora_app_data.buffsize = 0;
m_lora_app_data.port = LORAWAN_APP_PORT;
lmh_send(&m_lora_app_data, LMH_UNCONFIRMED_MSG);
}
/**
@brief Send a LoRaWan package
@return result of send request
*/
bool sendLoRaFrame(float temperature, float pressure, float humidity, float gas_resistance, float iaq, float dew_point, float discomfort_index, float heat_index)
{
if (lmh_join_status_get() != LMH_SET)
{
//Not joined, try again later
#ifndef MAX_SAVE
Serial.println("Did not join network, skip sending frame");
#endif
return false;
}
m_lora_app_data.port = LORAWAN_APP_PORT;
//******************************************************************
/// \todo here some more usefull data should be put into the package
//******************************************************************
uint8_t buffSize = 0;
uint16_t temp = (temperature * 100) + 5000;
uint16_t hum = (humidity  * 100) + 5000;
uint16_t press = pressure; // Already in hPa
uint16_t gas = gas_resistance / 100;
uint16_t iaqVal = iaq * 100;
uint16_t dp = dew_point * 100;
uint16_t di = discomfort_index * 100;
uint16_t hi = heat_index * 100;
// Reset buffer
buffSize = 0;
// Temperature
m_lora_app_data_buffer[buffSize++] = 0x01;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(temp >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(temp);
// Humidity
m_lora_app_data_buffer[buffSize++] = 0x02;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(hum >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(hum);
// Pressure
m_lora_app_data_buffer[buffSize++] = 0x03;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(press >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(press);
// Gas Resistance
m_lora_app_data_buffer[buffSize++] = 0x04;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(gas >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(gas);
// IAQ
m_lora_app_data_buffer[buffSize++] = 0x05;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(iaqVal >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(iaqVal);
// Dew Point
m_lora_app_data_buffer[buffSize++] = 0x06;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(dp >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(dp);
// Discomfort Index
m_lora_app_data_buffer[buffSize++] = 0x07;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(di >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(di);
// Heat Index
m_lora_app_data_buffer[buffSize++] = 0x08;
m_lora_app_data_buffer[buffSize++] = (uint8_t)(hi >> 8);
m_lora_app_data_buffer[buffSize++] = (uint8_t)(hi);
// Finalize
m_lora_app_data.buffsize = buffSize;
lmh_error_status error = lmh_send(&m_lora_app_data, LMH_UNCONFIRMED_MSG);
return (error == 0);
}

The main file can be found here:

/**
* @file main.h
* @author Bernd Giesecke (bernd.giesecke@rakwireless.com)
* @brief Includes, definitions and global declarations for DeepSleep example
* @version 0.1
* @date 2020-08-15
*
* @copyright Copyright (c) 2020
*
*/
#include <Arduino.h>
#include <SPI.h>
#include <LoRaWan-RAK4630.h>
// Comment the next line if you want DEBUG output. But the power savings are not as good then!!!!!!!
#define MAX_SAVE
/* Time the device is sleeping in milliseconds = 2 minutes * 60 seconds * 1000 milliseconds */
#define SLEEP_TIME 2 * 60 * 1000
// LoRaWan stuff
int8_t initLoRaWan(void);
bool sendLoRaFrame(float temperature, float pressure, float humidity, float gas_resistance, float iaq, float dew_point, float discomfort_index, float heat_index);
extern SemaphoreHandle_t loraEvent;
// Main loop stuff
void periodicWakeup(TimerHandle_t unused);
extern SemaphoreHandle_t taskEvent;
extern uint8_t rcvdLoRaData[];
extern uint8_t rcvdDataLen;
extern uint8_t eventType;
extern SoftwareTimer taskWakeupTimer;

Step 7: Adding Payload Formatters in TTN

1. Set Up a Custom Payload Formatter:

• When data is transmitted via LoRaWAN, it is often in a raw, unreadable format. Payload Formatters in TTN help convert these raw values into human-readable data (like JSON).
• In TTN, navigate to the Payload Formatter section of your application.
• Choose the Uplink option and select Custom JavaScript Formatter from the Formatter Type dropdown.
• Write a JavaScript function to "unpack" the data received from the device, reversing any conversions you made before sending:

function Decoder(bytes, port) {
var decoded = {};
for (var i = 0; i < bytes.length; i += 3) {
var type = bytes[i];
var value = (bytes[i + 1] << 8) | bytes[i + 2];
switch (type) {
case 0x01: // Temperature (scaled and offset)
decoded.Temp_C = (value - 5000) / 100;
break;
case 0x02: // Humidity (scaled)
decoded.Humidity = (value- 5000) / 100;
break;
case 0x03: // Pressure (hPa)
decoded.Pressure_hPa = value;
break;
case 0x04: // Gas Resistance (raw Ohms)
decoded.Gas_Resistance_Ohm = value * 100;
break;
case 0x05: // IAQ (scaled)
decoded.IAQ = value / 100;
break;
case 0x06: // Dew Point (°C)
decoded.Dew_Point_C = value / 100;
break;
case 0x07: // Discomfort Index
decoded.Discomfort_Index = value / 100;
break;
case 0x08: // Heat Index (°C)
decoded.Heat_Index_C = value / 100;
break;
default:
decoded["Unknown_" + type] = value;
break;
}
}
return decoded;
}

2. Test and Save:

• On the same page, TTN provides fields to test your script with sample data. Input a test payload and verify the decoded output.
• Once the script works as expected, save it.

3. Monitor Data in TTN:

Step 8: Sending Data to Ubidots, Creating Dashboards, and Setting Alerts

In this final step, the goal is to complete the pipeline by:

Forwarding your sensor data from TTN to Ubidots using a webhook

Decoding the payload so the values can be understood and used by Ubidots

Visualizing the data on a live dashboard

Creating automated alerts (events) based on sensor conditions

This part transforms your raw IoT data into actionable insights, allowing you to monitor environmental conditions and respond to them in real time (e.g., send a warning when gas levels drop or lights turn on).

We’ve already covered how to format and decode the payload using a custom function, but the full setup—connecting TTN to Ubidots, configuring the webhook, setting up the dashboard, and building alerts—is covered step-by-step in the following external guide:

Step-by-Step Guide to Setting Up Webhooks in TTN and Integrating with Ubidots

Please refer to that guide to:

Set up your Ubidots account and plugin

Create and configure your webhook in TTN

Use the decoding function in Ubidots

Build visual dashboards and event triggers for your data

Once you've followed those instructions, your system will be fully functional—receiving live sensor readings, displaying them visually, and responding to environmental changes through alerts and automation.