Automated Bottle Sorting Robot Using Arduino

#include <Servo.h>

// Define ultrasonic sensor pins for lid, metal, and plastic bins
#define LID_TRIG_PIN 9
#define LID_ECHO_PIN 8
#define METAL_TRIG_PIN 10
#define METAL_ECHO_PIN 11
#define PLASTIC_TRIG_PIN 13
#define PLASTIC_ECHO_PIN 12

// Define LED pins for indicating metal and plastic detection
#define METAL_LED A0
#define PLASTIC_LED A1

// Define servo motor pins for lid, metal bin, and plastic bin doors
#define SERVO_PIN 7
#define INDUCTIVE_SENSOR_PIN 5
#define METAL_SERVO_PIN 6 
#define PLASTIC_SERVO_PIN 4 

// Define distance thresholds for operations
#define THRESHOLD_DISTANCE 10  
#define LED_THRESHOLD_DISTANCE 20 

// Initialize servo objects
Servo myServo;
Servo metalServo;
Servo plasticServo;

void setup() {
  // Initialize serial communication
  Serial.begin(9600);
  
  // Configure pin modes for ultrasonic sensors
  pinMode(LID_TRIG_PIN, OUTPUT);
  pinMode(LID_ECHO_PIN, INPUT);
  pinMode(METAL_TRIG_PIN, OUTPUT);
  pinMode(METAL_ECHO_PIN, INPUT);
  pinMode(PLASTIC_TRIG_PIN, OUTPUT);
  pinMode(PLASTIC_ECHO_PIN, INPUT);
  
  // Configure pin modes for inductive sensor and LEDs
  pinMode(INDUCTIVE_SENSOR_PIN, INPUT);
  pinMode(METAL_LED, OUTPUT);
  pinMode(PLASTIC_LED, OUTPUT);
  
  // Attach servo motors to respective pins and set initial positions
  myServo.attach(SERVO_PIN); 
  metalServo.attach(METAL_SERVO_PIN); 
  plasticServo.attach(PLASTIC_SERVO_PIN);
  myServo.write(85); 
  metalServo.write(0); 
  plasticServo.write(0); 
}

// Function to read distance from ultrasonic sensor
long readUltrasonicDistance(int trigPin, int echoPin) {
  long duration, distance;
  
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);
  
  // Measure the duration of the echo pulse
  duration = pulseIn(echoPin, HIGH);
  
  // Calculate the distance based on the speed of sound
  distance = duration * 0.034 / 2;
  
  return distance;
}

void loop() {
  // Read distances from ultrasonic sensors
  long lidDistance = readUltrasonicDistance(LID_TRIG_PIN, LID_ECHO_PIN);
  long metalDistance = readUltrasonicDistance(METAL_TRIG_PIN, METAL_ECHO_PIN);
  long plasticDistance = readUltrasonicDistance(PLASTIC_TRIG_PIN, PLASTIC_ECHO_PIN);

  // Print distances to serial monitor
  Serial.print("Lid Distance: ");
  Serial.print(lidDistance);
  Serial.println(" cm");
  Serial.print("Metal Distance: ");
  Serial.print(metalDistance);
  Serial.println(" cm");
  Serial.print("Plastic Distance: ");
  Serial.print(plasticDistance);
  Serial.println(" cm");

  // Check if lid distance is within threshold for operation
  if (lidDistance <= THRESHOLD_DISTANCE) {
    openLid(); // Open the lid
    delay(3000);
    closeLid(); // Close the lid after 3 seconds

    bool metalDetected = false;
    unsigned long startTime = millis();
    // Perform metal detection process for up to 10 seconds
    while (millis() - startTime < 10000) {
      // Check if metal is detected by inductive sensor
      if (digitalRead(INDUCTIVE_SENSOR_PIN) == HIGH) {
        // If metal is detected and within LED threshold distance, indicate and sort metal
        if (metalDistance <= LED_THRESHOLD_DISTANCE) {
          indicateMetal();
          metalDetected = true;
          break;
        } else {
          sortMetal();
          metalDetected = true;
          break;
        }
      }
      delay(100);
    }

    // If no metal detected, check and sort plastic if within LED threshold distance
    if (!metalDetected) {
      if (plasticDistance <= LED_THRESHOLD_DISTANCE) {
        indicatePlastic();
      } else {
        sortPlastic();
      }
    }
  }

  // Update LEDs based on current distances
  updateLEDs(metalDistance, plasticDistance);

  // Delay before next loop iteration
  delay(1000);
}

// Function to open the lid
void openLid() {
  myServo.write(10);
}

// Function to close the lid
void closeLid() {
  myServo.write(85);
}

// Function to indicate detection of metal
void indicateMetal() {
  digitalWrite(METAL_LED, HIGH);
  delay(500);
  digitalWrite(METAL_LED, LOW);
  openLid();
  delay(3000);
  closeLid();
}

// Function to sort metal into the metal bin
void sortMetal() {
  metalServo.write(35);
  delay(1000);
  metalServo.write(0);
}

// Function to indicate detection of plastic
void indicatePlastic() {
  digitalWrite(PLASTIC_LED, HIGH);
  delay(500);
  digitalWrite(PLASTIC_LED, LOW);
  openLid();
  delay(3000);
  closeLid();
}

// Function to sort plastic into the plastic bin
void sortPlastic() {
  plasticServo.write(50);
  delay(1000);
  plasticServo.write(0);
}

// Function to update LEDs based on current distances
void updateLEDs(long metalDistance, long plasticDistance) {
  // Turn on metal LED if metal is detected within LED threshold distance
  if (metalDistance <= LED_THRESHOLD_DISTANCE && digitalRead(INDUCTIVE_SENSOR_PIN) == HIGH) {
    digitalWrite(METAL_LED, HIGH);
  } else {
    digitalWrite(METAL_LED, LOW);
  }

  // Turn on plastic LED if plastic is detected within LED threshold distance
  if (plasticDistance <= LED_THRESHOLD_DISTANCE) {
    digitalWrite(PLASTIC_LED, HIGH);
  } else {
    digitalWrite(PLASTIC_LED, LOW);
  }
}