Published March 23, 2020 © CC BY-NC-SA

Smart Workbench Power

The device utilizes the Pyroelectric Infrared Sensor to automatically power down the electric power to the tools at the work bench if idle.

IntermediateFull instructions provided8 hours899

Things used in this project

Hardware components

KEMET Electronics Corporation Proximity Sensor- Pyroelectric Infrared Sensor Module

Espressif Wemos D1 Mini

Tactile Switch, Top Actuated

LED (generic)

Buzzer

3.3V Relay Module For Arduino And Raspberry Pi

Software apps and online services

Arduino IDE

Blynk

Hand tools and fabrication machines

3D Printer (generic)

Soldering iron (generic)

Story

Introduction

There are a lot of heat generating tools such as soldering iron, hot air working station etc. at the work bench that are potential fire hazards if left powered on for long period of time. Utilize the KEMET Pyroelectric Infrared Proximity Sensor and Blynk IoT, this smart socket will detect the human presence near the work bench, and automatically turn the power off if nobody is around for an extended period of time to improve the work bench safety, and save energy. The power and motion sensor can also be controlled, monitored and tracked remotely over the Internet from smartphones using Blynk App.

How it works

There are many smart plugs are available on the market but few of them features built-in PIR sensors for power management. Meanwhile the PIR sensors are mainly used for light controls and security applications. This project explores a new application to combine the PIR sensor with IoT connected power socket. Let's get started.

For this project, a KEMET Infrared Sensors is used. KEMET's SS-430L-N (Neutral Lens) sensor use the pyroelectric effect of ceramic by absorbing infrared rays emitted from the human body. The sensor detects the natural infrared signature produced by humans without using lenses.

I found that sensor is very sensitive. If used without additional covers, it will be triggered constantly by minute environmental temperature changes. In order to use it as a human body proximity senor, I experimented with different thickness of 3D printed covers and designed a 3D printed spherical sensor mount which helps to make the sensing area more 'directional' with appropriate level of sensitivity. Two layers of red PLA (approximately 0.4-0.5 mm in thickness) provides reasonably good filtering property.

1 / 2 • The PIR Sensor Dome

At the core of this device there is a time delay relay. Its off delay timer is controlled by a wifi enabled microprocessor with auto reset. A WeMos Mini D1 R1 board is used. The WeMos Mini is a mini wifi board with 4MB flash based on ESP-8266EX. It has a micro USB connection that makes the flashing the Arduino sketch very easy. The SS-430L-N has an output voltage of 3V DC which is compatible with the ESP-8266's pin input voltage, so they can be connected directly.

The relay controls the power output and can be triggered both locally or remotely. For safety reasons, the power only can be turned on on-demand either by pressing the button on the device, or remotely from the Blynk App. Once the power is turned on, the PIR sensor will keeps monitoring if there's human presence nearby. As soon as motion is detected, the off delay timer will be reset and restart. If there has been no motion detected for a extend period of time, for example 15 minutes, then the time is up and the power will be disconnected automatically. The power can also be shut off manually locally or remotely at any time. The device also functions as a motion sensor and keep monitoring the room constantly. A LED will turn on once the motion is detected with the pyroelectric sensor as visual cue. The buzzer will also emit different sound patterns as the device status changes.

Blynk dashboard

On the Blynk dashboard, virtually there is one power button and two LEDs. One LED shows the power status, another LED is the PIR sensor indicator and will illuminate if there's motioned detected. Additionally, there's also a chart available on the dashboard to display live and historical PIR sensor data. So the user can monitor remotely activities near the workbench.

1 / 2 • Smart Workbench Power Blynk Dashboard

Custom parts and hardware hookup

With a FDM 3D printer, I printed all the parts use PLA with 25% infill. The STL files are attached. Wiring the rest of the circuit according to the wiring schematic as well as the comments in the Arduino sketch. The pictures below show the detailed parts, circuit assembly and finished product of the Smart Workbench Power. I used a 5v power supply inside the case as power source. It is also possible to power it from the USB port. You can use the power socket and plug as shown in the picture. Use caution when working with mains voltage.

1 / 3 • Install the KEMET sensor inside the dome

Setting up the Blynk app

Download Blynk app to your phone or tablet, register and sign in your account.

Create a New Project.
Select WeMos D1 mini as Device model.
Copy the AUTH TOKEN to be used in the code.
Include two LED and a Styled Button widget.
Include a SuperChart widget.
Includes a Push Notification widget.
Press Play (Triangle icon at upper right corner)

1 / 6 • Step 1. Create new project with WeMos D1 mini

Programming

You'll need to download the latest version of the Arduino IDE which is available at https://www.arduino.cc/en/Main/Software, and add ESP8266 board to your boards manager. There are a lot of great tutorials can be found online, I will skip the step-by-step instructions here.

1. Install the Blynk library for ESP8266 from https://github.com/blynkkk/blynk-library

2. Connect your WeMos D1 mini to the computer use USB cable and load the sketch.

An example Arduino sketch is attached with 10 minutes no motion time-out for demonstration purpose. There are many additional improvements such as turning the PIR function on/off, setting customized delay timer etc. can be implemented.

// Set up no motion time-out value in seconds
#define timeSeconds 600

Before uploading, make sure to paste your authorization token into the auth [] variable. Also make sure to load your Wifi network settings into the ssid[] and pass[] variables.

// You should get Auth Token in the Blynk App.
char auth[] = " ";
// Your WiFi credentials.
char ssid[] = " ";
char pass[] = " ";

Put it into action

The sensor have a active range around 1 meter (3 feet). You can turn the dome to the desired orientation to minimize false triggering. I set it up next to the soldering iron handle so it will be monitoring the hand movement on the work bench surface. The video shows how everything works.

