Published October 6, 2020 © MIT

Programming ESP12F with an ESP8266 NodeMCU, the easy way

Learn how to program an esp12F with an esp8266 nodemcu board without adding buttons to reset and put it into flash mode.

BeginnerFull instructions provided1 hour2,052

Programming ESP12F with an ESP8266 NodeMCU, the easy way

Things used in this project

Hardware components

Espressif ESP8266 ESP-12E

NodeMCU ESP8266 Breakout Board

Story

Hi, so I was working on a project which requires a WS2812B RGB LED setup which an ESP12F module. the goal was to set up a web server for the RGB LEDs to change its colour.

version 2 of this

To accomplish this feat, we need a minimal ESP12F setup, which would be this-

now, this setup lets us program the ESP12F from an FTDI module by manually putting the ESP12F in flashing mode just by pressing buttons in the right sequence.

check out my previous post about ESP12F with FTDI

Materials required

ESP12F which you can buy from utsource.net
NodeMCU
10K resistors x 4
Jumper wires
10uF Capacitor
WS2812B LEDs

this setup works only if you know what are you doing, most of the time people make mistake in the button pressing sequence and this doesn't work.

SO what to do?

well, we can program the ESP12F module with another device which you might already have, a NodeMCU.

I saw Brain Lough on this topic using a NodeMCU board and ESP8266. and I thought I can add the NodeMCU on a proper PCB with all the resistance attached to make a permanent programmer for future ESP12F projects!

Schematic

this is the Schematic that we need to follow

after wiring everything together according to the schematic, we just need to upload the sketch to our setup with these settings-

Uploading the code

I have prepared a webserver for toggling the ws2812B which is based around Neopixel Library.

Select the port number of the NodeMCU (Tools->Port)
Select the Board type "NodeMCU 1.0 (ESP12-E Module)"
Click upload

and that's pretty much it, we don't need to select the "generic ESP8266 board" this time.

Results

1 / 2

Designing the Programming board-

In order to set an ESP8266 Programmer via NodeMCU, we need to Breakout the following pins:

Ground
GPIO 0
VCC
TX
RX
RST

we need these pins in both modules, the programmer and your project's PCB in my case this-

by preparing these two setups and hooking them together via Programming headers which consist of VCC, GND, Reset, GPIO0, TX and RX, we can flash ESP12F without adding external buttons for putting the ESP12F into flash mode.

Conclusion-

well, this auto-resetting and flashing without buttons is quite handy if you don't want to make a custom programmer with the same functions with adding transistors in the existing FTDI hookup sketch.

I mean the esp12F programming with NODEMCU setup is functional and can help you program ESP12F without any problem and effort.

so if you have any problem, just leave a comment!

Thanks

Code

neopixle_web_server.ino

// Neopixel
#include <Adafruit_NeoPixel.h>

// ESP8266
#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>

// Webserver Config
const char *ssid = ""; //put your WIFI ssid in between " "
const char *password = ""; // and password too
ESP8266WebServer server ( 80 );

// Neopixel Config
#define NeoPIN 2 //D4 is 2
#define NUM_LEDS 6 //define number of leds in your strip, mine is 6 
int brightness = 150;
Adafruit_NeoPixel strip = Adafruit_NeoPixel(NUM_LEDS, NeoPIN, NEO_RGB + NEO_KHZ800);


const int led = 13;

void setup ( void ) {

  Serial.begin ( 115200 );

  // ##############
  // NeoPixel start
  Serial.println();
  strip.setBrightness(brightness);
  strip.begin();
  strip.show(); 
  delay(50);
  Serial.println("NeoPixel started");
  
  // #########
  // Webserver
  pinMode ( led, OUTPUT );
  digitalWrite ( led, 0 );
  
  WiFi.begin ( ssid, password );
  Serial.println ( "" );

  // Wait for connection
  while ( WiFi.status() != WL_CONNECTED ) {
    delay ( 500 );
    Serial.print ( "." );
  }

  Serial.println ( "" );
  Serial.print ( "Connected to " );
  Serial.println ( ssid );
  Serial.print ( "IP address: " );
  Serial.println ( WiFi.localIP() );

  if ( MDNS.begin ( "esp8266" ) ) {
    Serial.println ( "MDNS responder started" );
  }

  // what to do with requests
  server.on ( "/", handleRoot );
  server.onNotFound ( handleNotFound );
  server.begin();

  
  
  Serial.println ( "HTTP server started" );
}

void loop ( void ) {
  // waiting fo a client
  server.handleClient();
}


void handleRoot() {
  Serial.println("Client connected");
  digitalWrite ( led, 1 );
  
  // data from the colorpicker (e.g. #FF00FF)
  String color = server.arg("c");
  Serial.println("Color: " + color);
  // setting the color to the strip 
  setNeoColor(color);

  // building a website
  char temp[5000];
  int sec = millis() / 1000;
  int min = sec / 60;
  int hr = min / 60;
  char clr [7];
  color.toCharArray(clr, 7);
  snprintf ( temp, 5000,

"<!DOCTYPE html>\n<html>\n\
  <head>\n\
    <title>Esp8266 NeoPixel Controler</title>\n\
    <style>\
      body { background-color: #cccccc; font-family: Arial; Color: #008; }\
    </style>\n\
    <meta name=\"viewport\" content=\"width=device-width, height=device-height, initial-scale=1.0, user-scalable=0, minimum-scale=1.0, maximum-scale=1.0\" />\n\
  </head>\n\
  <body>\n\
    <h1>R G B  Glasses BRO</h1>\n\
    <p>Uptime: %02d:%02d:%02d</p>\n\
    \n\
    <form action=\"\" name=\"pick\" method=\"post\">\n\
    <input type=\"color\" name=\"c\" value=\"%02d\" onchange=\"document.forms['pick'].submit();\" />\n\
    &nbsp;<span onclick=\"document.forms['pick'].submit();\" style=\"font-size:16pt;\"> CHANGE </span>\n\
    </form>\n\
    \n\
  </body>\
</html>",

    hr, min % 60, sec % 60, clr
  );
  server.send ( 200, "text/html", temp );
  digitalWrite ( led, 0 );
}

void handleNotFound() {
  digitalWrite ( led, 1 );
  String message = "File Not Found\n\n";
  message += "URI: ";
  message += server.uri();
  message += "\nMethod: ";
  message += ( server.method() == HTTP_GET ) ? "GET" : "POST";
  message += "\nArguments: ";
  message += server.args();
  message += "\n";

  for ( uint8_t i = 0; i < server.args(); i++ ) {
    message += " " + server.argName ( i ) + ": " + server.arg ( i ) + "\n";
  }

  server.send ( 404, "text/plain", message );
  digitalWrite ( led, 0 );
}



void setNeoColor(String value){
  Serial.print("Setting Neopixel...");
  // converting Hex to Int
  int number = (int) strtol( &value[1], NULL, 16);
  
  // splitting into three parts
  int r = number >> 16;
  int g = number >> 8 & 0xFF;
  int b = number & 0xFF;
  
  // DEBUG
  Serial.print("RGB: ");
  Serial.print(r, DEC);
  Serial.print(" ");
  Serial.print(g, DEC);
  Serial.print(" ");
  Serial.print(b, DEC);
  Serial.println(" ");
  
  // setting whole strip to the given color
  for(int i=0; i < NUM_LEDS; i++) {
    strip.setPixelColor(i, strip.Color( g, r, b ) );
  }
  // init
  strip.show();
  
  Serial.println("on.");
}