Published November 29, 2023

IoT Robot Car using MQTT

Build an Arduino powered robot or car that can be remotely controlled over the web using the EMQX MQTT broker.

BeginnerFull instructions provided1 hour1,865

Things used in this project

Hardware components

Arduino UNO R4 WiFi

Arduino MotorShield Rev3

DC Motor, 12 V

Battery Holder, 18650 x 2

4WD Smart Robot Car Chassis Kit

Software apps and online services

EMQX

Arduino IDE

Story

In this guide I'll show you how to quickly put together a remote controlled robot using off-the-shelf parts and open-source software! While this guide covers the basics of driving a robot, the MQTT messaging framework used can be modified to include other components and sensors for two way communication!

If you’re unfamiliar, MQTT stands for Message Queuing Telemetry Transport. It’s a robust messaging protocol with a publish and subscriber model - using topics to define where messages are coming from or going to.

EMQX is the most feature rich, secure, and reliable MQTT broker available as both an open-source project and as a managed cloud service. This guide will be using EMQX.

Install EMQX

You have a number of options for deploying EMQX. You can install it locally or use our cloud platform to deploy a dedicated deployment.

At this time we don't have a working example for the Arduino Uno R4 WiFi that can connect using a certificate file. So you'll need to either use the dedicated cloud trial or the free EMQX Community edition.

For a local deployment using the EMQX Community edition, follow this Hackster guide.

https://www.hackster.io/virgilvox/mqtt-basics-with-the-emqx-community-edition-58f18f

Assemble the Robot Car

For this guide I used this robot car kit. Really you can use any robot kit or chassis that is driven by 3-12v motors.

Follow the instructions for putting together your robot.
Mount a battery pack and insert charged batteries. (The kit I used came with the battery holder but the 18650 batteries were purchased separately).
Mount the Arduino Uno R4 WiFi.
Plug the Arduino Motor Shield into the Arduino Uno R4.

Wiring

You only need to wire a couple of things together. You can use a barrel jack connected to the positive and negative leads of the battery holder and plug that directly into the Arduino Uno R4 or you can wire it to the terminals on the motor shield.

You then need to wire the motors to the A+/A- and B+/B- terminals on the motor shield. One motor or set of motors per side assigned to each letter. Ensure that the placement of positive and negative leads of the motors drive in the same direction based on polarity. Test this by connecting their leads directly to the power source. That way in the code forward means forward for both motors. Otherwise you'll have to adjust polarity for the motors in the code.

Setting up the Arduino IDE and Libraries

Install the latest Arduino IDE.
Install the ArduinoMqttClient and the ArduinoJson library. You can do so easily from the Library Manger.

Program the Arduino Sketch

The Arduino sketch creates a basic program that connects to your WiFi network, connects to the broker as the user created on your EMQX broker, subscribes to messages on a topic car/action and when a JSON message is received with a direction command it will set the motors to correspond and drive the robot.

Create a blank sketch in the Arduino IDE and copythe sketch included at the bottom of this guide.
At the top of the sketch configure your WiFi credentials, the user credentials from your EMQX broker, and the IP addressor Hostname.
Plug the Arduino to your computer.
In Tools > Board select the type of Arduino development board that you are using.
In Tools > Port select the corresponding port for your Arduino.
Click the Upload arrow.
Once uploaded open the Serial Monitor from the Tools menu in order to monitor the device logs and view messages received.

Drive the robot car using MQTT

You can test this using MQTTX, a free test client provided by EMQX.

Plug the battery into the Arduino Uno R4
Wait a few moments for the Arduino to connect to the broker. (You can see active connection in the EMQX dashboard)
Connect to the broker using MQTTX or some other MQTT client.
Publish to the topic car/action with the following JSON structure using one of the commands forward, backward, left, right, or stop.

{
    "action": "forward"
}

What next?!

There are MQTT client libraries for every language and platform. You can easily build your own driving application or have the robot controlled by Twitch or some other service. You can follow our guide for using Node-Red with EMQX to quickly program an interface for controlling the robot without code! The applications you can create are endless. Be sure to share what you build with us!

Join Our Community!

We have an amazing community of open-source contributors and users of the EMQX project and cloud service. Join in on the discussions, share your projects, or feel free to ask any questions! We'd love to hear from you!

mqtt-car.ino

#include "WiFiS3.h"
#include <ArduinoMqttClient.h>
#include <ArduinoJson.h>

char ssid[] = "";    // your network SSID (name)
char pass[] = "";    // your network password 

