Published April 19, 2022 © GPL3+

Arduino Opla environment and intrusion

Arduino Opla, PIR sensor and sound sensor with two way communication through Blynk to smart phone

IntermediateFull instructions provided363

Things used in this project

Hardware components

Arduino Oplà IoT Kit

PIR Sensor, 7 m

Keyes Microphone Sound Detection Sensor Module for Arduino

Software apps and online services

Blynk

Story

In this project the Arduino Opla with a PIR sensor and sound sensor are used to send environmental and intrusion data to a smart phone or tablet through Blynk. Commands from the smart phone control LEDs and relays on the Opla to activate remote devices.

I was looking for a compact Internet of Things (IoT) device with self-contained temperature, humidity and air pressure sensors that could be remotely located in a hangar with my airplane and send this information to my smart phone. I wanted to be able to detect intrusions into my locked hangar since several people at the airport have a key. I also wanted to be able to remotely turn on/off two different external devices such as an electric engine preheater and light from my smart phone.

I have a Verizon Jet Pack 8800 in my hangar that provides a wifi Internet connection for the Opla since there is no other wifi signal available. The Opla's MKR IoT Carrier has a lot of sensors including temperature, humidity and air pressure. I used the PIR sensor that came with the Opla IoT Kit and an Elegoo microphone sensor to detect intrusions. The Opla has an internal color graphics display which I used to display temperature, humidity, air pressure and run time hours locally when I'm in the hangar. For amusement and experience with the Opla's capabilities I programmed the Opla's buzzer to play the theme from Close Encounters of the Third Kind on startup. Although I started with the Arduino_MKRIoTCarrier All_Features sketch example, I modified it significantly for my needs.

The Opla kit included a Seeed Studios PIR sensor and Grove cable which I used on port A5 of the Opla to sense intrusions. I wanted a sound sensor and I already had a Keyes Microphone Sound Detection Sensor Module for Arduino from an Elegoo sensor kit that runs on 3.5 - 10 volts. The Opla uses 3.3 volts so I needed a microphone sensor that would operate on the lower voltage.

I used code snippets from the Blynk library examples to construct my sketch. I included all of the sensitive wifi and Blynk login information in a separate config.h include file. The Blynk Template ID would not work in the config.h file and had to be included in the sketch, but it wasn't sensitive since it's the standard Quick Start template.

The included libraries were based on the example Blynk sketches used with MKR IoT Carrier and MKR WiFi 1010.

One change that I wanted to make from the example sketch was to find a better way to store and play a tune on the Opla's buzzer. I used a C++ structure to define a note's attributes and included an array of the structure for all the notes in the tune. This was much easier to deal with than the separate include file and duration array used in the example. I looked up the note frequencies on the Internet. It took some experimentation to get the note durations right.

I added three Blynk timer events to the sketch. The Blynk timer.run() method can handle up to 8 timer events of different durations as defined by the timer.setInterval() statements in the setup section of the sketch. Blynk guidelines stress using the timer events rather than delay() statements, which might block the Blynk heartbeat and drop the connection.

The first timer event sends temperature, humidity, pressure and run time data to virtual Blynk pins which display the data in widgets on the Blynk Cloud web template and smart phone Blynk app. This timer event also checks the Opla's pin A5 for a HIGH output on the PIR sensor each time the event is called. If a HIGH is detected, indicating an intrusion, then the sketch writes the HIGH to a Blynk virtual pin that displays as LED widgets on the Blynk Cloud web template and smart phone's Blynk app. The on time and sensitivity of the PIR sensor can be adjusted with two potentiometers on the sensor board. Once triggered, the PIR sensor's output goes HIGH for about 4 seconds. To prevent multiple events from being sent to Blynk Cloud, I included a logic switch variable that inhibits Blynk virtual pin writes for 6 seconds. I used time stamps rather than delays to avoid blocking the Blynk heartbeat.

