Components

Published September 12, 2021

Adjustable delay relay timer switch circuit home automation

Build an adjustable delay timer with relay switch using Arduino nano

IntermediateFull instructions provided5,361

Adjustable delay relay timer switch circuit home automation

Things used in this project

Hardware components

Arduino Nano R3

Omron G5V-2 Relay

2N2222 Transistor

Story

Home automation systems monitor and/or control home appliances such as lighting, climate, entertainment systems, and other devices. This also includes home security such as access control and alarm systems. For switching and controlling these systems one often requires a relay based mechanism that enables the switching of large amounts of current.

This project features an Arduino Nano controlled timer which will count down from a preset time. When the timer reaches zero, the Nano activates a relay switch. The relay can be connected to two external devices for control. Buttons are provided to adjust the timeout period as well as an on/off button to start and stop the timer.

Components

A TM1637 7 segment LED timer module provides the timer display in minutes and seconds. (Hours and minutes are available via a separate sketch) These modules are available for very little money from Ebay and Ali Express.

The relay is a double pole, double throw (DPDT) Omron G5V-2 relay which cost around $1.00 each; also from Ebay and Ali Express.

There are three tactile buttons: a button to adjust the minutes, one to adjust the seconds and a third to start, or stop the timer. Stopping the timer also switches off the relay if it has been activated.

Finally, an Arduino Nano performs the actual timer and relay switching logic. A single 2N2222 transistor is used by the Nano to do the actual switching of the relay because it is doubtful that a pin on the Arduino can supply enough current to energize a relay coil.

Timed Relay Circuit Diagram

HowTheCircuitWorks

The brains of the circuit is provided by the Arduino Nano which handles the timer countdown and relay activation functions. An explanation of how the code works that runs on the Nano follows in the next section. The buttons are used to set the timeout period and start and stop the timer respectively; these are connected to the Nano's digital pins. When the timer reaches zero, the Nano sends a logic HIGH signal through digital pin 6. This pin is connected to the gate of a 2N2222 transistor, which switches on in response to the HIGH signal from the Nano. This in turn energizes the coil of the relay which switches on Output B and switches off Output A.

Why two output control lines? Output A (pin 6 of the relay) turns off when the timer expires and Output B (pin 8 of the relay) turns on when the timer expires. Having one output turn on and the other turn off when the timer expires can be useful under some circumstances, but if you only need to turn on, or turn off a device then simply leave one of the outputs unconnected. For demonstration purposes I have the outputs connected to LEDs.

Pin 4 of the relay is the positive supply voltage for the devices connected to the output pins A and B. I have this tied to 5 Volts in the circuit above so I can drive a couple of LEDs, but if your devices need a higher voltage than this, then supply that voltage on pin 4.

You may have noticed the diode connected across the contacts to the relay's coil. This is necessary to prevent a voltage spike potentially damaging the transistor which can happen when the relay is turned on and then off. When you switch off the current to an electromagnet, the electric field surrounding the coil collapses. As it does so it sends a reverse voltage spike down the coils power connections. The diode absorbs the energy stored in the relay's coil when you switch the current off. Without the diode, the energy will cause a large and probably destructive voltage spike which would likely destroy the transistor.

Timer Relay Switch Sketch

/**
 * Relay Timer Switch - A timer based relay switch which will control up to two devices
 * 
 * Note: This sketch requires the TM1637 7 segment led display library.
 * 
 * Author: Mario Gianota (mariogianota@protonmail.com) September 2021
 */
#include <TM1637Display.h>

#define CLK 7
#define DIO 8
#define _UNPRESSED 0
#define _PRESSED 1
#define _RELEASED 3
#define SECONDS_ADJUST 0
#define MINUTES_ADJUST 1
#define TIMER_ENABLE 2

int keyboard[3] = {0,0,0}; // Index 0 = seconds adjust, 1 = minutes adjust, 2 = timer on/off
bool timerEnabled;

int seconds;
int minutes;
long startTime;

TM1637Display display(CLK, DIO);

void setup() {
  // Input buttons
  pinMode(2, INPUT);  // Minutes adjust
  pinMode(3, INPUT);  // Seconds adjust
  pinMode(4, INPUT);  // Timer on/off
  // Timer indicator LED
  pinMode(5, OUTPUT);
  // Transistor base
  pinMode(6, OUTPUT);
  timerEnabled = false;
  //Serial.begin(9600);
  pinMode(CLK, OUTPUT);
  pinMode(DIO, OUTPUT);
  display.setBrightness(0x0f);
}

void loop() {
  read_keyboard();
  
  if( keyboard[TIMER_ENABLE] == _RELEASED ) {
    timerEnabled = ! timerEnabled;
    if( timerEnabled )
      startTime = millis();
  }

  if( timerEnabled ) {
    digitalWrite(5, HIGH);
  } else {
    digitalWrite(5, LOW);
  }

  if( seconds == 0 && timerEnabled ) {
    digitalWrite(6, HIGH);
  } else {
    digitalWrite(6, LOW);
  }

  minutes = seconds / 60;
  display.showNumberDec(seconds - minutes * 60, true, 2, 2);
  display.showNumberDec(minutes, true, 2, 0);

  if( ! timerEnabled ) {
    if( keyboard[SECONDS_ADJUST] == _RELEASED ) {
      seconds++;
    }
    if( keyboard[MINUTES_ADJUST] == _RELEASED ) {
      seconds += 60;
    }
    return;
  }

  calc_time();
}

void read_keyboard() {
  int state;
  for(int i=2; i<=4; i++) {
    state = digitalRead(i);
    if( state == LOW ) {
      keyboard[i-2] = _PRESSED;
    } else if( state == HIGH && keyboard[i-2] == _PRESSED ) {
      keyboard[i-2] = _RELEASED;
    } else {
      keyboard[i-2] = _UNPRESSED;
    }
  }
  delay(10);
}

void calc_time() {
  if( millis() - startTime >= 1000 ) {
    seconds--;
    if( seconds < 0 ) {
      seconds = 0;
    }
    startTime = millis();
  }
}

Adjustable delay relay timer switch circuit home automation

Things used in this project

Hardware components

Story

Components

Code

Timer Relay Switch Sketch

Credits

mariogianota

Comments

Embed the widget on your own site

Adjustable delay relay timer switch circuit home automation

Adjustable delay relay timer switch circuit home automation

Things used in this project

Hardware components

Story

Components

Code

Timer Relay Switch Sketch

Credits

mariogianota

Comments

Related channels and tags