Plant Monitoring with Agrumino and Air Humidity Sensor

Environmental parameters sensing and transmission from Agrumino to Thingspeak platform.

BeginnerProtip2 hours187

Plant Monitoring with Agrumino and Air Humidity Sensor

Things used in this project

Hardware components

Lifely Agrumino

Adafruit GY-21

Software apps and online services

Arduino IDE

ThingSpeak API

Story

The task of our project is to sense environmental parameters, like temperature, luminance, moisture, humidity, and to transmit them to an IoT platform, in order to monitor the vital parameters of a plant.

For the implementation of this project, we use a lively Agrumino and a humidity sensor with an I2C interface. We decided to use Thingspeak as the IoT platform to receive the data measured by the sensors.

Thingspeak setup

Thingspeak is an IoT platform, which allows to monitor, store and analyse live data streams collected from sensors or connected devices.

In order to be able to use this platform, we need to go to https://thingspeak.com/ and create a Thingspeak account.

Once we log in, we need to create a new channel, which allows us to collect all the data associated with our project.

In our case, the "fields" (data) that we want to include and visualize in the channel are the battery voltage and the battery level of Agrumino, the soil moisture (expressed in % and in mV), the air humidity, the luminance and the environmental temperature sensed by Agrumino.

Channel setting

In the newly created channel, two API Keys are provided: one needed to read the data sent from Agrumino and one hypothetically needed to send data.

Hardware setup

The moisture sensor should be connected to the Agrumino board on the indicated port in the figure, and it interfaces with the board using the I2C protocol.

The I2C address of the humidity sensor is 0x40.

1 / 2 • I2C port

As shown in the figure, the red wire is connected to the power supply, the black wire is connected to the ground, the yellow wire is connected to the SCL signal, and the white wire is connected to the SDA signal.

The communication between Agrumino and the humidity sensor has been implemented using a library that can be downloaded from the following GitHub link.

Code setup

First, you need to download the code from the provided link. Once opened, you have to insert your WIFI SSID in the "SSID_NAME" string and the password in the "SSID_PASSWORD" string. Also, replace your API KEY in the "writeAPIKey" constant.

Setup

After this, you can start using your Agrumino to monitor the plant.

The communication between Agrumino and Thingspeak occurs as follows: first, data acquisition takes place, and then the data is transmitted to the platform through an HTTP GET request.

Data sensing

Data transmission

Once the data is transmitted, it can be viewed in real-time on ThingSpeak.

1 / 2 • Thingspeak data

After the information is transmitted, the system enters "deep sleep" mode to avoid unnecessary power consumption of the battery.

To turn off the system:

Conclusion

This project provides a simple way to communicate data over the Internet concerning vital parameters for plant monitoring.

It is easily scalable for additional parameters (obtainable with the integration of additional types of sensors), making it a starting point for a future work.

A possible way could be the integration of a notification system based on events that alerts when threshold values are exceeded during the operation of the device.

Agrumino code

/*AgruminoThingspeak.ino - Very seimple project for Agrumino board using the Agrumino library.
  Created by gabriele.foddis@lifely.cc
  This sketch send data in your thingspeak account.
  For this sketch is necessary a thingspeak account ( free account available)*/

#include <Agrumino.h>
#include <ESP8266WiFi.h>
#include "GY21.h"

#define SSID_NAME ""///Insert your wifi name" 
#define SSID_PASSWORD  "" ///Insert your wifi password"
const char* writeAPIKey = ""; ////API key of your channel

#define CONNECTION_ATTEMPS 100 ///Maximum number of connection attempt
#define BAUD_RATE 115200 ///Serial baud rate
#define MIN_TO_MS (1000000 * 60)
int agruminoId = ESP.getChipId();
const char* host = "api.thingspeak.com";
unsigned int SLEEP_TIME_MIN = 2; /*only minute sleep, max 60 minute */
int wifiCount = 0;

Agrumino agrumino;
GY21 sensor;

void blinkLedConnect() {
  agrumino.turnLedOn();
  delay(200);
  agrumino.turnLedOff();
  delay(200);
  agrumino.turnLedOn();
  delay(200);
  agrumino.turnLedOff();
  delay(200);
  agrumino.turnLedOn();
  delay(200);
  agrumino.turnLedOff();
}