The second timer event checks for a HIGH from the microphone sensor connected to the Opla on pin A6 on a shorter timer interval of 500 milliseconds so as not to miss briefer events. A separate timer event was needed because the interval was different. Sound events are much shorter in duration than the output of the PIR sensor so the 1 second interval of the first timer event might not catch a sound event. The digital output of the microphone sensor is used rather than the analog output. The sensitivity of the microphone sensor is set by an on-board potentiometer so that the on-board LED and data output are only turned on by louder sounds. To prevent multiple events from being sent to Blynk, I included the same logic switch code that was used on the PIR sensor event.

The third timer event displays the temperature, humidity, air pressure and run time in decimal hours on the Opla's local graphics display every 5 seconds.

Two BLYNK_WRITE() special functions check for and send commands from the Blynk Cloud web template or the Blynk smart phone app to the Opla on virtual pins V0 and V6. One command lights the four Opla LEDs blue and opens/closes Opla relay 1. The other command lights the four Opla LEDs red and opens/closes Opla relay 2. The button widgets on the Blynk Cloud web template and Blynk smart phone app show ON/OFF when the buttons are activated. The Opla relays can control normally open or normally closed external circuits. I would use them to turn on a light on my hangar or an electric engine preheater. The contacts are rated at 24 volts so the relays would have to activate higher voltage relays or solid state devices to control 120 VAC circuits such as an engine preheater.

The main loop in the sketch is minimal as recommended in the Blynk guidelines and only contains Blynk.run() to keep the Blynk heartbeat alive and timer.run() to check and operate the three events.

The function that displays the data on the graphics display controls the position and text color of each line in the display. Pixels stay on once set so it was simpler to erase the entire display and re-write the data every 5 seconds rather than manipulating each line of the display.

The function that plays the tune on the Opla buzzer simply steps through the notes in the array. Rests between notes are entered in the array with a 0 frequency and the appropriate duration.

Code

Arduino_MKR1010-Blynk-1

Arduino_MKR1010-Blynk-1

Arduino

This sketch collects environmental sensor data and security
intrusion detection data from an Arduino Opla MKR IoT device and
sends them to a smart phone using Blynk Cloud service. Switch
commands from the smart phone are sent to the Opla's relays and
LEDs to actuate external functions. The Opla is composed of an
Arduino MKR WiFi 1010 board and Arduino MKR IoT Carrier. A Seeed
Studios PIR sensor hardware and sound sensor are connected to the
Opla's Grove connector ports. Blynk Cloud service is used to send
environmental data to a smart phone and actuator commands from
the smart phone to the Opla. The Opla features used are:
graphics display, environmental sensors, multicolor LEDs,
relays and buzzer.

/*************************************************************
This sketch collects environmental sensor data and security
intrusion detection data from an Arduino Opla MKR IoT device and
sends them to a smart phone using Blynk Cloud service. Switch
commands from the smart phone are sent to the Opla's relays and
LEDs to actuate external functions. The Opla is composed of an
Arduino MKR WiFi 1010 board and Arduino MKR IoT Carrier. A Seeed
Studios PIR sensor hardware and sound sensor are connected to the
Opla's Grove connector ports. Blynk Cloud service is used to send
environmental data to a smart phone and actuator commands from
the smart phone to the Opla. The Opla features used are:
graphics display, environmental sensors, multicolor LEDs,
relays and buzzer.
*************************************************************/

/* Comment this out to disable prints */
#define BLYNK_PRINT Serial

/* Template ID for Blynk.Cloud service */
#define BLYNK_TEMPLATE_ID   "TMPLV8JgWeEN"

//Number of notes in the buzzer tune
#define NOTES 11

//Included libraries
#include <SPI.h>
#include <WiFiNINA.h>
#include <Arduino_MKRIoTCarrier.h>
#include <BlynkSimpleWiFiNINA.h>
#include "config.h" //Login credentials and authorization token

// Get the Blynk authorization token from the config.h file
char auth[] = BLYNK_AUTH_TOKEN;

// Get the wifi SSID and password from the config.h file
char ssid[] = WIFI_SSID;
char pass[] = WIFI_PASS;

//Instantiate the MKR IoT carrier and Blynk timer
MKRIoTCarrier carrier;
BlynkTimer timer;

//Global variables for environment sensors and run time
float temperature,humidity,pressure,hours;

