Published March 6, 2019 © CC BY-NC-ND

Reaction Timer - F1 Style

Would you like to train your reaction time in milliseconds? Now you can with a timer inspired by the F1 race start lights.

BeginnerShowcase (no instructions)30 minutes8,997

Things used in this project

Hardware components

Arduino UNO

Maxim Integrated 8 Dig x 7 Seg LED Display with MAX72XX

SparkFun Pushbutton switch 12mm

Solderless Breadboard Half Size

Jumper wires (generic)

Software apps and online services

Arduino IDE

Story

1 - Introduction

Would you like to train your reaction time in milliseconds?

This project is a reaction timer using Arduino and more some components, but really simple and easy to be done.

The rules are very simple, similar to the Formula 1 racing start lights procedure:

"Once all cars have safely taken up their grid positions at the end of the formation lap five red lights will appear in sequence at one-second intervals. These red lights are then extinguished to signal the start of the race".

Note: After the last red light is lit, a random time (0 to 3 seconds) define when all red lights will be off. The total time from the first red light until all of lights are off varies between 4 to 7 seconds.

A 8 dig x 7 seg LED display is used to show the "lights on", your reaction time in milliseconds and also your best mark (minimum time achieved).

There are only 02 buttons:

Start (button #1 on the left)
Reaction Time (button #2 on the right)

If the time of 9.999 seconds has elapsed after all the lights are off, a warning signal "- - - -" will be displayed when you press the button #2.

If you jump start, the timer is blocked and a warning "JP" is shown on display.

The right way is to wait for all the lights off !!

Try to get better every time !!

Video: Reaction Timer with Arduino

1 / 8 • Reaction Timer View

F1 Racing Start Lights

2 - Material List

Arduino Uno R3
LED Display with MAX7219 (8 Digits x 7 Segments)
Tactile Button Switch
Breadboard
Jumper Wires

1 / 5 • Arduino UNO R3

3 - Reaction Time Insights

It is known that "the average reaction time for humans is 0.25 seconds to a visual stimulus, 0.17 for an audio stimulus, and 0.15 seconds for a touch stimulus".

I am not a neuro-scientist and this is not a scientific lab device, but with this project I have done some tests changing the code and I noticed some interesting points about how our brains work:

If you keep a constant time in sequence at one-second intervals until extinguished all of lights, your brain learn about this time interval and then your reaction goes better time after time. There is a kind of syncronization between the beat of lights and your finger movement! In this case the response of time can be around 50ms or less!!
A random time at the end of cycle assures a more realistic measures of time reaction, avoiding the effect described previously. If the random time is less than 200ms, your performance will be worst. For better results, the last light must be on for more than 200ms.
Visual stimulus demands more brain processing and the time reaction is lower when the lights are just turned off comparing when the color of lights are changed. Maybe this was the reason to Formula 1 eliminated the green lights to start the race. Nowadays the race starts when all the red lights are off.

Code

Reaction_Timer_F1_Style_with_8_Dig_x_7_Seg_MAX7219_V1_1.ino

/*
   Project:     Rection Timer - F1 Style
   Author:      LAGSILVA
   Hardware:    Arduino UNO-R3 - 8 Dig x 7 Seg MAX7219 Display
   Revision:    1.1
   Date:        06.Mar.2019
   License:     CC BY-NC-ND 4.0
                (Attribution-NonCommercial-NoDerivatives 4.0 International)
*/

#include <LedControl.h>       // Library for LED control with MAX72XX
#include <Bounce2.h>          // Library for Bounce of switches

/*
  Pins of Arduino Nano for LedControl:
  Pin #7 is connected to DataIn (DIN)
  Pin #8 is connected to CLK (CLK)
  Pin #9 is connected to LOAD (CS)
*/

// LedControl(int dataPin, int clkPin, int csPin, int numDevices)
LedControl lc = LedControl(7, 8, 9, 1);

long ti, diffTime;
int milhar, centena, dezena, unidade;
int recorde = 10000;

byte pinStartStop = 4;        // Start-Stop Pin
byte pinLapse = 3;            // Time Lapse Pin

bool statusSW1 = false;
bool statusSW2 = false;

Bounce SW1 = Bounce();        // Define Bounce to read StartStop switch
Bounce SW2 = Bounce();        // Define Bounce to read Lapse switch



void setup() {

  pinMode (pinStartStop, INPUT_PULLUP);
  pinMode (pinLapse, INPUT_PULLUP);

  randomSeed(analogRead(0));

  // After setting up the button, setup the Bounce instance
  SW1.attach(pinStartStop);   // Sets the pin (Internal Pull-Up)and matches the internal state to that of the pin
  SW1.interval(4);            // Sets the debounce time in milliseconds for SW1
  SW2.attach(pinLapse);       // Sets the pin (Internal Pull-Up)and matches the internal state to that of the pin
  SW2.interval(4);            // Sets the debounce time in milliseconds for SW2

  lc.shutdown(0, false);      // The MAX72XX is in power-saving mode on startup, we have to do a wakeup call
  lc.setIntensity(0, 2);      // Set the brightness of display between 0 and 15
  lc.clearDisplay(0);         // Clear the display

  lc.setRow(0, 7, 1);         // Waiting indicator: "-"
  lc.setRow(0, 6, 1);         // Waiting indicator: "-"
  lc.setRow(0, 5, 1);         // Waiting indicator: "-"
  lc.setRow(0, 4, 1);         // Waiting indicator: "-"
  lc.setRow(0, 3, 1);         // Waiting indicator: "-"
  lc.setRow(0, 2, 1);         // Waiting indicator: "-"
  lc.setRow(0, 1, 1);         // Waiting indicator: "-"
  lc.setRow(0, 0, 1);         // Waiting indicator: "-"

}


void loop() {

  SW1.update();   // Start-Stop

  if (SW1.fell()) {
    statusSW1 = !statusSW1;
    ti = random(200, 3000);               // Random time after lights off (200 to 3000 milliseconds)
    lc.clearDisplay(0);
  }

  if (statusSW1 == true) {

    statusSW1 = false;
    statusSW2 = true;

    for (byte k = 7; k >= 3; k--) {
      for (byte k1 = 1; k1 <= 20; k1++) {
        SW2.update();
        if (SW2.fell()) {
          lc.setRow(0, 1, 60);            // Jump Start Warning: "J"
          lc.setRow(0, 0, 103);           // Jump Start Warning: "P"
          statusSW2 = false;
          return (0);
        }
        delay(1000 / 20);                 // Time control between lights on
      }
      lc.setRow(0, k, 29);
    }

    for (byte k1 = 1; k1 <= 40; k1++) {
      SW2.update();
      if (SW2.fell()) {
        lc.setRow(0, 1, 60);              // Jump Start Warning: "J"
        lc.setRow(0, 0, 103);             // Jump Start Warning: "P"
        statusSW2 = false;
        return (0);
      }
      delay(ti / 40);                     // Time control before lights off
    }

    lc.clearDisplay(0);

    ti = millis();                        // Start time after display off

  }


  SW2.update();   // Lap Time

  if (SW2.fell() && statusSW2 == true) {

    diffTime = millis() - ti;             // Reaction time after display off

    statusSW2 = false;

    if (diffTime >= 20 && diffTime <= 9999) {   // Overflow verification

      milhar = diffTime / 1000;
      centena = (diffTime / 100) % 10;
      dezena = (diffTime / 10) % 10;
      unidade = diffTime % 10;

      lc.setDigit(0, 3, milhar, true);
      lc.setDigit(0, 2, centena, false);
      lc.setDigit(0, 1, dezena, false);
      lc.setDigit(0, 0, unidade, false);

      if (diffTime < recorde) {           // Best mark (minimum reaction time)
        recorde = diffTime;
      }

      milhar = recorde / 1000;
      centena = (recorde / 100) % 10;
      dezena = (recorde / 10) % 10;
      unidade = recorde % 10;

      lc.setDigit(0, 7, milhar, true);    // Print the best mark
      lc.setDigit(0, 6, centena, false);
      lc.setDigit(0, 5, dezena, false);
      lc.setDigit(0, 4, unidade, false);

    }
    else {
      lc.clearDisplay(0);
      lc.setRow(0, 3, 1);   // Overflow warning: " - "
      lc.setRow(0, 2, 1);   // Overflow warning: " - "
      lc.setRow(0, 1, 1);   // Overflow warning: " - "
      lc.setRow(0, 0, 1);   // Overflow warning: " - "
    }

  }

}