Published November 22, 2022

CO2 Monitoring and Early Warning Using Wio Terminal

Wio Terminal with SCD30 sensor to measure the indoor air quality and remind you.

BeginnerFull instructions provided1 hour983

CO2 Monitoring and Early Warning Using Wio Terminal

Things used in this project

Hardware components

Seeed Studio Wio Terminal

Seeed Studio Grove - CO2 & Temperature & Humidity Sensor (SCD30)

Software apps and online services

Arduino IDE

Story

Overview

Winter has come. Do you often feel sleepy? Do you know why winter is sleepier than summer? One is that in winter we often eat more, sleep more, and wear more clothes, which makes us prone to sleepiness. It is more because we are in a closed indoor environment for a long time in winter, and excessive carbon dioxide（CO2） will make people feel sleepy.

Excessive levels of CO2 in a crowded office can cause irritability and heart palpitations. In addition, if the concentration of CO2 accumulated overnight in a closed bedroom is too high, people will feel breathless and anxious the next morning.

How much concentration of PPM is harmful to the human body? According to research:

When the indoor CO2 concentration is below 700ppm, it belongs to clean air, and people will feel very comfortable.
When CO2 concentration is 700ppm to 1000ppm, it is still normal, which belongs to ordinary air, but some sensitive people will have a bad feeling.
When CO2 concentration exceeds 1000ppm, but the air is in a critical stage in the range of 1500ppm, people feel dull, begin to lose concentration, and have heart palpitations.
When CO2 concentration reaches 1500ppm to 2000ppm, the air is considered to be slightly polluted, it can cause headache, dizziness, and difficulty breathing.
And if it exceeds 2000ppm, it is considered to be seriously polluted. We don’t even want to continue working, and our ability of thinking is significantly reduced.

Therefore, knowing the concentration of carbon dioxide in the air is very useful for our work and life. This project detects carbon dioxide, humidity, and temperature and displays these data on Wio Terminal. Let the air quality of each scene be clear at a glance, and remind you to open windows for ventilation.

Hardware Setup

We will be using Grove CO2 sensor (SCD30)for CO2 level measurement. The Grove - SCD30 is a 3-in-1 Arduino sensor that can measure CO2, temperature, and humidity. Based Sensirion SCD30, is a Non-Dispersive Infrared(NDIR) carbon dioxide sensor with high precision and wide measurement accuracy. It would be a perfect choice if you are looking for a multifunctional sensor for your Arduino weather station or other environmental projects.

Wio Terminal is compatible with Arduino and Micropython and is built with an ATSAMD51 microcontroller with wireless connectivity supported by Realtek RTL8720DN. Its CPU speed runs at 120MHz (Boost up to 200MHz). Realtek RTL8720DN chip supports both Bluetooth and Wi-Fi providing the backbone for IoT projects. The Wio Terminal is Highly Integrated with a 2.4” LCD Screen, there is an onboard IMU(LIS3DHTR), microphone, buzzer, microSD card slot, light sensor, and infrared emitter(IR 940nm).

There are built-in magnets and two mounting holes on the well-designed enclosure, allowing you to set up your IoT project without hassle.

Development Environment

The application is developed, compiled, and flashed using Arduino IDE. Please download the latest Arduino IDE and follow Seeed's wiki to install it. To install the Wio Terminal board library, open the Arduino IDE, click on File > Preferences, and copy the below URL to Additional Boards Manager URLs: https://files.seeedstudio.com/arduino/package_seeeduino_boards_index.json

Click on Tools > Board > Board Manager Search Wio Terminal and click on install. And you would need to select the board and port using the Tools > Board menu.

To install the library for the Grove CO2 Sensor (SCD30):

Step 1. Download the Seeed SCD30 Library Library from Github.
Step 2. Refer to How to install library for Arduino.
Step 3. Restart the Arduino IDE. Open the example, and open it directly in the Arduino IDE via the path: File → Examples →Grove_scd30_co2_sensor→SCD30_Example.

Project Step Description

Step 1: Connect Wio Terminal and sensor.

Step 2: interface design, display text, and pictures: Press the "A" key to display the temperature, humidity, and CO2 value

Step 3: The buzzer sounds when the warning value is reached

