IoT AWS & Azure Smart Meeting Room

/*
 * Publish/Subscribe MQTT PIR Sensors for Smart Meeting Rooms IoT Use Cases 
 *
 * Copyright (C) 2019 Fabio R. Caetano fabior_bra@yahoo.com.br
 *
 *
 * This file is distributed in the hope that it will be useful, but without any warranty; without even
 * the implied warranty of merchantability or fitness for a particular purpose.
 */

#include <WiFi101.h>
#include <WifiLocation.h>
#include <SPI.h>
#include "Adafruit_MQTT.h"
#include "Adafruit_MQTT_Client.h"

const char* googleApiKey = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
char ssid[] = "xxxxxx";
char pass[] = "xxxxxx";


#define host      "<MQTT Broker IP address or FQDN>"
//if DNS is used: i.e.: AWS Route53>"
#define clientid  "<prefix>-meetingroom1"
//clientid must match user-part of room mailbox address, configured via o365 admin
#define username  "sensor1"
#define password  "sensor123"
String mqttpayload1;
String mqttpayload2;
String mqttpayload3;

WiFiClient wificlient;
Adafruit_MQTT_Client mqttclient(&wificlient, host, 1883, clientid, username, password);
WifiLocation location(googleApiKey);


int ledPin = 13; // choose the pin for the LED
int inputPin = 5; // choose the input pin (for PIR sensor)
int pirState = LOW; // we start, assuming no motion detected
int val = 0; // variable for reading the pin status
int status = WL_IDLE_STATUS;

// You don't need to change anything below this line!
#define halt(s) { Serial.println(F( s )); while(1);  }

/****************************** Feeds ***************************************/

// Setup a feed called 'sensor/#' for publishing.
// Notice MQTT paths for AIO follow the form: <username>/feeds/<feedname>
Adafruit_MQTT_Publish topiclocation = Adafruit_MQTT_Publish(&mqttclient, "pir_sensor/location/" clientid);
Adafruit_MQTT_Publish topicstate = Adafruit_MQTT_Publish(&mqttclient, "pir_sensor/state/" clientid);

// Setup a feed called 'onoff' for subscribing to changes.Future use only. intended to trigger monitoring only when room is booked.
Adafruit_MQTT_Subscribe onoffmonitor = Adafruit_MQTT_Subscribe(&mqttclient, "pir_sensor/onoffmonitor");

/*************************** Sketch Code ************************************/


void setup() {
  
  WiFi.setPins(8,7,4,2);
  
// while (!Serial);
  Serial.begin(115200);

  Serial.println(F("Adafruit MQTT demo for WINC1500"));

  // Initialise the Client
  Serial.print(F("\nInit the WiFi module..."));
  // check for the presence of the breakout
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WINC1500 not present");
    // don't continue:
    while (true);
  }
  Serial.println("ATWINC OK!");
  
  pinMode(ledPin, OUTPUT); // declare LED as output
  pinMode(inputPin, INPUT); // declare sensor as input

  mqttclient.subscribe(&onoffmonitor);

  MQTT_connect(); // Call once on setup to send Room Sensor Location
  
  location_t loc = location.getGeoFromWiFi();

  Serial.println("Location request data");
  Serial.println(location.getSurroundingWiFiJson());
  Serial.println("Latitude: " + String(loc.lat, 7));
  Serial.println("Longitude: " + String(loc.lon, 7));
  Serial.println("Accuracy: " + String(loc.accuracy));

  mqttpayload1 = "{\"Location\": \"";
  mqttpayload2 = "\"}";
  mqttpayload3 = mqttpayload1 + String(loc.lat, 7) + String(",") + String(loc.lon, 7) + String(",") + String(loc.accuracy) + mqttpayload2;
  const char *publishloc = mqttpayload3.c_str();
        
  Serial.println(publishloc);

  topiclocation.publish(publishloc);  
}


void loop() {
  // Ensure the connection to the MQTT server is alive (this will make the first
  // connection and automatically reconnect when disconnected).  See the MQTT_connect
  // function definition further below.
  MQTT_connect();

  // this is our 'wait for incoming subscription packets' busy subloop
  Adafruit_MQTT_Subscribe *subscription;
  while ((subscription = mqttclient.readSubscription(5000))) {
    if (subscription == &onoffmonitor) {
      Serial.print(F("Got: "));
      Serial.println((char *)onoffmonitor.lastread);

      if (0 == strcmp((char *)onoffmonitor.lastread, "OFF")) {
        digitalWrite(ledPin, LOW);
      }
      if (0 == strcmp((char *)onoffmonitor.lastread, "ON")) {
        digitalWrite(ledPin, HIGH);
      }
    }
  }

 val = digitalRead(inputPin); // read input value
 
  if (val == HIGH) { // check if the input is HIGH
      digitalWrite(ledPin, HIGH); // turn LED ON
      if (pirState == LOW) {
        // we have just turned on
        mqttpayload1 = "{\"State\": \"Detected\"}";
        const char *publishstate = mqttpayload1.c_str();
        
        Serial.println(publishstate);
        topicstate.publish(publishstate);
        // We only want to print on the output change, not state
        pirState = HIGH;
      }
  } else {  
      digitalWrite(ledPin, LOW); // turn LED OFF
      if (pirState == HIGH){
        // we have just turned of
        mqttpayload1 = "{\"State\": \"End\"}";
        const char *publishstate = mqttpayload1.c_str();
 
        Serial.println(publishstate);
//        topicstate.publish(publishstate);
        // We only want to print on the output change, not state
        pirState = LOW;
      }
  }

}

// Function to connect and reconnect as necessary to the MQTT server.
// Should be called in the loop function and it will take care if connecting.
void MQTT_connect() {
  int8_t ret;

  // attempt to connect to Wifi network:
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(ssid, pass);

    // wait 10 seconds for connection:
    uint8_t timeout = 10;
    while (timeout && (WiFi.status() != WL_CONNECTED)) {
      timeout--;
      delay(1000);
    }
  }
  
  // Stop if already connected.
  if (mqttclient.connected()) {
    return;
  }

  Serial.print("Connecting to MQTT... ");

  while ((ret = mqttclient.connect()) != 0) { // connect will return 0 for connected
       Serial.println(mqttclient.connectErrorString(ret));
       Serial.println("Retrying MQTT connection in 5 seconds...");
       mqttclient.disconnect();
       delay(5000);  // wait 5 seconds
  }
  Serial.println("MQTT Connected!");
}