For this tutorial you need
How to get kitty ears
Getting the circuit board
For this project, you need [BOM per pair]
The left board has the
The right board has the
To be sure
Make sure to connect the Arduino to the ATtiny as follows
Lastly

Published May 19, 2018 © GPL3+

Light Up Kitty Ears!

This 3D printed headset comes with custom cat-ear PCBs, created in Autodesk EAGLE and printed at OSHPark!

BeginnerFull instructions provided3 hours4,993

Things used in this project

Hardware components

5mm LED (need 8 of them) Bright White

ATTINY85-20PU-ND

Coin Cell Battery Holder

Resistor 10 OHM (need 2 of them)

Tactile Switch

Coin Cell Battery 3V

OSH Park Custom fabricated PCB

Software apps and online services

Autodesk Fusion

Autodesk EAGLE

Arduino IDE

OSH Park OSHPark Custom PCB Print

Hand tools and fabrication machines

Dremel 2050-15 Stylo+

Dremel 3D45 3D Printer

Soldering iron (generic)

Pliers

Story

LIGHT UP KITTY EARS! It's the second iteration of the cat ears so feel free to redesign, remix, reprogram or even reverse engineer anything and everything that I am about to show you! <3

This time - with the boards being printed at OSHPark, and an Hackster.io tutorial by me and Alex Glow that shows you how to solder these cute little boards!

1 / 2 • Anouk Wipprecht + Alex Glow of Hackster.io during 'tutorial makings'

For this tutorial you need:

3D printed CAT EAR headset which you can find attached

the custom PCB (either mill it or order one at OSHPark)

a set of electronic parts found above

To program the ATtiny you need:

an Arduino (UNO),

Electrolytic Decoupling Capacitors - 10uF/25V (1x),

jumping wires (M/M)

Tools you need: soldering iron, soldering wick, pliers, wire + your computer with Arduino installed.

All parts to make the 'Light Up Kitty Ears' including 5mm leds, 10 0hm resistors, ATtiny, coin cell battery, coin cell battery holder and a button.

How to get kitty ears:

The Kitty Ears can be obtained in a few ways, which you can choose from below:

1. Get them from Shapeways [EASY] Just CLICK THIS LINK and order them!

[SLS printing can be expensive but the quality is absolutely the best. But just to point out - I don't take a markup myself (meaning - I don't receive money for this!) the costs are printing costs only]

2. Print them yourself [MEDIUM] I added a link (.STL file) below. Download the file and import it to the 3D printer of your choice to 3D print the headset yourself. NOTE - you might need to tweak, cut, or align the design a bit to be printed well, as the design is originally created for SLS printing (powder printing) like Shapeways would print it for you. If it worked on your machine - let me know or share your results! I am using the OBJET Connex 500, and a Dremel 3D45 3D Printer and the results are good aside from support removal and polishing.

3. Redesign them with Fusion360 [EXPERT] In Fusion360 - AutoDesk's cool freeform and solid modelling software, you are able to import your file and customise from there. Whether you are new to CAD or already using parametric CAD software, Fusion360 can be cool for you to look into. You can find some tutorials on Instructables (like building a lamp) on how to work with this piece of software.

3D printed Cat Ears in Nylon (Black) - WHITE gives an even better effect (more glow)

Getting the circuit board:

Now - the circuit board will host the BRAIN of your design (the chip - in this case the ATtiny) amongst some other of the electronics. There are a few ways you can get the CUSTOM PCB's created with AUTODESK EAGLE:

1. Get them from OSHPARK (if you are in USA): HERE is the link to order the PCB's from OSHpark (3 boards for $13.20)

2. Mill them out yourself: If you have a mill, you can mill them out; we succeeded using an Othermill, the file is a bit different for this (see next step. I would say - this would be an easy solution and by def. the cheapest one around. So it might be worth checking your local Makerspace, Hackerspace, Fablab or TechShop if they have an mill that you can use)

3. Be creative: draw your circuit with conductive ink! This is an expertise question, but if you use conductive ink you might be able to draw the traces out by hand. Either way - if this experiment works out - let me know! ^^ #ElectronicKittyEars on twitter!

Custom PCB's you can order at OSHPark! (Purple <3)

You can skip this step when you are ordering your boards, but might you want to mill them out yourself - see Gerber ZIP file.

NOTE: since there are no plated through-holes, we added a large through-hole "test point" under the ATtiny to route one of the signals out. So a wire will need to be added through that hole and soldered on both sides if hole plating is not present!!

Milled Ear PCB's (milled on an Othermill)

For this project, you need [BOM per pair]:

Digikey (8) C512A-WNN-CZ0B0151-ND (8 leds in total, each pair)

Digikey (1) ATTINY85-20PU-ND (1 ATtiny in total, each pair)

Digikey (1) BAT-HLD-001-THM-ND (1 battery holder, each pair)

Digikey (2) 10.0AYTB-ND (2 resistors, 10 Ohm, each pair)

Digikey (1) P8010S-ND (1 button, each pair)

Digikey (1) P189-ND (1 3V coin cell battery, each pair*)