bool pirStatus = false; //Logic switch to prevent multiple PIR alarms
bool soundStatus = false; //Logic switch to prevent multiple sound alarms
uint32_t t0, t1; //Declare timestamp variables

//C++ structure for a note to the buzzer
struct Note {
  String name;
  float frequency;
  int duration;
};

//Buzzer tune array on startup from Close Encounters of the Third Kind
Note tune[NOTES] = {
  {"D4",293.66,500},
  {"E4",329.63,500},
  {"C4",261.63,500},
  {"C3",130.81,500},
  {"G3",196.00,1000},
  {"R1",0.00,500},
  {"D4",293.66,500},
  {"E4",329.63,500},
  {"C4",261.63,500},
  {"C3",130.81,500},
  {"G3",196.00,1000}  
};

//Blynk timer event that reads environmental and PIR intrusion data from Opla sensors
void myTimerEvent1()
{
  temperature = carrier.Env.readTemperature(FAHRENHEIT); //Fahrenheit temperature
  humidity = carrier.Env.readHumidity(); //% humidity
  pressure = carrier.Pressure.readPressure()*0.295301; //Pressure in inches of mercury
  hours = millis()/3600000.0; //Run time in decimal hours

  //Send the environmental data from Opla to the smart phone through Blynk virtual pins
  Blynk.virtualWrite(V1, temperature);
  Blynk.virtualWrite(V2, humidity);
  Blynk.virtualWrite(V4, pressure);
  Blynk.virtualWrite(V5, hours);

  //If PIR sensor on pin A5 is high and logic switch is low then event and status are sent to Blynk Cloud
  if (digitalRead(A5) && pirStatus == false) {
    Blynk.logEvent("pir","PIR sensor tripped");
    Blynk.virtualWrite(V3,HIGH);
    Serial.println("PIR tripped");
    pirStatus = true; //Turn on the PIR logic switch
    t0 = millis(); //Take a timestamp for how long the logic switch and virtual Blynk pin stay on
  }
  //Turn off the logic switch and Blynk virtual pin after 6 seconds
  if (millis() - t0 > 6000) {
    Blynk.virtualWrite(V3,LOW);
    pirStatus = false;
  }
}

//Blynk timer event that sends sound sensor data from Opla to the smart phone through a Blynk virtual pin 
void myTimerEvent2()
{
   //If sound sensor on pin A6 is high and logic switch is low then event and status are sent to Blynk Cloud
  if (digitalRead(A6) && soundStatus == false) {
    Blynk.logEvent("sound","Sound sensor tripped");
    Blynk.virtualWrite(V7,HIGH);
    Serial.println("Sound tripped");
    soundStatus = true; //Turn on the sound logic switch
    t1 = millis(); //Take a timestamp for how long the logic switch and virtual Blynk pin stay on
  }
  //Turn off the logic switch and Blynk virtual pin after 5 seconds
  if (millis() - t1 > 5000) {
    Blynk.virtualWrite(V7,LOW);
    soundStatus = false;
  }
}

//Blynk timer event that displays environmental data on the Opla's display
void myTimerEvent3()
{
  displayEnv();
}

//Flashes Opla LEDS blue 4 times and opens/closes Opla relay 1 on command from smart phone
BLYNK_WRITE(V0)
{
  int pinValue = param.asInt(); // assigns incoming value from Blynk virtual pin V0 to a variable
  int i;
  if (pinValue) {
    for (i=0;i<=4;i++) {
      carrier.leds.setPixelColor(i,  0 ,  0 , 50);
    }
    carrier.leds.show();
    carrier.Relay1.open();
  } else {
    for (i=0;i<=4;i++) {
      carrier.leds.setPixelColor(i, 0, 0, 0);
    } 
    carrier.leds.show();
    carrier.Relay1.close();
  }
}