Smart workbench power placement

Smart workbench power demostration

Schematics

Code

Smart workbench power demo

/**The MIT License (MIT)
Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:
The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.
*/

#define BLYNK_PRINT Serial    // Comment this out to disable prints and save space
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>

// You should get Auth Token in the Blynk App.
char auth[] = " ";

// Your WiFi credentials.
char ssid[] = " ";
char pass[] = " ";

// Set up no motion time-out value in seconds
#define timeSeconds 600

// Set pins for LED and PIR Motion Sensor
const int SensorPin = D1;
const int buttonPin =D6;
const int Relay = D5;
const int ledPw =D2;
const int ledPin =D7;
const int Buzzer =D8;

WidgetLED led1(V0);
WidgetLED led2(V2);

boolean vPinState =  false;        // Set the default virtual pin state  
boolean powerState = false;       // Set the power state
boolean startTimer = false;

int Sensor = 0;        
int buttonState;  // Set the PIR sensor input pin state
int lastButtonState = LOW;

unsigned long lastDebounceTime = 0;  // the last time the output pin was toggled
unsigned long debounceDelay = 50;    // the debounce time; increase if the output flickers

// Timer: Auxiliary variables
unsigned long now = millis();
unsigned long lastTrigger = 0;

void setup(){
  Serial.begin(9600);
  delay(10);
  Blynk.begin(auth, ssid, pass);  
    while (Blynk.connect() == false) {      
    // Wait until connected              
  }    
  pinMode(buttonPin, INPUT_PULLUP);
  pinMode(Relay, OUTPUT);
  pinMode(ledPin, OUTPUT);
  pinMode(Buzzer, OUTPUT);
  pinMode(ledPw, OUTPUT);
  
  // PIR Motion Sensor mode INPUT
  pinMode(SensorPin, INPUT);

  digitalWrite(Relay, HIGH);
  digitalWrite(ledPw, LOW);
  digitalWrite(ledPin, LOW);
  digitalWrite(Buzzer, LOW);
}

void loop(){

  int reading = digitalRead(buttonPin);

  if (reading != lastButtonState) {
    lastDebounceTime = millis();
  }

if ((millis() - lastDebounceTime) > debounceDelay) {
     if (reading != buttonState) {
      buttonState = reading;
      if (buttonState == LOW) {
        powerState = !powerState;
        if(powerState){
        startTimer = true;  //manually start power
        lastTrigger = millis();  
        buzzer2(2);
        }else{startTimer = false;  //manually turn off power
        buzzer2(3);
        }
      }
    }
  }

  lastButtonState = reading;

  Serial.print("Power State=  ");
  Serial.println(powerState);
  now = millis();
  if(powerState && startTimer && (now - lastTrigger < (timeSeconds*1000))) {
    Serial.println("Power on...");
    digitalWrite(ledPw, HIGH);
    digitalWrite(Relay, LOW);
    Blynk.virtualWrite(V1, HIGH);
    led1.on();
  }else{
    Serial.println("Power off...");
    digitalWrite(ledPin, LOW);
    digitalWrite(ledPw, LOW);
    digitalWrite(Relay, HIGH);
    Blynk.virtualWrite(V1, LOW);
    led1.off();
    if (powerState && startTimer && (now - lastTrigger > (timeSeconds*1000))){
    Serial.println("Power auto off has commenced...");
    Blynk.notify("Power auto off has commenced...");
    buzzer2(5); //Beep 5 times for automatic shutoff
    } 
    powerState = false;
    startTimer = false;
    }
   checkSensor();  
   Blynk.run();  
}

void checkSensor(){
    Sensor = digitalRead(SensorPin);
    if (Sensor == HIGH){
    Serial.println("MOTION DETECTED!!!");  
    digitalWrite(ledPin, HIGH);
    led2.on();
    startTimer = true;
    lastTrigger = millis();
    delay(500);
    }else{
    digitalWrite(ledPin, LOW);
    led2.off();
    }
} 

BLYNK_CONNECTED(){
    Blynk.virtualWrite(V1, LOW);
    led1.setColor("#D3435C");
    led2.setColor("#ED9D00");
  }

BLYNK_WRITE(V1)  
{  
  // Get the virtual input state  
  int vPinState = param.asInt();  
  // If the virtual input went high  
  if(vPinState==1)  
  {   
   Serial.println("Power remote on");
   powerState = true;
   startTimer = true;
   now = millis();
   lastTrigger = millis();
   Blynk.setProperty(V1, "onColor", "#D3435C");  //RED  
   buzzer2(2);
   Blynk.run();
  } 
  
  if(vPinState == 0){
   powerState = false;
   startTimer = false;
   Blynk.setProperty(V1, "offColor", "#5F7CD8");  //BLUE 
   Serial.println("Power remote off");   
   buzzer2(3);
   Blynk.run();
   } 
 }  

void buzzer2(int num){
  uint8_t i;
  for (i=0; i<num; i++){
    digitalWrite(Buzzer, HIGH);
    delay(100);
    digitalWrite(Buzzer, LOW);
    delay(100);
    }
 }

Credits

ArtSuzhou

8 projects • 29 followers

Smart Workbench Power

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Introduction

How it works

Blynk dashboard

Custom parts and hardware hookup

Setting up the Blynk app

Programming

Put it into action

Custom parts and enclosures

Smart power front cover

Smart power PIR sensor dome

Smart power PIR snsor dome retainer

Smart power case

Smart power case rear cover

Wemos D1 mini mounting plate

Smart power push button retainer

Schematics

Smart power schematics

Code