* feel free to take more coin cell batteries for if they empty out ;)

All parts (once more) for delicious kitty ear makings!

The first step is to take all elements and put them together on the board in the correct way so it looks like attached layout. NOTE that the both boards are not similar; they both are occupied differently:

The left board has the:

4 LEDs

2 resistors

Battery holder

ATtiny

The right board has the:

4 LEDs

Button

PCB - electronic parts layout <3

Here an small movie on how exactly to put the parts in.

'How To' in speed-up mode - to show you how / where to place the parts for soldering <3

To be sure:

Make sure you place the 5mm Bright White LED's the right way

Use 10 0hm resistors.

When you place thin wire in between the PCB's make sure it's insulated!

Ready? No - for sure not: You're missing your BRAIN! This is where the ATtiny comes in: the microcontroller.ATtiny is a cheap and powerful alternate when u don't need too many PWM pins. Since ATtiny85 is just a microcontroller we need a Arduino (Uno) to program. Otherwise our circuitry would be wayyy too big ;) Let's do it!

ARDUINO.CC INSTALLED? Make sure you have ARDUINO.CC installed on your computer (it's free // open source) or are working on a computer with the latest version of Arduino installed! Install ATtiny support on here if it's non discoverable.

COPY THE CODE! Attached (underneath) is the code - download this and place this in your 'Arduino' folder

PROGRAM THE ATtiny >> To program the ATtiny you need;

an Arduino (UNO),Electrolytic Decoupling Capacitors - 10uF/25V (1x),

jumping wires (M/M)

follow THIS INSTRUCTABLES TO KNOW HOW using the code that is attached to this step.

This is another way, but you need a few more parts for it: 'Program an ATtiny With Arduino' This way you have an LED indicator. For this, you will need:

Arduino

Breadboard

ATtiny85 (or ATtiny45)

10uF 16V electrolytic capacitor

220ohm 1/4 watt resistor

solid core hookup wire

Make sure to connect the Arduino to the ATtiny as follows:

Arduino +5V ---> ATtiny Pin 8

Arduino Ground ---> ATtiny Pin 4

Arduino Pin 10 ---> ATtiny Pin 1

Arduino Pin 11 ---> ATtiny Pin 5

Arduino Pin 12 ---> ATtiny Pin 6

Arduino Pin 13 ---> ATtiny Pin 7

After this, upload the sketch (code) to your Arduino as you would any other sketch.

Next up once you flashed in the animation for the LED, you can solder it directly to the board if you want!

NOTE the orientation!! [IMPORTANT] - there is a white dot on the PCB, it corresponds with the little dot/dent in the ATtiny - align them! So they both point the same direction.

Solder ahead! Make sure the tip of your soldering iron is clean! Since the legs are pretty close together.

After programming - make sure that the dot on the ATtiny is pointing left-downwards (see picture)

Lastly:

IF CORRECT - the next step what you can do is put the battery into the right ear and see if it flashes!

There are 3 animations in the chip: a chase, a glow and a twinkle, which will be followed by a short time-out [so don't think it's broken, when t's just resting;)] >> if this is allright you can wire the two ears together so you have access to the on/off button! :)

Blinkie Blinkie Blinkie ^^

Then:

Put them back into the headset (align the wire in the piece between the two ears) I personally keep them loose in the headset so I can take them out and change the battery. Another smart thing to do is to extend the button with an wire that you can mount on the side of the headset so it's easier reachable (or model a hole!).

CUSTOMISE!... And why leave these ears BLACK (?) No need! Get some fluff, make them fluffy, or take a marker and customise your ears to your style! Let's make our pawed friends proud <3

We put together the kitty ears at the Hackster studio!

Schematics

Code

Light Up Kitty Ears CODE

#include <avr/sleep.h>
#include <avr/interrupt.h>

#define PIN_LED_0  0
#define PIN_LED_1   1
#define PIN_LED_2   2
#define PIN_LED_3   3
//#define PIN_SWITCH  3

#define PIN_STATE_NO_CHANGE   0
#define PIN_STATE_INPUT         1
#define PIN_STATE_LOW           2
#define PIN_STATE_HIGH          3

void setPin(int pin, int state) {
  switch (state) {
    case PIN_STATE_INPUT:
      pinMode(pin, INPUT);
      digitalWrite(pin, LOW);
      break;
    case PIN_STATE_LOW:
      digitalWrite(pin, LOW);
      pinMode(pin, OUTPUT);
      break;
    case PIN_STATE_HIGH:
      digitalWrite(pin, HIGH);
      pinMode(pin, OUTPUT);
      break;
  }
}

void setLedPins(int pin0, int pin1, int pin2, int pin3) {
  setPin(PIN_LED_0, pin0);
  setPin(PIN_LED_1, pin1);
  setPin(PIN_LED_2, pin2);
  setPin(PIN_LED_3, pin3);
}

void setLed(int led, bool on = true) {
  switch (led) {
    case 0:
      setLedPins(
        on ? PIN_STATE_HIGH : PIN_STATE_LOW,
        PIN_STATE_INPUT,
        on ? PIN_STATE_LOW : PIN_STATE_HIGH,
        PIN_STATE_INPUT);
      break;
    case 1:
      setLedPins(
        on ? PIN_STATE_LOW : PIN_STATE_HIGH,
        PIN_STATE_INPUT,
        on ? PIN_STATE_HIGH : PIN_STATE_LOW,
        PIN_STATE_INPUT);
      break;
    case 2:
      setLedPins(
        PIN_STATE_INPUT,
        on ? PIN_STATE_HIGH : PIN_STATE_LOW,
        on ? PIN_STATE_LOW : PIN_STATE_HIGH,
        PIN_STATE_INPUT);
      break;
    case 3:
      setLedPins(
        PIN_STATE_INPUT,
        on ? PIN_STATE_LOW : PIN_STATE_HIGH,
        on ? PIN_STATE_HIGH : PIN_STATE_LOW,
        PIN_STATE_INPUT);
      break;
    case 4:
      setLedPins(
        on ? PIN_STATE_HIGH : PIN_STATE_LOW,
        PIN_STATE_INPUT,
        PIN_STATE_INPUT,
        on ? PIN_STATE_LOW : PIN_STATE_HIGH);
      break;
    case 5:
      setLedPins(
        on ? PIN_STATE_LOW : PIN_STATE_HIGH,
        PIN_STATE_INPUT,
        PIN_STATE_INPUT,
        on ? PIN_STATE_HIGH : PIN_STATE_LOW);
      break;
    case 6:
      setLedPins(
        PIN_STATE_INPUT,
        on ? PIN_STATE_HIGH : PIN_STATE_LOW,
        PIN_STATE_INPUT,
        on ? PIN_STATE_LOW : PIN_STATE_HIGH);
      break;
    case 7:
      setLedPins(
        PIN_STATE_INPUT,
        on ? PIN_STATE_LOW : PIN_STATE_HIGH,
        PIN_STATE_INPUT,
        on ? PIN_STATE_HIGH : PIN_STATE_LOW);
      break;
  }
}

bool getButton(void) {
  setLedPins(
    PIN_STATE_INPUT,
    PIN_STATE_LOW,
    PIN_STATE_INPUT,
    PIN_STATE_INPUT);
  digitalWrite(PIN_LED_0, HIGH);
  delay(5);
  bool result = (digitalRead(PIN_LED_0) == LOW) ? true : false;
  setLedPins(
    PIN_STATE_INPUT,
    PIN_STATE_INPUT,
    PIN_STATE_INPUT,
    PIN_STATE_INPUT);
  digitalWrite(PIN_LED_0, LOW);
  return result;
}

void sleep() {

    GIMSK |= _BV(PCIE);                     // Enable Pin Change Interrupts
    PCMSK |= _BV(PCINT3);                   // Use PB3 as interrupt pin
    ADCSRA &= ~_BV(ADEN);                   // ADC off
    set_sleep_mode(SLEEP_MODE_PWR_DOWN);    // replaces above statement

    sleep_enable();                         // Sets the Sleep Enable bit in the MCUCR Register (SE BIT)
    sei();                                  // Enable interrupts
    sleep_cpu();                            // sleep

    cli();                                  // Disable interrupts
    PCMSK &= ~_BV(PCINT3);                  // Turn off PB3 as interrupt pin
    sleep_disable();                        // Clear SE bit
    ADCSRA |= _BV(ADEN);                    // ADC on

    sei();                                  // Enable interrupts
    } // sleep

ISR(PCINT0_vect) {
    // This is called when the interrupt occurs, but I don't need to do anything in it
}

// the setup routine runs once when you press reset:
void setup() {
  pinMode(PIN_LED_0, INPUT);
  pinMode(PIN_LED_1, INPUT);
  pinMode(PIN_LED_2, INPUT);
  pinMode(PIN_LED_3, INPUT);
}

// the loop routine runs over and over again forever:
void loop() {
  static int led = 0;
  static bool on = true;
  
  static bool lastButton = false;
  bool button = false;

  button = getButton();
  if (button != lastButton) {
    if (button) {
      on = !on;
    } else if (!on) {
      // Time to go to sleep
      setLedPins(
        PIN_STATE_INPUT,
        PIN_STATE_LOW,
        PIN_STATE_INPUT,
        PIN_STATE_INPUT);
      digitalWrite(PIN_LED_0, HIGH);
      for (bool wake = false; !wake; ) {
        sleep();
        delay(20);
        if (digitalRead(PIN_LED_0) == LOW) {
          wake = true;
        }
      }
      on = button = true;
    }
    lastButton = button;
  }

  if (on && !button) {
    setLed(led, true);
  } else {  
    setLedPins(
      PIN_STATE_INPUT,
      PIN_STATE_INPUT,
      PIN_STATE_INPUT,
      PIN_STATE_INPUT);
  }
  
  if (++led >= 8) led = 0;
  delay(25);

}

Credits

Anouk Wipprecht

1 project • 32 followers

Dutch FashionTech Designer, Tinkerer and Creative.

Light Up Kitty Ears!