void blinkLed() {
  agrumino.turnLedOn();
  delay(200);
  agrumino.turnLedOff();
}

void setup() {

  Serial.begin(BAUD_RATE);
  agrumino.setup();
  agrumino.turnBoardOn();
  wifiSetup();
}

void wifiSetup() {

  Serial.print("Connecting to ");
  Serial.println(SSID_NAME);
  WiFi.mode(WIFI_STA);
  WiFi.begin(SSID_NAME, SSID_PASSWORD);


  while ((WiFi.status() != WL_CONNECTED) && (wifiCount < CONNECTION_ATTEMPS))
  {
    delay(500);
    wifiCount++;
    Serial.print(".");
      
  }

  if (wifiCount >= CONNECTION_ATTEMPS)
  {
    Serial.println("Failed to connect,...sleep....");
    agrumino.turnBoardOff(); // Turn Board off before sleep to save battery :)
    ESP.deepSleep(MIN_TO_MS * SLEEP_TIME_MIN);
  }
  else if (WiFi.status() == WL_CONNECTED) {

    Serial.println("I'm Connected with:"  );
    Serial.println(SSID_NAME);
    delay(100);
  }
}

void loop() {
  

  if (WiFi.status() == WL_CONNECTED)
  {
    blinkLedConnect();
  }
  
  WiFiClient client;
  const int httpPort = 80;
  if (!client.connect(host, httpPort)) {
    return;
  }
  Serial.println("#########################\n");

  boolean isAttachedToUSB =   agrumino.isAttachedToUSB();
  boolean isBatteryCharging = agrumino.isBatteryCharging();
  boolean isButtonPressed =   agrumino.isButtonPressed();
  float temperature =         agrumino.readTempC();
  float soilMoistureMv =      agrumino.readSoilRaw();
  float soilMoisturePerc =    agrumino.readSoil();
  float illuminance =         agrumino.readLux();
  float batteryVoltage =      agrumino.readBatteryVoltage();
  unsigned int batteryLevel = agrumino.readBatteryLevel();

  Wire.begin(SDA, SCL);
  float air_humidity = sensor.GY21_Humidity();

  int agruminoId = ESP.getChipId();


  Serial.println("");
  Serial.println("isAttachedToUSB:   " + String(isAttachedToUSB));
  Serial.println("isBatteryCharging: " + String(isBatteryCharging));
  Serial.println("isButtonPressed:   " + String(isButtonPressed));
  Serial.println("temperature:       " + String(temperature) + " C");
  Serial.println("soilMoistureMv:    " + String(soilMoistureMv) + " mV");
  Serial.println("soilMoisture%:     " + String(soilMoisturePerc) + "%");
  Serial.println("illuminance :      " + String(illuminance) + " lux");
  Serial.println("batteryVoltage :   " + String(batteryVoltage) + " V");
  Serial.println("batteryLevel :     " + String(batteryLevel) + "%");
  Serial.println("Air humidity :     " + String(air_humidity) + "%");
  Serial.println("");

  //Write data, channel settings.

  String url = "/update?key=";
  url += writeAPIKey;
  url += "&field1="; 
  url += String(temperature * 1000);
  url += "&field2=";
  url += String(soilMoistureMv);
  url += "&field3=";
  url += String(soilMoisturePerc);
  url += "&field4=";
  url += String(illuminance);
  url += "&field5=";
  url += String(batteryVoltage);
  url += "&field6=";
  url += String(batteryLevel);
  url += "&field7=";
  url += String(agruminoId);
  url += "&field8=";
  url += String(air_humidity);
  url += "\r\n";


  // Request to the server
  client.print(String("GET ") + url + " HTTP/1.1\r\n" +
               "Host: " + host + "\r\n" +
               "Connection: close\r\n\r\n");

  blinkLed();
  agrumino.turnBoardOff(); // Board off before delay/sleep to save battery :)
  Serial.println("sleep mode enabled.....bye");
  ESP.deepSleep(MIN_TO_MS * SLEEP_TIME_MIN);
}