When CO2<700, normal level, display picture 0
700<=CO2<1000, a little bad feeling, display picture 1
1000<=CO2<1500, causing slight discomfort, display picture 2
1500<=CO2<2000, the air is slightly polluted, display picture 3, and the buzzer alarms at the same time
CO2>=2000, serious pollution, display picture 4 and the buzzer alarms at the same time

Demo

Conclusion

There are many other possibilities for this project. In the future, I want to use the built-in WiFi module of Wio Terminal to upload data to the cloud, and then display the data on the PC and mobile terminals. Data early warning is more intelligent, and remote monitoring will make smart homes more convenient.

Thanks to KeHoSoftware and Seeed wiki for inspiration and help, I was able to start the journey of learning and making projects in Wio Terminal.

wioterminal_co2_traffic_light.ino

  #include"TFT_eSPI.h"
   TFT_eSPI tft;
   #define LCD_BACKLIGHT (72Ul)
   bool tft_backlight = true;
   #include <Arduino.h>
   #include "Seeed_FS.h" 
   #include "RawImage.h"
   #include "Free_Fonts.h"       


   #include "SCD30.h"
   int grove_scd30_co2   = 0;
   int grove_scd30_temp  = 0;
   int grove_scd30_humi  = 0;
   int scd30_temp_offset = -4;
   int scd30_humi_offset = 13;
   
   
   void sensor_co2()
   {
     float result[3] = {0};
  
     if (scd30.isAvailable()) 
     {
      scd30.getCarbonDioxideConcentration(result);
      grove_scd30_co2  = result[0];
      grove_scd30_temp = result[1];
      grove_scd30_humi = result[2];
      // serial print of all sensor values
      Serial.print(F("[?] GROVE SCD30 CO2 --> "));
      Serial.print("SCD30-CO2:"); Serial.print(grove_scd30_co2); 
      Serial.print("  SCD30-T:"); Serial.print(grove_scd30_temp+scd30_temp_offset);  
      Serial.print("  SCD30-H:"); Serial.println(grove_scd30_humi+scd30_humi_offset);
      // display co2 pictures on TFT
      const char* list[] = {"co2-low-rgb565.bmp", "co2-mid1-rgb565.bmp", "co2-mid2-rgb565.bmp", "co2-high1-rgb565.bmp", "co2-high2-rgb565.bmp"};
      // rgb traffic light (planned)
      int r,g,b;
      uint8_t cnt = 0;
      if (grove_scd30_co2<700)   { r=0;   g=127; b=0; cnt=0; }
      if (grove_scd30_co2>=700)  { r=0;   g=127; b=0; cnt=1; }
      if (grove_scd30_co2>=1000) { r=127; g=127; b=0; cnt=2; }
      if (grove_scd30_co2>=1500) { r=127; g=0;   b=0; cnt=3; wio_buzzer();}
      if (grove_scd30_co2>=2000) { r=127; g=0;   b=0; cnt=4; wio_buzzer();} 
      drawImage<uint16_t>(list[cnt],0,0); 
      tft.setTextColor(TFT_BLACK,TFT_WHITE);
      tft.setFreeFont(FMB18);
      tft.drawNumber(grove_scd30_co2,80,190);                 
     }
   }
  
  void wio_buzzer(){
    analogWrite(WIO_BUZZER, 128);
    delay(1000);
    analogWrite(WIO_BUZZER, 0);
    delay(1000);
    
    }

   // this timer is used to update tft display
   unsigned long previousMillis = 0;
   // send every 10 minutes
   // unsigned long interval = 600000;  
   // send every 3 minutes
   // unsigned long interval = 180000;
   // send every 30 seconds
   unsigned long interval = 30000;   
   unsigned long counter  = 0; 


void tft_display_status_bar(String room_name, long int room_bg) 
{
  tft.fillRect(0,0,320,50,room_bg);
  tft.setFreeFont(FMB18);
  tft.setTextColor(TFT_WHITE);
  tft.setCursor((320 - tft.textWidth(room_name)) / 2, 32);
  tft.print(room_name); 
}


