Published July 24, 2023 © GPL3+

Beep--Attention!They are living in a harsh environment !

Monitoring temperature and humidity using XIAOESP32S3, humidity and temperature sensor and buzzer, alert when they exceed a certain threshold.

BeginnerFull instructions provided1 hour213

Beep--Attention!They are living in a harsh environment !

Things used in this project

Hardware components

Seeed Studio Grove - Wio-E5 (STM32WLE5JC)

XIAO ESP32S3

Temperatrue and Humidity sensor

Seeed Studio Grove - Piezo Buzzer

Seeed Studio XIAO Expansion Board

Seeed Studio Grove - Universal 4 Pin Buckled 5cm Cable (5 PCs Pack)

Software apps and online services

Arduino IDE

Story

INTRODUCTION

When storing electronic components, medications or other environmentally sensitive items, temperature and humidity requirements are often necessary. However, monitoring these parameters manually can be time-consuming and labor-intensive. In this project, we will attempt to create a device that automatically alerts through buzzer when the temperature exceeds a certain threshold.

Additionally, you can view the temperature and humidity on a local LED screen or remotely via the TTN platform. So, it is also a remote temperature and humidity monitor!

Contents of the Tutorial

Basic idea:Overview of the project idea
Connection:How to connect electronic components
Add to TTN:How to Upload data to TTN platform
Application:several examples this device can be used
Code:Complete example code

Basic idea

The project will be carried out according to the following ideas：

Firstly, data will be collected using temperature and humidity sensors, and the LED display will show the data.

Then, check if the real-time data is greater than or less than the threshold we set, and if it is, the buzzer will sound an alarm.

Meanwhile, the E5 module will send the data to the TTN platform via LoRaWAN so that we can view the data remotely.

As you can see, this project is aimed at enabling local alerts for quick actions and remote monitoring of relevant data.

Connection

Step 1 Preparation

Hardware:

E5 grove *1;XIAO ESP32S3 module *1;XIAO expansion board *1;Temperature and Humidity sensor *1;Piozer buzzer *1, Grove cable*3, USB-Type C cable*1.

Software:

Download Arduino IDE

Add ESP32 board package to your Arduino IDE

Add libraries:u8g2,DHT

Step 2 Insert the ESP32S3 module into the XIAO expansion board.

note:You need to first install antenna and solder the header pins.refer to this.

Step 3 Connect other components to the XIAO expansion board.

note:Please make sure to connect the pins to the correct ports

Step 4 Connect to PC using USB-Type C cable, upload the code.If success, you can see temperature and humidity data in Serial Monitor.Buzzer will beeps if temperature greater than 30 degree.

Step 5 I have set the threshold values in advance, but you can also modify them according to your own needs in line 200 to 205.

if( temp > 30.00 ) {//Set your threshold values
analogWrite(Buzzer, 20);
delay(1000);
analogWrite(Buzzer, 0);
delay(1000);
}

Add to TTN

Step 1 Register a TTN account, and add an application and the device on the TTN platform, refer to this.

In this part you can choose to use the AppEui, DevEui and APPKey in the code or write Eui and Key generated by TTN or pensonally into the device.Modify them in lines 140 to 148.

at_send_check_response("+ID: AppEui", 1000, "AT+ID\r\n");
at_send_check_response("+MODE: LWOTAA", 1000, "AT+MODE=LWOTAA\r\n");//select mode
at_send_check_response("+DR: EU868", 1000, "AT+DR=EU868\r\n");//select frequency band
at_send_check_response("+CH: NUM", 1000, "AT+CH=NUM,0-2\r\n");//select sub band
at_send_check_response("+ID: DevEui", 1000, "AT+ID=DevEui,\"2CF7F1C042900211\"\r\n");//write deveui
at_send_check_response("+ID: AppEui", 1000, "AT+ID=AppEui,\"0128944F83E7AF55\"\r\n");//write AppEui
at_send_check_response("+KEY: APPKEY", 1000, "AT+KEY=APPKEY,\"2B7E151628AED2A6ABF7158809CF4F3C\"\r\n");//write appkey
at_send_check_response("+CLASS: C", 1000, "AT+CLASS=A\r\n");//write device class
at_send_check_response("+PORT: 8", 1000, "AT+PORT=8\r\n");

Step 2 Decode the payload.

Locate End device>Payload fomatters>uplink, choose Custom Javascript fomatter

Copy and paste this code into fomatter code, apply.You can see data massages in TTN now.

