Step 1: Components
Step 2: Preparing the power strip
Step 3: Measuring and cutting
Step 4: Drilling
Step 5: Scheme
Step 6: Mounting the plexiglass board
Step 6: Mounting ESP8266
Step 7: ESP8266 flashing firmware
Step 8: Testing HTTP server on ESP8266

Published April 7, 2017 © GPL3+

ESP8266 WiFi Remote Relay Switch

This tutorial will show you how to convert an old power strip into a WiFi remote control to control electrical devices via Internet.

IntermediateFull instructions provided22,927

Things used in this project

Hardware components

ESP8266 ESP-12F D1 Mini

Power strip

Relay (generic)

250V 10A

Jumper wires (generic)

SparkFun Pushbutton switch 12mm

AC to DC Step Down Module Buck Converter Power Supply

220V turn 5V

Story

In this tutorial I will show you how to convert an old power strip into WiFi remote control. This will allow us to control electrical devices from the Internet via HTTP. For example, we will be able to turn on and off a heater, fan or light over the Internet. To build it I will use a popular electronic circuit, ESP8266 D1 mini. ESP8266 is a good platform for IOT (the Internet of things).

See this project here: ESP8266 WIFI Remote Relay Switch

Step 1: Components

ESP8266 D1 mini

Power strip

Relay Module 250V 10A

AC-DC buck step-down module 220V turn 5V

Button switch

Some wires

Step 2: Preparing the power strip

At the beginning I removed the broken switch and cleaned everything.

The broken switch

Step 3: Measuring and cutting

I measured and cut the plexiglass board for electronic circuits. For cutting, I used a hot wire foam cutter from a previous project. Follow the link to see how I built this tool.

Plexiglass cut with hot wire.

Step 4: Drilling

I drilled mounting holes for the plexiglass board. Then I mounted the plexiglass board inside the power strip.

Drilling of mounting holes, for plexiglass board.

Step 5: Scheme

Schematic of the electronic circuit

Step 6: Mounting the plexiglass board

The next step is assembling the plexiglass board and electronic circuits together. In this project, I only use one relay to control the power strip.

AC-DC step-down and relay module 250V 10A

Step 6: Mounting ESP8266

Because my power strip is made of metal, I'm afraid there might be a problem with the WiFi connection. That's why the ESP8266 is assembled inside a plastic case and screwed to the power strip.

ESP8266 D1 mini.

Step 7: ESP8266 flashing firmware

I had a problem with flashing firmware. My version of the ESP8266 D1 mini has something wrong with the RST pin, it does not work. That's why, I disconnect the USB cable from the computer instead of using the RST button. In this article, step by step, I described the entire software flashing procedure - SONOFF - ESP8266 update firmware with Arduino IDE.

Download source code: ESP8266_on_off.ino Before you upload the software to ESP8266 setup your WiFi connection.

#define WIFI_SSID ""
#define WIFI_PASSWORD ""

1 / 2 • Connect the USB cable to the ESP8266 D1 mini.

Step 8: Testing HTTP server on ESP8266

1 / 3 • Open serial monitor in Arduino IDE.

Open serial monitor in Arduino IDE.

Get your server IP from serial monitor.

Now open WWW page in your browser.

Now we can control the power strip using the web browser; we can also use the button on the plastic box.

ESP8266_on_off.ino

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>


//------------------------------------------
//SETUP LED
long time_led;
#define LED_DELAY 1000
#define LED_PIN 2


//------------------------------------------
//SETUP RELAY
#define RELAY0_PIN D2
#define RELAY1_PIN D1
#define RELAY2_PIN D5
#define RELAY3_PIN D6

//------------------------------------------
//SETUP BUTTON
#define BUTTON_PIN D3
#define BUTTON_DELAY 300

long t_button;

//------------------------------------------
//WIFI i server HTTP
ESP8266WebServer server(80);
#define WIFI_SSID ""
#define WIFI_PASSWORD ""
#define HOST_NAME "onoff"


bool button_last;
long t_now;