//Flashes Opla LEDS red 4 times and opens/closes Opla relay 2 on command from smart phone
BLYNK_WRITE(V6)
{
  int pinValue = param.asInt(); // assigning incoming value from pin V6 to a variable
  int i;
  if (pinValue) {
    for (i=0;i<=4;i++) {
      carrier.leds.setPixelColor(i, 0, 50, 0);
    }
    carrier.leds.show();
    carrier.Relay2.open();
  } else {
    for (i=0;i<=4;i++) {
      carrier.leds.setPixelColor(i, 0, 0, 0);
    } 
    carrier.leds.show();
    carrier.Relay2.close();
  }
}

//Initial setup section
void setup()
{
  Serial.begin(9600); //For debugging
  pinMode(A5,INPUT); //Read PIR sensor input on pin A5
  pinMode(A6,INPUT); //Read sound sensor input on pin A6
  //Initialize the MKR IoT carrier
  if (!carrier.begin()) {
    Serial.println("Failed to initialize MKR IoT carrier!");
    while (1);
  }
  playTune(); //Play the buzzer tune on startup
  Blynk.begin(auth, ssid, pass); //Connect to Blynk Cloud
  timer.setInterval(1000L, myTimerEvent1); //Set the Blynk timer1 PIR sensor interval
  timer.setInterval(500L, myTimerEvent2); //Set the Blynk timer2 sound sensor interval
  timer.setInterval(5000L, myTimerEvent3); //Set the environmental display timer3 interval
}

// Main loop section
void loop()
{
  Blynk.run(); //Run the Blynk connection
  timer.run(); //Run the Blynk timer
}

//Displays the environmental sensor values on the Opla's graphics display
void displayEnv() {
  carrier.display.fillScreen(ST77XX_BLACK); //oled clear()
  carrier.display.setTextSize(2); //Set the display text size to medium
  carrier.display.setCursor(50, 30); //Move the cursor to the first line
  carrier.display.setTextColor(ST77XX_BLUE); //Set the display text color to blue
  carrier.display.print("Temperature"); //Write the label
  carrier.display.setCursor(50, 50); //Move the cursor to the next line
  carrier.display.setTextColor(ST77XX_WHITE); //Set the text color to white
  carrier.display.print(temperature); //Display the temperature sensor value
  carrier.display.setCursor(50, 70); //Move the cursor to the next line
  carrier.display.setTextColor(ST77XX_MAGENTA); //Set the text color to magenta
  carrier.display.print("Humidity"); //Write the label
  carrier.display.setCursor(50, 90); //Move the cursor to the next line
  carrier.display.setTextColor(ST77XX_WHITE); //Set the text color to white
  carrier.display.print(humidity); //Display the humidity sensor value
  carrier.display.setCursor(50, 110); //Move the cursor to the next line
  carrier.display.setTextColor(ST77XX_GREEN); //Set the text color to green
  carrier.display.print("Pressure"); //Write the label
  carrier.display.setCursor(50, 130); //Move the cursor to the next line
  carrier.display.setTextColor(ST77XX_WHITE); //Set the text color to white
  carrier.display.print(pressure); //Display the pressure sensor value
  carrier.display.setCursor(50, 150); //Move the cursor to the next line
  carrier.display.setTextColor(ST77XX_RED); //Set the text color to red
  carrier.display.print("Hours"); //Write the label
  carrier.display.setCursor(50, 170); //Move the cursor to the next line
  carrier.display.setTextColor(ST77XX_WHITE); //Set the text color to white
  carrier.display.print(hours, 3); //Display the run time hours
}

//Plays the buzzer tune
void playTune() {
  for (int x=0;x<NOTES;x++) {
    carrier.Buzzer.sound(tune[x].frequency);
    delay(tune[x].duration);
    carrier.Buzzer.noSound();
  }
}

Credits

maulepilot

0 projects • 1 follower

Arduino Opla environment and intrusion

Things used in this project

Hardware components

Software apps and online services

Story

Custom parts and enclosures

Schematic

Code

Arduino_MKR1010-Blynk-1

Credits

maulepilot

Comments

Embed the widget on your own site

Arduino Opla environment and intrusion

Arduino Opla environment and intrusion

Things used in this project

Hardware components

Software apps and online services

Story

Custom parts and enclosures

Schematic

Code

Arduino_MKR1010-Blynk-1

Credits

maulepilot

Comments

Related channels and tags