function Decoder(bytes, port) {
var decoded = {};
if (port === 8) {
decoded.temp = bytes[0] <<8 | bytes[1];
decoded.humi = bytes[2] <<8 | bytes[3];
}
return decoded;
}

Application

Storage of electronic components
Storage of temperature and humidity sensitive drugs
Cold chain transportation
Environmental monitoring in daily life

Temperature and Humidity monitor with buzzer alert

# include <Arduino.h>
# include <U8x8lib.h>
# include "DHT.h"
#include "Wire.h"
//# define DHTPIN 0 // what pin we're connected to

// Uncomment whatever type you're using!
//# define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT20   // DHT 20
// #define DHTTYPE DHT22   // DHT 22  (AM2302)
//#define DHTTYPE DHT21   // DHT 21 (AM2301)
#define Buzzer  2 //Buzzer GPIO

//DHT dht(DHTPIN, DHTTYPE);
DHT dht(DHTTYPE);         //   DHT10 DHT20 don't need to define Pin
#if defined(ARDUINO_ARCH_AVR)
    #define debug  Serial
//
#elif defined(ARDUINO_ARCH_SAMD) ||  defined(ARDUINO_ARCH_SAM)
    #define debug  SerialUSB
#else
    #define debug  Serial
#endif
//
U8X8_SSD1306_128X64_NONAME_HW_I2C u8x8(/*reset=*/U8X8_PIN_NONE);
// U8X8_SSD1306_128X64_NONAME_SW_I2C u8x8(/*clock=*/ SCL, /*data=*/ SDA, /*reset=*/ U8X8_PIN_NONE);   // OLEDs without Reset of the Display

static char recv_buf[512];
static bool is_exist = false;
static bool is_join = false;
static int led = 0;

static int at_send_check_response(char *p_ack, int timeout_ms, char*p_cmd, ...)
{
    int ch;
    int num = 0;
    int index = 0;
    int startMillis = 0;
    va_list args;
    memset(recv_buf, 0, sizeof(recv_buf));
    va_start(args, p_cmd);
    Serial1.printf(p_cmd, args);
    Serial.printf(p_cmd, args);
    va_end(args);
    delay(200);
    startMillis = millis();

    if (p_ack == NULL)
    {
        return 0;
    }

    do
    {
        while (Serial1.available() > 0)
        {
            ch = Serial1.read();
            recv_buf[index++] = ch;
            Serial.print((char)ch);
            delay(2);
        }

        if (strstr(recv_buf, p_ack) != NULL)
        {
            return 1;
        }

    } while (millis() - startMillis < timeout_ms);
    return 0;
}

static void recv_prase(char *p_msg)
{
    if (p_msg == NULL)
    {
        return;
    }
char*p_start = NULL;
    int data = 0;
    int rssi = 0;
    int snr = 0;

    p_start = strstr(p_msg, "RX");
    if (p_start && (1 == sscanf(p_start, "RX: \"%d\"\r\n", &data)))
    {
        Serial.println(data);
        u8x8.setCursor(2, 4);
        u8x8.print("led :");
        led = !!data;
        u8x8.print(led);
        if (led)
        {
            digitalWrite(LED_BUILTIN, LOW);
        }
        else
        {
            digitalWrite(LED_BUILTIN, HIGH);
        }
    }

    p_start = strstr(p_msg, "RSSI");
    if (p_start && (1 == sscanf(p_start, "RSSI %d,", &rssi)))
    {
        u8x8.setCursor(0, 6);
        u8x8.print("                ");
        u8x8.setCursor(2, 6);
        u8x8.print("rssi:");
        u8x8.print(rssi);
    }
    p_start = strstr(p_msg, "SNR");
    if (p_start && (1 == sscanf(p_start, "SNR %d", &snr)))
    {
        u8x8.setCursor(0, 7);
        u8x8.print("                ");
        u8x8.setCursor(2, 7);
        u8x8.print("snr :");
        u8x8.print(snr);
    }
}