void setup() {
  //Setup pin mode
  pinMode(BUTTON_PIN, INPUT_PULLUP);
  pinMode(LED_PIN, OUTPUT); //Initialize onboard LED as output
  pinMode(RELAY0_PIN, OUTPUT);
  pinMode(RELAY1_PIN, OUTPUT);
  pinMode(RELAY2_PIN, OUTPUT);
  pinMode(RELAY3_PIN, OUTPUT);
  SW_all_off(); //Turn off all relays
  button_last = HIGH;

  //Setup UART
  Serial.begin(115200);
  Serial.println("");
  Serial.println("START");

  //Setup WIFI 
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
  WiFi.hostname( HOST_NAME );
  Serial.print("Connecting to WIFI");

  //Wait for WIFI connection
  while( WiFi.status() != WL_CONNECTED ) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to ");
  Serial.println( WIFI_SSID );
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  //Setup HTTP server
  server.on("/", handleRoot);
  server.on("/sw", handleSW);
  server.onNotFound(handleNotFound);
  server.begin();
  Serial.println("HTTP server started");
  
}
 
void loop() {
  t_now = millis();
  
  server.handleClient();

  //Blinking an LED
  if( t_now - time_led > LED_DELAY ){
    digitalWrite(LED_PIN, !digitalRead(LED_PIN));
    time_led = t_now;
  }

  //Check button
  bool b = digitalRead( BUTTON_PIN );
  if( b != button_last && t_now - t_button > BUTTON_DELAY ){
    if( b==HIGH && button_last==LOW ){
      SW(0, digitalRead( RELAY0_PIN ));
      Serial.println("BUTTON");
    }

    t_button = t_now;
    button_last = b;
  }
}

void SW_all_on(){
  digitalWrite(RELAY0_PIN, LOW);
  digitalWrite(RELAY1_PIN, LOW);
  digitalWrite(RELAY2_PIN, LOW);
  digitalWrite(RELAY3_PIN, LOW);
}

void SW_all_off(){
  digitalWrite(RELAY0_PIN, HIGH);
  digitalWrite(RELAY1_PIN, HIGH);
  digitalWrite(RELAY2_PIN, HIGH);
  digitalWrite(RELAY3_PIN, HIGH);
}

void SW(byte num, bool sw){
  switch( num ){
    case 0: digitalWrite(RELAY0_PIN, !sw); break;
    case 1: digitalWrite(RELAY1_PIN, !sw); break;
    case 2: digitalWrite(RELAY2_PIN, !sw); break;
    case 3: digitalWrite(RELAY3_PIN, !sw); break;
  }
}

void handleRoot(){
  String html = "<!DOCTYPE html>\r\n";
  html += "<html>\r\n";
  html += "<head>\r\n";
  html += "<meta charset='UTF-8'>\r\n";
  html += "<title>ESP8266</title>\r\n";
  html += "<body>\r\n";

  html += "ESP8266 - ";
  html += HOST_NAME;
  html += "\r\n";

  if( !digitalRead(RELAY0_PIN) ){
    html += "<a href='sw?sw=off' style='display: inline-block; width: 100px; background-color: red; text-align: center;'>OFF</a>\r\n";
  }else{
    html += "<a href='sw?sw=on' style='display: inline-block; width: 100px; background-color: green; text-align: center;'>ON</a>\r\n";
  }
  
  //html += "<br>\r\n";
  //html += "<a href='sw?sw=on'>LED On</a>\r\n";
  //html += "<a href='sw?sw=off'>LED Off</a>\r\n";
  
  html += "</body>\r\n";
  html += "</html>\r\n";

  
  server.send(200, "text/html", html);
}

void handleSW(){
  if (server.arg("sw")== "on"){
    SW(0, HIGH);
  }else{
    SW(0, LOW);
  }

  String ip = WiFi.localIP().toString();
  server.sendHeader("Location", String("http://") + ip, true);
  server.send ( 302, "text/plain", "");
  server.client().stop();
}

void handleNotFound(){
  String message = "File Not Found\n\n";
  message += "URI: ";
  message += server.uri();
  message += "\nMethod: ";
  message += (server.method() == HTTP_GET) ? "GET" : "POST";
  message += "\nArguments: ";
  message += server.args();
  message += "\n";
  for (uint8_t i=0; i<server.args(); i++){
    message += " " + server.argName(i) + ": " + server.arg(i) + "\n";
  }
  server.send(404, "text/plain", message);
}

ESP8266 WiFi Remote Relay Switch