void tft_display_room_screen(String room_name, long int room_bg) 
{
  tft.fillScreen(TFT_WHITE);
  tft.fillRect(0,0,320,50,room_bg);
  tft.setFreeFont(FMB18);
  tft.setTextColor(TFT_WHITE);
  tft.setCursor((320 - tft.textWidth(room_name)) / 2, 32);
  tft.print(room_name);
  // drawing verticle line
  tft.drawFastVLine(150,50,190,TFT_DARKGREEN);
  // drawing horizontal line
  tft.drawFastHLine(0,140,320,TFT_DARKGREEN);  
}


void tft_display_sensor_temperature(int temperature) 
{
  // setting the temperature
  tft.setTextColor(TFT_BLACK);
  tft.setFreeFont(FMB9);
  tft.drawString("Temperature",15,65);
  tft.setTextColor(TFT_BLACK);
  tft.setFreeFont(FMB18);
  tft.drawNumber(temperature,50,95);
  //tft.drawNumber(21,50,95);
  tft.setFreeFont(FMB12);
  tft.drawString("C",100,95);  
}

void tft_display_sensor_humidity(int humidity) 
{
  // setting the humidity
  tft.setTextColor(TFT_BLACK);
  tft.setFreeFont(FMB9);
  tft.drawString("Humidity",30,160);
  tft.setTextColor(TFT_BLACK);
  tft.setFreeFont(FMB18);
  tft.drawNumber(humidity,50,190);
  tft.setFreeFont(FMB12);
  tft.drawString("%",100,190);
}


void tft_display_sensor_co2(int co2) 
{ 
  // setting the CO2
  tft.setTextColor(TFT_BLACK);
  tft.setFreeFont(FMB9);
  tft.drawString("CO2",220,160);
  tft.setTextColor(TFT_BLACK);
  tft.setFreeFont(FMB18);
  tft.drawNumber(co2,160,190);
  tft.setFreeFont(FMB12);
  tft.drawString("ppm",250,190);
}


void setup() 
{
  Serial.begin(9600);
  delay(3000);
  Serial.println(F(" "));
  Serial.println(F(" "));
  Serial.println(F("Starting..."));
  Serial.println(F("WioTerminal CO2 Traffic Light Version 1.00"));
  Serial.println(F("GROVE SCD30 connected via I2C"));
  Serial.println(F(" "));

  pinMode(WIO_KEY_A, INPUT_PULLUP);
  pinMode(WIO_KEY_B, INPUT_PULLUP);
  pinMode(WIO_KEY_C, INPUT_PULLUP);
  pinMode(WIO_BUZZER, OUTPUT);


  Serial.println(F("[?] SD card initialize.."));
  if (!SD.begin(SDCARD_SS_PIN, SDCARD_SPI)) 
  {
    while (1);
  }
  
  tft.begin();
  tft.setRotation(3);
  Serial.println(F("[?] GROVE SCD30 CO2 sensor initialize.."));
  Wire.begin();
  scd30.initialize();
  delay(500);
  sensor_co2();  
}

void loop() 
{
  if (digitalRead(WIO_KEY_A) == LOW) 
  {
    Serial.println("[x} A Key pressed");   
    delay(200);
    // display room screen
    tft_display_room_screen("Bed-Room", TFT_BLUE);
    // display temperature sensor
    tft_display_sensor_temperature(grove_scd30_temp+scd30_temp_offset);
    // display humidity sensor
    tft_display_sensor_humidity(grove_scd30_humi+scd30_humi_offset);  
    // display co2 sensor
    tft_display_sensor_co2(grove_scd30_co2);    
    
  }
  else if (digitalRead(WIO_KEY_B) == LOW) 
  {
    Serial.println("[x] B Key pressed");     
    delay(200);
    // read the co2 sensor */
    sensor_co2();
  }
  else if (digitalRead(WIO_KEY_C) == LOW) 
  {
    Serial.println("[x] C Key pressed");
    tft_backlight = !tft_backlight;
     // Turning off the LCD backlight
    if (tft_backlight == false) { digitalWrite(LCD_BACKLIGHT, LOW);  }
     // Turning on the LCD backlight
    if (tft_backlight == true)  { digitalWrite(LCD_BACKLIGHT, HIGH); }
    delay(200);
  }
  

  
  if (millis() - previousMillis > interval)
  {
    // correct timer
    previousMillis = millis();
    // read the co2 sensor */
    sensor_co2();
  }
  
}