void setup(void)
{
    u8x8.begin();
    u8x8.setFlipMode(1);
    u8x8.setFont(u8x8_font_chroma48medium8_r);

    Serial.begin(115200);
    pinMode(LED_BUILTIN, OUTPUT);
    digitalWrite(LED_BUILTIN, HIGH);
  //
    pinMode(Buzzer, OUTPUT);
  //
    Serial1.begin(9600,SERIAL_8N1,44,43);
    Serial.print("E5 LORAWAN TEST\r\n");
    u8x8.setCursor(0, 0);

    if (at_send_check_response("+AT: OK",100, "AT\r\n"))
    {
        is_exist = true;
        at_send_check_response("+ID: AppEui", 1000, "AT+ID\r\n");
        at_send_check_response("+MODE: LWOTAA", 1000, "AT+MODE=LWOTAA\r\n");//select mode
        at_send_check_response("+DR: EU868", 1000, "AT+DR=EU868\r\n");//select frequency band
        at_send_check_response("+CH: NUM", 1000, "AT+CH=NUM,0-2\r\n");//select sub band
        at_send_check_response("+ID: DevEui", 1000, "AT+ID=DevEui,\"2CF7F1C042900211\"\r\n");//write deveui
        at_send_check_response("+ID: AppEui", 1000, "AT+ID=AppEui,\"0128944F83E7AF55\"\r\n");//write AppEui
        at_send_check_response("+KEY: APPKEY", 1000, "AT+KEY=APPKEY,\"2B7E151628AED2A6ABF7158809CF4F3C\"\r\n");//write appkey
        at_send_check_response("+CLASS: C", 1000, "AT+CLASS=A\r\n");//write device class
        at_send_check_response("+PORT: 8", 1000, "AT+PORT=8\r\n");
        delay(200);
        u8x8.setCursor(5, 0);
        u8x8.print("LoRaWAN");
        is_join = true;
    }
    else
    {
        is_exist = false;
        Serial.print("No E5 module found.\r\n");
        u8x8.setCursor(0, 1);
        u8x8.print("unfound E5 !");
    }

    dht.begin();

    u8x8.setCursor(0, 2);
    u8x8.setCursor(2, 2);
    u8x8.print("temp:");

    u8x8.setCursor(2, 3);
    u8x8.print("humi:");

    u8x8.setCursor(2, 4);
    u8x8.print("led :");
    u8x8.print(led);
}

void loop(void)
{
    float temp = 0;
    float humi = 0;

    temp = dht.readTemperature();
    humi = dht.readHumidity();

    Serial.print("Humidity: ");
    Serial.print(humi);
    Serial.print(" %\t");
    Serial.print("Temperature: ");
    Serial.print(temp);
    Serial.println(" *C");

    u8x8.setCursor(0, 2);
    u8x8.print("      ");
    u8x8.setCursor(2, 2);
    u8x8.print("temp:");
    u8x8.print(temp);
    u8x8.setCursor(2, 3);
    u8x8.print("humi:");
    u8x8.print(humi);
    //
    if( temp > 30.00 ) {
      analogWrite(Buzzer, 20);
      delay(1000);
      analogWrite(Buzzer, 0);
      delay(1000);
    }
    //
    if (is_exist)
    {
        int ret = 0;
        if (is_join)
        {

            ret = at_send_check_response("+JOIN: Network joined", 12000, "AT+JOIN\r\n");
            if (ret)
            {
                is_join = false;
            }
            else
            {
                at_send_check_response("+ID: AppEui", 1000, "AT+ID\r\n");
                Serial.print("JOIN failed!\r\n\r\n");
                delay(5000);
            }
        }
        else
        {
            char cmd[128];
            sprintf(cmd, "AT+CMSGHEX=\"%04X%04X\"\r\n", (int)temp, (int)humi);
            ret = at_send_check_response("Done", 5000, cmd);
            if (ret)
            {
                recv_prase(recv_buf);
            }
            else
            {
                Serial.print("Send failed!\r\n\r\n");
            }
            delay(5000);
        }
    }
    else
    {
        delay(1000);
    }
}

Beep--Attention!They are living in a harsh environment !

Things used in this project

Hardware components

Software apps and online services

Story

INTRODUCTION

Contents of the Tutorial

Basic idea

Connection

Add to TTN

Application

Code

Temperature and Humidity monitor with buzzer alert

U8g2

DHT

Credits

chloe zhang

Comments

Embed the widget on your own site

Beep--Attention!They are living in a harsh environment !

Beep--Attention!They are living in a harsh environment !

Things used in this project

Hardware components

Software apps and online services

Story

INTRODUCTION

Contents of the Tutorial

Basic idea

Connection

Add to TTN

Application

Code

Temperature and Humidity monitor with buzzer alert

U8g2

DHT

Credits

chloe zhang

Comments

Related channels and tags