Simplest IoT Temperature and Humidity Meter

// IoT Thermometer with ESP-01
// If you do not know how to configure Adafruit OI go to the link below.
// Tutorial Link: https://learn.adafruit.com/adafruit-io-basics-analog-input
//
// Adafruit invests time and resources providing this open source code.
// Please support Adafruit and open source hardware by purchasing
// products from Adafruit!
//
// Written by Todd Treece for Adafruit Industries
// Copyright (c) 2016 Adafruit Industries
// Licensed under the MIT license.
//
// All text above must be included in any redistribution.

/************************** Configuration ***********************************/

// edit the config.h tab and enter your Adafruit IO credentials
// and any additional configuration needed for WiFi, cellular,
// or ethernet clients.
#include "config.h"
#include <DHT.h>    // DHT library

/************************ Example Starts Here *******************************/

// Set input pin for receive the data from the sensor. I used GPIO1
#define DHTPIN 1
// Select DHT type sensor
#define DHTTYPE DHT11

// variables
int current_temp = 0;
int last_temp = -1;

int current_hum = 0;
int last_hum = -1;

// set pin and type of sensor
DHT dht(DHTPIN, DHTTYPE);

// set up the feeds
AdafruitIO_Feed *temp_feed = io.feed("temp_feed");
AdafruitIO_Feed *hum_feed = io.feed("hum_feed");
AdafruitIO_Feed *st_feed = io.feed("st_feed");

void setup() {

  // start the serial connection
  Serial.begin(115200);

  // Start the dht function.
  dht.begin();


  // wait for serial monitor to open
  while(! Serial);

  // connect to io.adafruit.com
  Serial.print("Connecting to Adafruit IO");
  io.connect();

  // wait for a connection
  while(io.status() < AIO_CONNECTED) {
    Serial.print(".");
    delay(500);
  }

  // we are connected
  Serial.println();
  Serial.println(io.statusText());
  
}

void loop() {

  // io.run(); is required for all sketches.
  // it should always be present at the top of your loop
  // function. it keeps the client connected to
  // io.adafruit.com, and processes any incoming data.
  io.run();

  // Get humidity data from the sensor
  float hum = dht.readHumidity();
  // Get temperature data from the sensor
  float temp = dht.readTemperature();

  float st = dht.computeHeatIndex(temp, hum, false);

  // Print values in the serial monitor console
  Serial.print("Humedad: ");
  Serial.print(hum);
  Serial.println(" %\t");
  Serial.print("Temperatura: ");
  Serial.print(temp);
  Serial.println(" *C ");
  Serial.print("Índice de calor: ");
  Serial.print(st);
  Serial.println(" *C ");

  
  delay(10000);
 

  // Check if there was an error taking the data.
  if (isnan(hum) || isnan(temp)){
    Serial.println("Error en obtener los datos ");
    return;
  }
  
  current_temp = temp;
  current_hum = hum;
  
  // return if the value hasn't changed
  if((current_temp == last_temp) && (current_hum == last_hum))
    return;

  // save the current state to the feeds
  Serial.println("sending -> ");
  Serial.println(current_temp);
  temp_feed->save(current_temp);
  Serial.println(current_hum);
  hum_feed->save(current_hum);
  Serial.println(st);
  st_feed->save(st);

  // store last values
  last_temp = current_temp;
  last_hum = current_hum;

  // wait three seconds (1000 milliseconds == 1 second)
  //
  // because there are no active subscriptions, we can use delay()
  // instead of tracking millis()
  // wait 60 seconds to send the data to the Adafruit IO.
  delay(60000);

}