Published October 11, 2016 © GPL3+

Bluetooth Light Switch

Physically engaging light switches with cloud connectivity. Featuring the Wicked Device Turner Onner and Bluz DK.

BeginnerFull instructions provided2 hours2,468

Things used in this project

Hardware components

Bluz DK

Turner Onner

Software apps and online services

IFTTT Amazon Alexa service

Story

Introduction

I saw this post, and had to have one. As someone who lives in an apartment, I'm not allowed to swap out my light switches for smart ones. I've even considered breaking that rule, but I don't have neutral wiring, so I really shouldn't. There's a nifty device called the Switchmate that I've looked into, however it is a Bluetooth device that requires your phone; it doesn't currently support any sort of hub functionality. And IoT needs some sort of hub or WiFi connection to meet the "Internet" component.

The other option is smart bulbs. I do have Hue bulbs, which are great for lamps, since you can leave the lamp on, then tell the bulb to be off. Hue bulbs on a switched load can be annoying, as you have to keep the switch On all the time. And as a light switch user all my life, I'm very accustomed to flipping that switch if I leave or enter.

So I got a Turner Onner. Their kit includes an ESP8266 NodeMCU board, and their example program creates a web server with On and Off buttons. I'm not an expert on that board, but as it is WiFi, it requires more power than BLE, so I'd have to have it plugged in all the time, or swap batteries often. So I replaced that with the Bluz DK, a BLE board that can connect to the Particle Cloud via your phone or a gateway.

Hardware

The Turner Onner is a handful of acrylic components, so that a servo can be mounted next to a switch. Rotate the servo one way to flip the switch on, the other way for off. It mounts right on top of existing switches. Super simple, super great.

The servo is controlled by a Bluz DK controller. I got the external battery board so that it can run off a CR2032 battery. The Bluz DK is connected to a Bluz Gateway via BLE. That gateway has a Bluetooth module and a Particle Photon, so that it can be a hub to connect DK's to the Particle cloud.

Software

The Turner Onner's ESP hosted a web server that had buttons for On and Off. But pulling out my phone to turn off my lights is for cavemen. I'd rather tell Alexa to do it. Because my specialty is software close to the hardware level, I've not developed a skill for Alexa. I just use IFTTT to pass Alexa commands to the Particle cloud.

In the definitions, you can choose what to name the load (LOCALE), and how it is mounted (MOUNT). The name will register cloud events for On and Off. So for my bedroom lights, two cloud events are registered, "BedroomLightsOn" and "BedroomLightsOff". The plan would be to buy a coupe more of these for my kitchen lights and bedroom ceiling fan.

The MOUNT definition is where the servo is relative to the switch. For my bedroom, I want it on the right because my door is on the left. As I walk in or leave, I don't want the servo in the way of my finger. In my kitchen however, the entry is on the right, so I will want the servo on the left. If for some reason your switches are backwards (up = off, down = on), you can also use these to reverse direction.

On startup, it will point the On and Off functions to the correct CCW or CW functions, depending on the mounting position. It will then register events in the Particle Cloud that will trigger those functions. It will then go into a low power sleep mode. The DK will check-in with the gateway -> cloud every 100ms and see if there are any new events to process. If there are, it will run the appropriate function and go back to sleep.

The IFTTT setup is pretty straightforward. Setup the Alexa trigger with the action you'd like to take (bedroom lights on), and point it to a Particle Event per the LOCALE definition in code (BedroomLightsOn).

Code

turneronner.ino

/*
 * turneronner.ino
 * Nick Stanley
 *
 * Uses the Turner Onner from wickeddevice to control light switches via Paricle Cloud
 * Designed for Bluz DK - bluetooth module linked to a Particle Gateway
 *
 * Define the room/load name in LOCALE
 * Define the side the Turner Onner is mounted on in MOUNT
 *
 */
#include "application.h"

//Mounting options
#define LEFT 0
#define RIGHT 1

//Servo PWM pin
#define SERVO_PIN D0
//LED on D7
#define LED_PIN D7

//Room or load name, appends "on" and "off" to cloud function
//ex "Bedroom", "BedroomFan", "Kitchen"
#define LOCALE "BedroomLights"  

//What side the turner onner is mounted on
//ex LEFT or RIGHT       
#define MOUNT RIGHT              

//Servo and position objects
Servo LightSwitchServo;
int pos = 90;

//Pointer functions called by cloud.
//Pointed functions differ based on MOUNT definition
void (*TurnOn)(const char*, const char*);
void (*TurnOff)(const char*, const char*);

/* 
 * FlipUp_CCW
 *
 * Turn the servo counter clockwise, 
 * such that it would flip a switch up
 * LEFT = On
 * RIGHT = Off
 */
void FlipUp_CCW(const char *e, const char *arg)
{
    digitalWrite(LED_PIN, HIGH);
    //Counter clockwise 80 degrees
    for(pos = 90; pos <= 170; pos += 1)
    {
        LightSwitchServo.write(pos);
        delay(15);
    }
    //back to center
    for(pos = 170; pos >= 90; pos -= 1)
    {
        LightSwitchServo.write(pos);
        delay(15);
    }
    digitalWrite(LED_PIN, LOW);
}
/* 
 * FlipDown_CW
 *
 * Turn the servo clockwise, 
 * such that it would flip a switch down
 * LEFT = Off
 * RIGHT = On
 */
void FlipDown_CW(const char *e, const char *arg)
{
    digitalWrite(LED_PIN, HIGH);
    //clockwise 90 degrees
    for(pos = 90; pos >= 0; pos -= 1)
    {
        LightSwitchServo.write(pos);
        delay(15);
    }
    //back to center
    for(pos = 0; pos <= 90; pos += 1)
    {
        LightSwitchServo.write(pos);
        delay(15);
    }
    digitalWrite(LED_PIN, LOW);
}

/*
 * setup
 *
 * Point the on/off functions per the defined 
 * mounting position, initialize the servo, and
 * subscribe to cloud events
 */
void setup() 
{
    //Name for cloud function
    String loc = LOCALE;
    //Direction pointing
    if(MOUNT == LEFT)
    {
        TurnOff = &FlipUp_CCW;
        TurnOn = &FlipDown_CW;
    }
    else
    {
        TurnOn = &FlipUp_CCW;
        TurnOff = &FlipDown_CW;
    }
    //Servo init
    LightSwitchServo.attach(SERVO_PIN);
    LightSwitchServo.write(pos);
    delay(15);
    //LED init
    pinMode(LED_PIN, OUTPUT);
    //Cloud subscriptions
    Particle.subscribe(loc + "On", TurnOn, MY_DEVICES);
    Particle.subscribe(loc + "Off", TurnOff, MY_DEVICES);
}
/*
 * loop
 * 
 * Sleep_Mode_CPU - check in every 100ms and
 * process any cloud events, otherwise run in
 * low power mode
 */
void loop() 
{
   System.sleep(SLEEP_MODE_CPU);
}

Credits

Nick Stanley

5 projects • 13 followers

Software Engineer - System Integrator - Maker of Things

Bluetooth Light Switch

Things used in this project

Hardware components

Software apps and online services

Story

Introduction

Hardware

Software

Schematics

Overview

Code

turneronner.ino

Credits

Nick Stanley

Comments

Embed the widget on your own site

Bluetooth Light Switch

Bluetooth Light Switch

Things used in this project

Hardware components

Software apps and online services

Story

Introduction

Hardware

Software

Schematics

Overview

Code

turneronner.ino

Credits

Nick Stanley

Comments

Related channels and tags