char mqtt_user[] = "test";
char mqtt_pass[] = "test";

WiFiClient wifiClient;
MqttClient mqttClient(wifiClient);

const char broker[] = "emqxpi.local";
int        port     = 1883;
const char subscribe_topic[]  = "car/action";

int rightDir = 12;
int rightPWM = 3;
int rightBrake = 9;

int leftDir = 13;
int leftPWM = 11;
int leftBrake = 8;

void setup() {

  pinMode(rightDir, OUTPUT);
  pinMode(rightPWM, OUTPUT);
  pinMode(rightBrake, OUTPUT);
  pinMode(leftDir, OUTPUT);
  pinMode(leftPWM, OUTPUT);
  pinMode(leftBrake, OUTPUT);

  Serial.begin(9600);
  while (!Serial) {
    ; 
  }

  // Connect to WiFi
  Serial.print("Attempting to connect to WPA SSID: ");
  Serial.println(ssid);
  WiFi.begin(ssid, pass);
  while (WiFi.status() != WL_CONNECTED) {
    // failed, retry
    Serial.print(".");
    delay(5000);
  }

  Serial.println("You're connected to the network");
  Serial.println();

  // You can provide a username and password for authentication
  mqttClient.setUsernamePassword(mqtt_user, mqtt_pass);

  Serial.print("Attempting to connect to the MQTT broker.");

  if (!mqttClient.connect(broker, port)) {
    Serial.print("MQTT connection failed! Error code = ");
    Serial.println(mqttClient.connectError());

    while (1);
  }

  Serial.println("You're connected to the MQTT broker!");

  mqttClient.onMessage(onMqttMessage);

  Serial.print("Subscribing to topic: ");
  Serial.println(subscribe_topic);

  // subscribe to a topic
  mqttClient.subscribe(subscribe_topic);

  Serial.print("Waiting for messages on topic: ");
  Serial.println(subscribe_topic);
}



void onMqttMessage(int messageSize) {
  Serial.print("Received a message with topic ");
  Serial.println(mqttClient.messageTopic());
  StaticJsonDocument<256> doc;
  deserializeJson(doc, mqttClient);
  const char* action = doc["action"];
  Serial.print("action: ");
  Serial.println(action);

  String direction(action);   

  if(direction == "forward"){
    Serial.println("forward drive");
    forward(200);
    delay(500);
    stop();
  }

  if(direction == "backward"){
    backward(200);
    delay(500);
    stop();
  }

  if(direction == "left"){
    left();
    delay(500);
    stop();
  }

  if(direction == "right"){
    right();
    delay(500);
    stop();
  }

  if(direction == "stop"){
    stop();
  }

}

void loop() {

  mqttClient.poll();
}


void forward(int speed) {
  digitalWrite(rightDir, HIGH);
  digitalWrite(leftDir, HIGH);

  digitalWrite(rightBrake, LOW);
  digitalWrite(leftBrake, LOW);

  analogWrite(rightPWM, speed);
  analogWrite(leftPWM, speed);
}

void backward(int speed) {
  digitalWrite(rightDir, LOW);
  digitalWrite(leftDir, LOW);

  digitalWrite(rightBrake, LOW);
  digitalWrite(leftBrake, LOW);

  analogWrite(rightPWM, speed);
  analogWrite(leftPWM, speed);
}

void stop() {
  analogWrite(rightPWM, 0);
  analogWrite(leftPWM, 0);

  digitalWrite(rightBrake, HIGH);
  digitalWrite(leftBrake, HIGH);
}

void left() {
  digitalWrite(rightDir, LOW);
  digitalWrite(leftDir, HIGH);

  digitalWrite(rightBrake, LOW);
  digitalWrite(leftBrake, LOW);

  analogWrite(rightPWM, 255);
  analogWrite(leftPWM, 255);
}

void right() {
  digitalWrite(rightDir, HIGH);
  digitalWrite(leftDir, LOW);

  digitalWrite(rightBrake, LOW);
  digitalWrite(leftBrake, LOW);

  analogWrite(rightPWM, 255);
  analogWrite(leftPWM, 255);
}

Credits

Moheeb Zara

39 projects • 136 followers

Developer Advocate at EMQ Technologies - . Co-founder - South West Maker Festival. Hardware hacker, artist, robots, HeatSync Labs

EMQ Technologies

5 projects • 6 followers

World's leading cloud-native MQTT-based IoT messaging platform and streaming database

IoT Robot Car using MQTT